【VBA】結合セルの値の取得

Question

Microsoft Office Personal 2010
エクセルVBAです。

例えばセルＢ３に『あああ』と入力されている時、
MsgBox Range("B3")
とすれば、
『あああ』
とメッセージが出ると思います。

これは良いのですが、指定したセルが結合セルだった場合、
一番左上のセルを指定しないと値が返ってきません。

例)
B3,B4,B5が結合セルで、値『あああ』が入っている場合
MsgBox Range("B3") 'あああ
MsgBox Range("B4") '△ブランク
MsgBox Range("B5") '△ブランク

これをB4,B5を指定しても『あああ』が返ってくるようにする方法はありますか？

尚、マクロを動かしたいエクセルは表になっており
間に空白のセルも含まれます。

Sub ZZZ()
    Dim i As Integer
    Dim maxRow As Integer
    i = 3
    maxRow = Cells(Rows.Count, 3).End(xlUp).Row
    
    While i <= maxRow
        Select Case Range("B" & i)
            Case "あああ"
                Select Case Range("C" & i)
                    Case "項目１": Range("D" & i) = "簡単に"
                    Case "項目２": Range("D" & i) = "書くと"
                    Case "項目３": Range("D" & i) = "こんな"
                End Select
            Case "いいい"
                                   Range("D" & i) = "感じの"
            Case "ううう"
                Select Case Range("C" & i)
                    Case "項目１": Range("D" & i) = "ことを"
                    Case "項目２": Range("D" & i) = "したい"
                End Select
            Case "えええ"
                Select Case Range("C" & i)
                    Case "項目１": Range("D" & i) = "です。"
                    Case "項目２": Range("D" & i) = "朝食に"
                    Case "項目３": Range("D" & i) = "納豆は"
                    Case "項目４": Range("D" & i) = "欠かせ"
                End Select
            Case "おおお"
                                   Range("D" & i) = "ない。"
        End Select
        i = i + 1
    Wend
End Sub

＜現状＞

＜理想＞

Answer 1

結合エリアはMergeAreaプロパティで表せます。
更にエリア内はItem配列に格納されるので、その中から１つ目を常に表示させれば良いと思われます。
次のような書き方でどうでしょうか。

' 全て同じ値が表示されるはず
MsgBox Range("B3").MergeArea.Item(1)
MsgBox Range("B4").MergeArea.Item(1)
MsgBox Range("B5").MergeArea.Item(1)

Comments

[torisan]

専用の関数がちゃんとあったんですね。
ありがとうございました！

Answer 2

こんなかな？

MsgBox Range("B3").MergeArea(1)
MsgBox Range("B4").MergeArea(1)
MsgBox Range("B5").MergeArea(1)

Comments

[torisan]

お早い回答ありがとうございました！