ExcelVBAで複数領域の選択

Question

ExcelVBAでマクロを作っています。
長方形の範囲を指定した際、その選択範囲を横一列毎の複数選択範囲に分割する必要がありますが、
方法がわかりません。

小さい範囲なら

Range("A1:C1,A2:C2,A3:C3").Select

で実現できますが
範囲が大きくなると255文字の制限に引っかかってエラーになります。
また

Uniom(Range("A1:C1,A2:C2,A3:C3"),...).Select

とした場合は文字数制限は解決しますが、選択範囲が結合してしまいます。

どうすれば実現できるでしょうか。
ご教示願います。

Answer 1

Unionはセル範囲の集合なので、隣接する範囲だと合体してしまうんですよね。
Range.AreasコレクションにAddでもできればよさそうなのですが、こちらはReadOnlyとのことで、なかなか痒いところに手が届かないようです。

今回の対応として思いつくのは２つ。

案①：Stringに収まる範囲で複数回の処理にわける。
⇒たとえば100行処理したい場合、10行ずつ10回処理する。

案②：連続しない範囲となるようUnionを分けて処理する。
⇒たとえば偶数行・奇数行で処理を分ける。

「Ctrl+範囲選択」でできる選択範囲の追加をVBAで実現できればもっとスマートになるのですが、この操作をマクロ記録してもトンチンカンなコードしか生成してくれないようで、現状こんなダサい回避策しか思い当りません。
もっとエレガントな回避策をご存じの方がいれば、自分も参考にさせていただきたいです(T-T)

Answer 2

根本的な解決にはなりませんが、Rangeの文字数制限を緩和するアドバイスです。

Rangeはセルに定義した名前でも範囲を指定することができます。
つまり選択範囲に1～2文字程度の簡潔な名前を定義してやればRangeの文字数を省略することができます。

Range("A1:C1").Name = "X"
Range("X").Select

---

Rangeの文字数省略を踏まえたコードを書いてみました。
何かしらの参考になりましたら幸いです。

※行単位・列単位で選択するとエラーになります。
※この方法ではせいぜい70行程度までしか処理できません。

Option Explicit

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    
    '変数定義
    Dim Source As String  '選択範囲
    Dim BgnRow As Long    '選択開始行
    Dim EndRow As Long    '選択終了行
    Dim BgnCol As Long    '選択開始列
    Dim EndCol As Long    '選択終了列
    Dim i      As Long    'ループカウンタ
    Dim DivRange As String
    
On Error GoTo Exception
    
    'イベント停止
    Application.EnableEvents = False
    
    '選択範囲をアドレスで取得
    Source = Target.Address(False, False)
    
    '選択範囲が連続したセル(長方形)か判定
    If InStr(Source, ":") > 0 Then
        
        '選択開始行と選択終了行を取得
        BgnRow = Range(Split(Source, ":")(0)).Row
        EndRow = Range(Split(Source, ":")(1)).Row
        
        '選択開始列と選択終了列を取得
        BgnCol = Range(Split(Source, ":")(0)).Column
        EndCol = Range(Split(Source, ":")(1)).Column
        
        '横一列毎に簡潔な名前を設定する
        For i = BgnRow To EndRow
            Range(Cells(i, BgnCol), Cells(i, EndCol)).Name = "_" & i
        Next
        
        'セルに設定した名前をカンマで結合する
        For i = BgnRow To EndRow
            DivRange = DivRange + "_" & i & ","
        Next
        
        '最後のカンマを除外
        DivRange = Mid(DivRange, 1, Len(DivRange) - 1)
        
        '横一列毎に選択
        Range(DivRange).Select
        
        'セルに設定した名前を全て削除する
        For i = BgnRow To EndRow
            Range(Cells(i, BgnCol), Cells(i, EndCol)).Name.Delete
        Next
        
    End If
    
Exception:
    
    'エラー内容を出力
    If Err.Number <> 0 Then
        MsgBox Err.Description
    End If
    
    'イベント再開
    Application.EnableEvents = True
    
End Sub

Comments

[deigo]

ありがとうございます。
一時的に名前をつけるんですね。目から鱗です。
ほかに実現方法がない場合はこの方法で検討しようと思います。