batファイル内で実行結果を変数に保存

Question

バッチファイル内で、
実行ファイルや"dir /w"等のコマンドを実行して、その結果を変数に格納すると言ったことは出来るでしょうか。

Answer 1

@echo off

setlocal enabledelayedexpansion
set LF=^


for /f "tokens=* delims=" %%x in ('dir /w') do set FILES=!FILES!%%x!LF!
echo !FILES!

delims を空にして改行を含むとまるっと代入出来ます。

が、この方法を使ったとしてもバッチファイルでは空行を検出する事ができないので他の処理系を使う等の考慮が必要です。

Comments

[uer03108]

回答有難うございました。
確認できました。
勉強になりました。

Answer 2

setlocal ENABLEDELAYEDEXPANSION
set TEXT=
for /F "delims=" %%A in ('dir') do (set TEXT=!TEXT!%%A^

)

echo !TEXT!

一応、このようにすればコマンドが出力したテキストをだいたい丸ごと環境変数に格納できます（空行を排除してしまうので完全に同じというわけにはいきませんが）。

あるいは、配列変数っぽく1行ずつ格納する方法もあります。

setlocal ENABLEDELAYEDEXPANSION
set COUNT=0
for /F "delims=" %%A in ('dir') do (set /A COUNT += 1 & set TEXT.!COUNT!=%%A)

for /L %%A in (1,1,%COUNT%) do call echo %%TEXT.%%A%%

Comments

[uer03108]

回答有難うございました。
変数を1つずつ作成して格納するということでしょうか。
バッチならではですね。

Answer 3

出来ます。が、dir /wのような複数行をどうやって変数に格納しますかね？
verのような1行であれば、

for /f "delims=" %%A in ('ver') do set VERSION=%%A

Comments

[uer03108]

回答有難うございました。
確かに

@echo off
for /f "delims=" %%A in ('dir /w') do set VERSION=%%A
echo %VERSION%

だど1行分しか表示されませんでした。