powerpointでタイトル（文字列+連続変数）をVBAで一括変換

Question

パワーポイントで、タイトルの位置に
テキスト+数字 の形でFor文を使って作りたいです。
例)こんにちは1(スライド1枚目)
こんにちは2（スライド2枚目）
...といった形です。

よろしくお願いします。

Answer 1

質問のタイトルでは"一括変換"となっていますが、本文では"タイトルの位置に～作りたい"
となっているので、すでにあるタイトルを変更したいのか、ない状態から追加したいのか、
どちらかわからないですが、とりあえず、タイトルを追加する方向で実装していみました。

PowerPoint 2016で動作確認しました。

(参考)

• テキストボックスを作成する(AddTextboxメソッド)：Excel VBA｜即効テクニック｜Excel VBAを学ぶならmoug

Sub test()
    Dim myPresentation As PowerPoint.Presentation
    Dim mySlide As PowerPoint.Slide
    Dim myShape As PowerPoint.Shape
    Dim ii As Integer, jj As Integer
    
    Set myPresentation = ActivePresentation

    If myPresentation.Slides.Count = 1 Then
        ' 表紙しかない場合は、終了
        Exit Sub
    End If

    ' 表紙は飛ばす(ii=2)
    For ii = 2 To myPresentation.Slides.Count
        Set mySlide = myPresentation.Slides(ii)

        ' テキストボックス追加
        Set myShape = mySlide.Shapes.AddTextbox( _
            Orientation:=msoTextOrientationHorizontal, _
            Left:=66, Top:=28.75, Width:=828, Height:=104.375 _
        )
        ' タイトル文字設定
        With myShape.TextFrame.TextRange
            .Text = "Title (" & ii & "/" & myPresentation.Slides.Count & ")"
            .Font.Bold = True
            .Font.Size = 44
        End With

        ' スライド中のテキストボックスの内容を出力
        For jj = 1 To mySlide.Shapes.Count
            Set myShape = mySlide.Shapes(jj)
            With myShape
                If myShape.HasTextFrame = msoTrue Then
                    Debug.Print .Top & "," & _
                                .Left & "," & _
                                .Width & "," & _
                                .Height & "," & _
                                """" & myShape.TextFrame.TextRange.Text & """"
                End If
            End With
        Next

    Next
End Sub