変数の設定をする際にエラーが出てしまう（オブジェクト変数またはWithブロック変数...）

Question

現在、新規入力した実験データを整理するべく、A4の値と一致するセルを検索し、そのセルの行番号を取得したいと考えております。
そこで、以下のコードを作成し動かしたところ、
「実行時エラー　91
オブジェクト変数またはWithブロック変数が設定されていません」
と表示されてしまいます。
完全にここで詰まってしまい調べたりしてみたのですが解決できず、ご助力頂きたく考えております。何卒よろしくお願いします。

Dim SamePlace As Range
Dim lastRng As Range

    Set lastRng = Sheet11.Cells(Rows.Count, 1).End(xlUp)
    Set SamePlace = Sheet11.Range(Cells(6, 1), lastRng).Find(what:=Range("A4").Value)
    '選択中のセルの行の番号を取得する
    Dim PlaceRow As Long
    PlaceRow = SamePlace.Row

Answer 1

別ルートで。

Sub sample()
    Dim rng As Range, v As String
    Set rng = Sheet11.Range("A6", Sheet11.Cells(Rows.Count, 1).End(xlUp))
    v = Sheet11.Range("A4").Value
    Dim PlaceRow
    If WorksheetFunction.CountIf(rng, v) > 0 Then PlaceRow = WorksheetFunction.Match(v, rng, 0) + 5
End Sub

Comments

[suichan]

ご回答いただき有難うございました。
お陰様で完成させることが出来ました！
お礼が遅くなってしまい申し訳ありません。

Answer 2

A4の値と一致するセルがないとそのエラーがでます。
ない場合は、 Is Nothing になりますので、それで場合分けすればいいでしょう。

    Dim SamePlace As Range
    Dim lastRng As Range

    Set lastRng = Sheet4.Cells(Rows.Count, 1).End(xlUp)
    Set SamePlace = Sheet4.Range(Cells(6, 1), lastRng).Find(what:=Range("A4").Value)
    If SamePlace Is Nothing Then   
        Msgbox "該当値はありません！"
    Else
        Dim PlaceRow As Long
        PlaceRow = SamePlace.Row
        Msgbox "該当値は" & PlaceRow  & "行目です。"
    End If
    
    MsgBox PlaceRow

Comments

[suichan]

ご回答いただき有難うございました。
お陰様で完成させることが出来ました！
お礼が遅くなってしまい申し訳ありません。

Answer 3

下記処理で、Rangeオブジェクトが取得できていないのではないでしょうか。
ブレークポイントを付与して、取得されたオブジェクトを確認してみてください。

Set SamePlace = Sheet11.Range(Cells(6, 1), lastRng).Find(what:=Range("A4").Value)

「what」に指定された条件のRangeが無い場合は「NoThing」が返されると思います。
ですので、「NoThing」に対して「Row」を参照しようとしてエラーが発生しているのかと思います。

「Row」の代入部分に条件指定を追加するとよいかもしれません。

If SamePlace Is Nothing Then
　　' 取得できなかったときの処理
Else
　　PlaceRow = SamePlace.Row
End If

※補足ですが、比較はオブジェクトどうしなので「Is」で比較します。

Comments

[suichan]

ご回答いただき有難うございました。
お陰様で完成させることが出来ました！
お礼が遅くなってしまい申し訳ありません。