GetObjectで起動中のファイルが起動しているか確認したい

Question

### 実現したいこと

特定のファイルが起動しているか確認したいです。
GetObjectの挙動がおかしいような気がしています。

### 前提

GetObjectで特定のファイルが起動しているか確認したい。

### 発生している問題・エラーメッセージ

```
オートメーションの操作中にファイル名またはクラス名を見つけられませんでした。
```

### 該当のソースコード

```VBA
Private Function IsRunning() As Boolean
    Dim app As Object
    On Error GoTo Err_Execute
    Set app = GetObject("C:\Users	est\Documents	est.xlsx", "Excel.Application")
    IsRunning = Not app Is Nothing
    Debug.Print app.Name
    Set app = Nothing
    Exit Function
Err_Execute:
    Debug.Print Err.Description
    Err.Clear
    Set app = Nothing
    IsRunning = False
End Function
```

### 試したこと

GetObject("C:\Users	est\Documents	est.xlsx")に変えて試しましたが上手くいきませんでした。
test.xlsxだけを起動してソースを実行してTrue、app.Nameはtest.xlsxだった。
abc.xlsxだけを起動してソースを実行してTrue、app.Nameはtest.xlsxだった。

### 補足情報（FW/ツールのバージョンなど）

Excel2016のファイル起動の確認です。
PowerPointの中に記述して確認しました。

Accepted Answer

GetObject関数は、対象のファイルを開いているExcelプロセスが存在しない場合、新しくExcelを起動してしまいます。そのため、純粋にファイルが開かれているかを確認したいのであれば、ファイルを書き込みモードで開けるかどうかをチェックするのが良いと思います。

```
Sub Test()
    MsgBox IsFileLocked("D:	est	est.xlsx")
End Sub

Function IsFileLocked(filePath As String) As Boolean
    Dim fso As Object
    Dim fileNum As Integer
    Dim errNum As Long

Set fso = CreateObject("Scripting.FileSystemObject")

' 1. FSOで存在確認
    If Not fso.FileExists(filePath) Then
        IsFileLocked = False
        Set fso = Nothing
        Exit Function
    End If
    Set fso = Nothing

' 2. 書き込みモードで開けるかチェック
    fileNum = FreeFile()
    On Error Resume Next
    ' 独占的なアクセスを試行
    Open filePath For Binary Access Read Write Lock Read Write As #fileNum
    errNum = Err.Number
    Close #fileNum
    On Error GoTo 0

' エラーならロックされている
    If errNum <> 0 Then
        IsFileLocked = True
    Else
        IsFileLocked = False
    End If
End Function
```