VBAを使用したセルのコピー＆ペースト時のアクティブシートの移動について

Question

###前提・実現したいこと
VBAを使用したマクロを作成したのですが、
実行環境等によってアクティブシートが移動するときとしないときがあるように感じます。
マクロ自体は対策を行い、完成しているのですが、今後のために正確な挙動の仕様がわかればと思い質問させていただきます。

###発生している問題・エラーメッセージ
以下のマクロを実行した際に、実行環境等によって異なる結果となる。
マクロはSheet1～3までの3枚のシートを予め作成したExcel内で実行しています。

###該当のソースコード

Sub test()
    Dim ws As Worksheet
    Dim r As Range
    
    ActiveSheet.Range("A1").Value = "test"
    
    ThisWorkbook.Worksheets("Sheet3").Activate
    ActiveSheet.Range("A2").Value = "test"
    
    Set ws = ThisWorkbook.Worksheets("Sheet2")
    
    ws.Range("A1").Copy
    ws.Range("B1").PasteSpecial (xlPasteFormats)
  '//※1

    ActiveSheet.Range("A3").Value = "test"
    ws.Range("C1").Copy
    ActiveSheet.Range("A4").Value = "test"
    ws.Range("D1").PasteSpecial (xlPasteFormats) '//※２
    ActiveSheet.Range("A5").Value = "test"

End Sub

###試したこと
以下の環境で動作の確認を行いました。

１．Excel2016にて、Sheet1をアクティブにした状態でマクロを直接実行(Alt+F8など)
→A1セルの文字列=Sheet1、A2～A5セルの文字列=Sheet3 に表示される

２．Excel2016にて、Sheet1にボタンを作成し、ボタン経由でマクロを実行
→A1セルの文字列=Sheet1、A2～A4セルの文字列=Sheet3、A5セルの文字列=Sheet2 に表示される

３．Excel2016にて、２．と同様にボタン経由でマクロを実行し、ソースコードの※２の行で一旦breakした後そのまま再開
→A1セルの文字列=Sheet1、A2～A5セルの文字列=Sheet3 に表示される

４．Excel2010にて、２．の手順を実行
→A1セルの文字列=Sheet1、A2～A5セルの文字列=Sheet3 に表示される

５．Excel2016にて、ソースコードの※1の部分にコピペモードの解除処理を追加し、２．の手順を実行
→A1セルの文字列=Sheet1、A2～A5セルの文字列=Sheet3 に表示される
（追加したコード：「Application.CutCopyMode = False」）

上記の実験から、※２でペーストを行う際に条件によりアクティブシートが移動することがあるようなのですが、一旦breakすると現象が発生しないことからも条件がよくわからない状態となっています。

この現象についてご存じの方がいらっしゃいましたら、ご教示いただければと存じます。
宜しくお願いいたします。

Answer 1

今後のために正確な挙動の仕様がわかればと思い

あいにく正確な挙動の仕様は当方も分からないのですが、気になりましたので少し調べて、推測してみました。（Excel 2013）

ある Worksheet に対して PasteSpecial を実行すると、その前に PasteSpecial を実行した Worksheet がアクティブになる、という摩訶不思議な動作をしているように見えます。
なお、途中で Activate メソッドによりアクティブシートを切り替えると、その動作はリセットされるようです。

このような動作を当てにするのは意味がなさそうですね。

Sub Demo()
    Dim sh1 As Worksheet
    Set sh1 = ThisWorkbook.Worksheets("Sheet1")     'ボタンを配置＆ログを記録するシート
    Dim sh2 As Worksheet
    Set sh2 = ThisWorkbook.Worksheets("Sheet2")     'テスト用シート(開始時にアクティブなシート)
    Dim sh3 As Worksheet
    Set sh3 = ThisWorkbook.Worksheets("Sheet3")     'テスト用シート(ペースト先)
    Dim sh4 As Worksheet
    Set sh4 = ThisWorkbook.Worksheets("Sheet4")     'テスト用シート(ペースト先)

    'シートを初期化
    sh1.Activate: sh1.Cells.Clear: sh1.Range("A1").Activate
    sh2.Activate: sh2.Cells.Clear: sh2.Range("A1").Activate
    sh3.Activate: sh3.Cells.Clear: sh3.Range("A1").Activate
    sh4.Activate: sh4.Cells.Clear: sh4.Range("A1").Activate

    'テスト(1)
    sh1.Range("A1").Value = "テスト(1)"
    sh2.Activate
    sh2.Range("A1").Copy
    sh1.Range("A2").Value = ActiveSheet.Name    'A2 ← "Sheet2"
    sh3.Range("A1").PasteSpecial                'Sheet3 にペースト (アクティブなシートは Sheet2 のまま)
    sh1.Range("A3").Value = ActiveSheet.Name    'A3 ← "Sheet2"
    sh4.Range("A1").PasteSpecial                'Sheet4 にペースト (Sheet3 がアクティブになる)
    sh1.Range("A4").Value = ActiveSheet.Name    'A4 ← "Sheet3"
    sh3.Range("A1").PasteSpecial                'Sheet3 にペースト (Sheet4 がアクティブになる)
    sh1.Range("A5").Value = ActiveSheet.Name    'A5 ← "Sheet4"

    'テスト(2)
    sh1.Range("B1").Value = "テスト(2)"
    sh2.Activate
    sh2.Range("A1").Copy
    sh1.Range("B2").Value = ActiveSheet.Name    'B2 ← "Sheet2"
    sh3.Range("A1").PasteSpecial                'Sheet3 にペースト (アクティブなシートは Sheet2 のまま)
    sh1.Range("B3").Value = ActiveSheet.Name    'B3 ← "Sheet2"
    sh2.Activate                                'あえて Sheet2 をアクティブにする
    sh4.Range("A1").PasteSpecial                'Sheet4 にペースト (アクティブなシートは Sheet2 のまま)
    sh1.Range("B4").Value = ActiveSheet.Name    'B4 ← "Sheet2"
    sh3.Range("A1").PasteSpecial                'Sheet3 にペースト (Sheet4 がアクティブになる)
    sh1.Range("B5").Value = ActiveSheet.Name    'B5 ← "Sheet4"

    'シート1をアクティブにして終了
    sh1.Activate
End Sub

Comments

[n_haraguchi]

返信おそくなってしまい申し訳ありません。
回答ありがとうございます。
ActiveSheetは使わず、明示的に指定してやるようにしようと思います。

Answer 2

この現象についてご存じの方がいらっしゃいましたら

残念ながらこちらについてはわかりません。

以下のマクロを実行した際に、実行環境等によって異なる

経験上の話ですが、私が今まで行ってきた挙動のブレ対策を書きます。

*Excelは思いもよらない動きをすることがある
→しかも、深追いしても何も収穫がないことが多い

ExcelのActiveSheetはあまりあてにしない方がよいと思います。
恐らく、内部でActiveSheet処理をする際に何らかの最適化のようなことがされているようで、時々思いもよらない（コードに書いてある順番と前後して）処理が行われることがあります。

対策）
・ActiveSheetの代わりに、シート名を指定してやるとうまくいきます。
・ActiveSheetを使うにしても、withでくくると思いもよらない挙動が減った（気がした）と思います。
※もし複数のブックを扱う場合、同じような問題が起きやすくなったと思います。この際には、シート名でくくる際にブック名も併せてくくるとより良いと思います。

Comments

[n_haraguchi]

返信おそくなってしまい申し訳ありません。
やはり、ActiveSheetではなく、しっかり名前で指定したほうが良さそうですね。
回答有り難うございます。