VBAのexec()について

Question

外部batファイルをexec()で実行しました。
ですがその際、StdOutには4096バイトしか出力出来ないそうで、結果が途中までしか出力出来ません。
batファイルを複数に分ければ全て出力可能だと思うのですが、なんとか一つのbatファイルで全ての結果を出力させることはできないでしょうか？

Answer 1

OldRiverさんがおっしゃっていたコマンド実行結果をファイル出力してそれを読む関数 "GetBatResult" を作ってみましたのでご参考までに参照頂けたらと思います。
※コマンド実行結果をファイル出力するので、bat実行ウィンドウを見せないためにexecコマンドではなくrunコマンドを使用しています。

Option Explicit

' バッチ呼び出しプロシージャ
Public Sub CallBat()

    ' bat実行結果をイミディエイトウィンドウに出力
    Debug.Print GetBatResult(InputBox("batファイル格納パスを記入して下さい", "batファイル選択"))
    
End Sub

' batファイルの実行結果を取得
Public Function GetBatResult(ByRef pBatFilePath As String) As String
    
    ' 変数宣言
    Dim fso As FileSystemObject
    Dim sh As IWshRuntimeLibrary.WshShell
    Dim txtStream As TextStream
    Dim tmpFileName As String
    
    ' オブジェクト初期化
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set sh = CreateObject("WScript.Shell")
    
    ' batファイルパスが入力されなかった場合は処理終了
    If pBatFilePath = "" Then
        MsgBox "batファイルパスが入力されませんでした", vbCritical + vbOKOnly, "エラー"
        Exit Function
    End If
    
    ' batファイルの存在確認(存在しない場合は処理終了)
    If Not fso.FileExists(pBatFilePath) Then
        MsgBox "batファイルが存在しません", vbCritical + vbOKOnly, "エラー"
        Exit Function
    End If
    
    ' 一時ファイル名を取得
    With fso
        tmpFileName = .BuildPath(.GetSpecialFolder(2), .GetTempName)
    End With
    
    ' エラー制御開始
    On Error GoTo 0
    
    ' コマンドを実行し結果を一時ファイルに出力
    sh.Run pBatFilePath & " > " & tmpFileName, 1, True
    
    ' コマンド実行を失敗した場合は処理終了
    If Err.Number <> 0 Then
        MsgBox "batファイルの実行に失敗しました", vbCritical + vbOKOnly, "エラー"
        Exit Function
    End If
    
    ' エラー制御終了
    On Error GoTo 0
    
    ' コマンド実行結果ファイルを開く
    Set txtStream = fso.OpenTextFile(tmpFileName, ForReading, False, TristateUseDefault)
    
    ' コマンド実行結果を取得
    With txtStream
        GetBatResult = .ReadAll
        .Close
    End With
        
    ' 一時ファイルを削除(失敗した場合は無視)
    On Error Resume Next
    fso.DeleteFile tmpFileName
    On Error GoTo 0
    
    ' オブジェクト開放
    Set fso = Nothing
    Set sh = Nothing
    Set txtStream = Nothing
    
End Function

Answer 2

StdOutでの取得はReadAllで一気に取得してますか？

外部batファイルの出力の一行が4096を超えないテキストデータであれば
StdOut.ReadLine
で一行ずつ取得してから連結で取得できないでしょうか？

実際に動くかどうかは全く確認してませんがイメージ的にこんな感じとか。

Set e = w.Exec(外部batファイル名)

Result = ""
Do Until e.AtEndOfStream
  Result = Result & e.StdOut.ReadLine & vbCrLf
Loop

Comments

[MikeDavis]

1行ずつ読んでいます。
どうやらbatファイルにたくさんのコマンドがあるので、stdoutに格納される結果自体が多いのだと思います。

[OldRiver]

そうなると一度ファイル出力するしかなさそうですね。
batファイル中のコマンド実行を全てリダイレクトでファイル出力してそれをVBAからファイル読み込みで取得するとか。