VBAのループ処理途中でシートへ入力したい。

Question

VBAでループ処理の途中でシートに書き込みを行い、その情報を基に処理を実行したいです。

具体的には・・・
エクセルファイルには２つのシートがあります。
”設定”シートと”記入”シートです。
”設定”シートのA列には２行目から処理対象のデータベース名が記載されています。

VBAを実行すると、ユーザーフォームが立ち上がります。

ユーザーフォームが立ち上がり、”記入”シートが選択されています。
記入シートに必要な情報を入力し、フォームの”OK”ボタンを押すと『処理』が実行されます。
その後、再度ユーザーフォームが立ち上がり、【テストDB2】の必要な情報を記入シートに
入力し、処理する。これを【テストDB6】までループするといった感じのコードにしたいです。

★ループを中断しシートに記入後、復帰させる。という処理が分かりません。

コードを書いてみました。
ループを中断し処理はできるのですが、各”テストDB”で中断し処理できません。
ユーザーフォームは【テストDB6】で表示されてしまいます。
【テストDB1】、【テストDB2】・・・は飛ばされてしまいます。

修正コードを教えて下さい。
※function 処理1 のコードは省いています。

Option Explicit
Dim fStop As Boolean        'グローバル変数を宣言

Sub sample()

Dim i As Long, N As Long, cnt As Long

    With Sheets("設定")
       i = .Cells(Rows.Count, 1).End(xlUp).Row
       
       If i > 1 Then
            fStop = True
            Sheets("記入").Select
            For cnt = 2 To i

            DoEvents
               If fStop = True Then
                 UserForm1.Label1.Caption = "【" & .Cells(cnt, 1).Text & "】の" & vbCrLf & "コードを入力して下さい。"
                 UserForm1.Show vbModeless
                 Sheets("記入").Select
               End If
               fStop = False
            Next cnt
       End If
    End With
End Sub

Private Sub Command1_Click()
    fStop = True
    処理１
    Sheets("記入").Select
    Unload Me
End Sub

Comments

[退会済みユーザー]

thisworkbookのコードとシート構成も書いて頂けますか？

Answer 1

ユーザーフォームをモードレス(vbModeless)で開くと、
コードを中断せずにすぐ次のコードへ進みます。
Forループの最後まで一気に進んでしまいます。

Do Uutil fStop
    Doevents
Loop

というようにDoループで待機させる方法もありますが、
ずっとコードが回り続けることになりますので、CPU負荷が大きくなり
お勧めできません。

ここは、ループは使わずに、
一つの処理が終わったら（ユーザーがOKを押したら）
次の処理へすすむというようなコーディングにするといいでしょう。

標準モジュール

Option Explicit

Public EndRow As Long        '最終行
Public CurRow As Long        '処理中の行

Sub 処理開始()
    EndRow = Sheets("設定").Cells(Rows.Count, 1).End(xlUp).Row
    CurRow = 2
    Call ユーザーフォーム
End Sub

Sub ユーザーフォーム()
    UserForm1.Label1.Caption = "【" & Sheets("設定").Cells(CurRow, 1).Text & "】の" _
                               & vbCrLf & "コードを入力して下さい。"
    UserForm1.Show vbModeless
    Sheets("記入").Select
End Sub

Sub 処理実行()
    CurRow = CurRow + 1
    If CurRow > EndRow Then
        MsgBox "全処理が完了しました。"
        Unload UserForm1
    Else
        UserForm1.Hide

        処理1

        Call ユーザーフォーム
    End If
End Sub

ユーザーフォーム

Private Sub CommandButton1_Click()
   Call 処理実行
End Sub

処理開始 を実行すると、
ユーザーフォームが開きユーザーに入力を即します。
入力後、ユーザーがOKを押すと、
次の入力を即すユーザーフォームが開きます。

Comments

[cd987456]

回答ありがとうございます。
各テストDB毎に処理できました。
ループしないとできないと思い込んでいました。
このような方法もあるんですね。
勉強になります。
ありがとうございました。