求む、VBAの記述例

Question

VBA初心者です。
どこから手を付けていいかも分からず困っています。

VBAで入力チェック
・有無
・形式：文字か数字の判定
・範囲チェック
・整合性チェック
エラーがあればメッセージを出力し、画面の再出力

考え方も教えてもらえると幸いです。
よろしくお願いします。

Answer 1

１．ファイルメニュー、オプション、リボンのユーザー設定で開発タブにチェックを入れる。
２．開発タブ、挿入、フォームコントロールのボタンでシート上に適当にボタンを配置。
３．マクロの登録画面が表示されるので、新規作成ボタンを押す。「Sub ボタン1_Click() ～ End Sub」と言うようなコードが作成される。
４．コードを書く。

Sub ボタン1_Click()
    '有無
    If IsEmpty(Sheet1.Range("B1").Value) Then
        MsgBox "セルB1に値が入力されていません。"
        Sheet1.Range("B1").Activate
        Exit Sub
    End If
    
    '形式：文字か数字の判定
    If Not IsNumeric(Sheet1.Range("B2").Value) Then
        MsgBox "セルB2に数値が入力されていません。"
        Sheet1.Range("B2").Activate
        Exit Sub
    End If
    
    '範囲チェック
    If Sheet1.Range("B3").Value < 1 Or Sheet1.Range("B3").Value > 5 Then
        MsgBox "セルB3は1～5の範囲の値を入力してください。"
        Sheet1.Range("B3").Activate
        Exit Sub
    End If
    
    '整合性チェック
    If Sheet1.Range("B3").Value = 1 And IsEmpty(Sheet1.Range("B4").Value) Then
        MsgBox "セルB3が1のとき、セルB4に値を入力してください。"
        Sheet1.Range("B4").Activate
        Exit Sub
    End If
    If Sheet1.Range("B3").Value <> 1 And Not IsEmpty(Sheet1.Range("B4").Value) Then
        MsgBox "セルB3が1以外のとき、セルB4に値は入力できません。"
        Sheet1.Range("B4").Activate
        Exit Sub
    End If
    
    MsgBox "チェックOK"
End Sub

あとはボタンを押せば動作すると思います。

Answer 2

VBAはエクセルでしょうか？
VBAじゃないとダメなのでしょうか？

「データの入力規則」で全部できるような？

セルにデータの入力規則を適用する

フォームを使ったVBA限定であればスルーしてください。

Comments

[aki1981]

エクセルのVBAです。

Answer 3

批判殺到な質問ですね。
対象がワークシートなのかフォームなのかで書き方はことなりますが、概ね次のような感じでしょう。

・有無

If 対象 <> "" Then
    ' データ有り
Else
    ' データ無し
End If

・形式：文字か数字の判定

If IsNumeric(対象) Then
    ' 数値
Else
    ' 数値ではない
End If

・範囲チェック

' 以上・以下(<=)にするか、より大きい・小さい(<)にするかは適宜判断してください
If 下限値 <= 対象 And 対象 <= 上限値 Then
    ' 範囲内
Else
    ' 範囲外
End If

・整合性チェック

仕様によるものなのでここでは答えられません。

エラーがあればメッセージを出力し、画面の再出力

If 入力エラー時 Then
    MsgBox "入力エラー"
End If

画面の再出力の意味がわからないので無回答。
MsgBoxの仕様は下記リンクを参照してください。
https://msdn.microsoft.com/ja-jp/library/office/gg251821.aspx

Comments

[aki1981]

正しい質問のやりかたもわからない状況です。
指摘していただいて、ありがとうございます。