フォルダ内の全てのExcelに同じ処理を繰り返す (VBA)

Question

【実施したいこと】
フォルダ内にExcelファイルが約200個あります。
この全てのに同じ処理をしたいのですが、マクロで繰り返す方法がわからないので教えて下さい。
処理をする内容は簡単なもので、マクロで作成しました。

・　各Excelファイルは１つのシートしか存在せず、シート名は重要ではないので全て「Sheet1」になっています。
・　各Excelファイルのデータの配置や表形式は同じです。
・　レコードの行数がExcelファイルによって異なります。

尚、下記のVBAを試してみたのですが、実際の処理が反映されず、間違いの箇所が分からずに困っています。
間違いもしくは、別の書き方があればそれを教えて頂けると幸いです。

【試してみたコード】
sub macro1()
dim myPath as string
dim myFile as string

　mypath = ThisWorkbook.Path

’指定フォルダのブックを順繰り拾う
myfile = dir(mypath & "*.xlsx")
do until myfile = ""

　’ブックを開いて処理を行い保存して閉じる
workbooks.open mypath & myfile
Sheets("Sheet1").Select
ActiveWorkbook.Names("該当するワード").Delete
ActiveWorkbook.Names("該当するワード").Delete
ActiveWorkbook.Names("該当するワード").Delete
ActiveWorkbook.Names("該当するワード").Delete
ActiveWorkbook.Names("該当するワード").Delete
activeworkbook.Save
activeworkbook.Close savechanges:=True

　　myfile = dir()
loop
end sub

Answer 1

パスとファイルの区切りに""がありません。（Dir()への引数のパスなど）
以下のように変更してみて下さい。

myFile = Dir(myPath & "\" & "*.xlsx")
Do Until myFile = ""
    'ブックを開いて処理を行い保存して閉じる
    Workbooks.Open myPath & "\" & myFile

因みに、「名前」はBook単位なので、Sheets("Sheet1").Selectは不要ですね。

追記

参考までに、Namesコレクションのようなコレクションの操作にはFor Eachを使用すると簡潔な記述になります。

Sub macro1()
Dim myPath As String
Dim myFile As String
Dim nm As Name

myPath = ThisWorkbook.Path & "\"
'指定フォルダのブックを順繰り拾う
myFile = Dir(myPath & "*.xlsx")
Do Until myFile = ""
    'ブックを開いて処理を行い保存して閉じる
    Workbooks.Open myPath & myFile
    For Each nm In ActiveWorkbook.Names
        Select Case nm.Name
        Case "該当するワード1", "該当するワード2"
            nm.Delete
        End Select
    Next
    ActiveWorkbook.Close savechanges:=True
    myFile = Dir()
Loop
End Sub

「名前」の定義を全て削除したいなら、Select Case～による判定は不要ですし、削除したくないものを限定したいなら、CASE で削除したくないものを指定してelseで削除を行えば記述が少なくて済みます。

Comments

[sincos41]

追記までして下さり、ありがとうございます。まだまだVBAは初心者ですので、今後にも繋がる助言を頂けて感謝してもしきれないほどです。大変勉強になりました。

Answer 2

下記のように改修すれば動作すると思います。
コメントに修正内容の説明を記述しています。

Option Explicit
Sub macro1()
    Dim myPath As String
    Dim myFile As String
    
    On Error Resume Next    '該当Excelファイル内に「該当するワード」が無かったときにエラーになるのでそれを無視する設定
    
    myPath = ThisWorkbook.Path
    
    myFile = Dir(myPath & "\" & "*.xlsx")   '\が無かったので追加
    Do Until myFile = ""
    
        Workbooks.Open myPath & "\" & myFile    '\が無かったので追加
        Sheets("Sheet1").Select
        ActiveWorkbook.Names("該当するワード").Delete
        ActiveWorkbook.Names("該当するワード").Delete
        ActiveWorkbook.Names("該当するワード").Delete
        ActiveWorkbook.Names("該当するワード").Delete
        ActiveWorkbook.Names("該当するワード").Delete
'        ActiveWorkbook.Save    'Closeのときにもセーブされるので削除
        ActiveWorkbook.Close savechanges:=True
        
        myFile = Dir()
    Loop
End Sub

Comments

[sincos41]

お礼が遅くなりましたが、修正ありがとうございます。無事に解決することができました。

[clown1616]

同じような内容で悩んでいました。ありがとうございました。

Answer 3

不具合のご説明が具体的でないので、
回答しやすくする為に、
以下の情報を記載した方が良いです。
・OS、Officeのバージョン（例：Win7(64bit)、Office2013(32bit)）
・どこのコードで、どうなってしまうのか？
(デバッグの方法を先に習得すべきかと：ブレークポイント、F5、F8、イミディエイト）

直接は関係ないですが、
WorkBook型の変数、WorkSheet型の変数を使えるようになった方が
インテリセンスが使えるようになり、書きやすく、書き損じが減ります。

また、ファイル関連の処理にはFSOを用いる方が扱いやすくなります。
（処理速度がシビアであればDirの方が早いです）