nasm システムコールの疑問

Question

自分はnasm 16bit のプログラミングを勉強したものです
今はnasm 32bitをubuntuの端末で動かそうとしているのですが
nasm16bitではシステムコールがint 21と学んだのですが、
nasm32bitでは自分の調べによるとint 0x80hと出たのですがこれは正しいのでしょうか？
また、nasm32でのファイル操作のシステムコールと文字列・文字の入出力のシステムコール、ファイルポインタ操作のシステムコールを教えてください
回答よろしくお願いします

Answer 1

int 21hとint 80h の違い、int 80hでのシステムコールの番号別の処理は前にご回答いただいてますので、nasm32用にx86アセンブリ言語で書いたサンプルを実際に32ビット版linux(Ubuntu 17.04 32bit)上で動作させてみたものをご紹介します。
サンプルは画面に文字列を出力し、簡単なファイルの読み書きをします。

以下のような流れになります。コード中のラベルと照らし合わせて見てください。
0. print_stdout:
”Hello World!"を標準出力に出力します。コンソール上に"Hello World!"と表示されます。

1. file1_open:

'file1.txt' をopenします。
2. file1_read:
ファイルから10バイト読み出し、バッファーへ保存します。
3. file1_print_stdout:
読み出した10バイトのデータを標準出力へ書き込みます。コンソール上に表示されます。
4. file1_close:
'file1.txt'をcloseします。
5. file2_open:
'file2.txt' を新規で書き込めるようopenします。
6. file2_write:
ファイルへ"Hello World!"を書き込みます。
7. file2_close:
'file2.txt'をcloseします。

test01.asm のソースコードです。

;test01.asm

section .bss
    BUFFER resb 1024

section .data
    FILEDESC dd 0
    MESSAGE: db "Hello World!", 10
    MESSAGE_LEN equ $-MESSAGE
    FILENAME1 db "file1.txt", 0
    FILENAME2 db "file2.txt", 0

section .text

global main

main:

.print_stdout:
    mov eax, 4
    mov ebx, 1
    mov ecx, MESSAGE
    mov edx, MESSAGE_LEN
    int 80h

.file1_open:
    mov eax, 5	; open
    mov ebx, FILENAME1
    mov ecx, 2	; read/write mode
    int 80h
    mov [FILEDESC], eax

.file1_read:
    mov eax, 3	; read
    mov ebx, [FILEDESC]
    mov ecx, BUFFER	; pointer to input buffer
    mov edx, 10; read 10 bytes
    int 80h

.file1_print_stdout:
    mov eax, 4
    mov ebx, 1
    mov ecx, BUFFER
    mov edx, 10
    int 80h

.file1_close:
    mov eax, 6 ; close
    mov ebx, [FILEDESC]
    int 80h;

.file2_open:
    mov eax, 5	; open
    mov ebx, FILENAME2
    ; O_CREAT=0x40, O_RDWR=0x02
    mov ecx, 42h	; read/write mode
    mov edx, 666q	; rw-rw-rw-
    int 80h
    mov [FILEDESC], eax

.file2_write:
    mov eax, 4	; write
    mov ebx, [FILEDESC]
    mov ecx, MESSAGE
    mov edx, MESSAGE_LEN
    int 80h

.file2_close:
    mov eax, 6 ; close
    mov ebx, [FILEDESC]
    int 80h

.exit:
    mov eax, 0
    ret

test01.asm はnasmとgccコマンドで、以下のようにアセンブル〜リンクします。

$ nasm -f elf -o test01.o test01.asm

$ gcc -o test01 test01.o

test01の実行結果です。

Comments

[binary]

分かりやすい例が付いた回答ありがとうございます。
この例を参考にしつつプログラミングしてみます。
今後もし質問を自分がした時はあつかましいですが回答よろしくお願いします。
本当にありがとうございました

[binary]

今更ですが質問いいですか？
dodox86さんが表示されたプログラムのこの部分なのですが
MESSAGE: db "Hello World!", 10
最後の「１０」と言うのはどこから出てきたものでか？
また、同じように
FILENAME1 db "file1.txt", 0
これの「０」もどこから出てきた数字ですか？
回答よろしくお願いします
無知ながら考えましたが思いつきませんでした
よろしければ回答よろしくお願いします。

Answer 2

Windows APIとPOSIX APIが異なるように、OS環境によってシステムコールの呼び方も異なります。int 21hはMS-DOSのもの、int 80hはLinuxのものです。

Comments

[binary]

システムコールに対する疑問に分かりやすく簡潔に答えていただきありがとうございます

Answer 3

アセンブラに興味があるのは今の時代、貴重な好奇心だと思います。システムコールですが、C言語でのシステムコール用の関数と照らし合わせてみると理解の助けになります。例えば、linuxのOPENで、アクセスモードのマクロ O_RDWR は2 で、ECXレジスタにセットする値と一致しています。int80hの説明で分かりづらい場合は適時、C言語でのシステムコールを参照することをお勧めします。ただ、このような値はプラットフォームで異なる場合があるので注意してください。頑張ってください。

Comments

[dodox86]

本来、回答へのコメントに入れるつもりで記入したものでした。間違いでしたが、低評価でも既についてしまっているので、このままにしておきます。

Answer 4

int 0x80で呼び出せる32bitシステムコールは、以下にある通りです。

32-bit system call numbers and entry vectors

eaxレジスタに、上記ソースの一番左の数字を入れて、各レジスタに適切なパラメータを入れて、int 0x80を行えばシステムコールが行えます。

上記ソースの3カラム目がシステムコールの名前(exitとか、forkとか)ですので、各システムコールの意味と使い方は、Linuxのマニュアルを当って調べてみてください。

ただ、それぞれをアセンブリ言語から呼び出すのは、相当難しいと思いますので、頑張ってください。

Comments

[binary]

2度目の回答ですよね？
本当にありがとうございます
これからも分からないことがある場合は質問させていただくのでよろしくお願いします。