【VBA】サブディレクトリも含めたファイル一覧を素早く取得したい

Question

以下のSample1とSample2はどちらもC:\Tempのサブディレクトも含めたファイル一覧を取得する関数です。
Sample1は'Sample2'よりも実行時間が短いですが、コマンドプロンプトが表示されてしまいます。

質問①Sample1でコマンドプロンプトを画面表示させない方法はありますか？
質問②Sample1,Sample2以外に素早くファイル一覧を取得できるような方法はありますか？

Sub Sample1()
    Dim WSH, wExec, sCmd As String, Result As String
    Set WSH = CreateObject("WScript.Shell")
    sCmd = "dir /B /S C:\Temp"
    Set wExec = WSH.Exec("%ComSpec% /c " & sCmd)
    Do While wExec.Status = 0
        DoEvents
    Loop
    Result = wExec.StdOut.ReadAll
    MsgBox Result
    Set wExec = Nothing
    Set WSH = Nothing
End Sub

Sub Sample2()
    Call FileSearch("C:\Temp")
End Sub

Sub FileSearch(Path As String)
    Dim FSO As Object, Folder As Variant, File As Variant
    Set FSO = CreateObject("Scripting.FileSystemObject")
    For Each Folder In FSO.GetFolder(Path).SubFolders
        Call FileSearch(Folder.Path)
    Next Folder
    For Each File In FSO.GetFolder(Path).Files
        Debug.Print File.Path
    Next File
End Sub

Answer 1

質問１は分かりません。

質問２は、Sample2は書き方を工夫すれば少し速くできますね。

Option Explicit

Sub Sample2()
    Dim fso As New Scripting.FileSystemObject
    FileSearch fso.GetFolder("C:\")
End Sub

Sub FileSearch(ByVal Folder As Scripting.Folder)
    Dim File As Scripting.File, SubFolder As Scripting.Folder, f As String
    On Error Resume Next
    For Each SubFolder In Folder.SubFolders
        FileSearch SubFolder
    Next
    For Each File In Folder.Files
        f = File.Path
    Next
End Sub

’参照設定で Microsoft Scripting Runtime にチェックを入れてください。

’実行結果（C:\ をスキャン。出力はせず変数に格納するのみ。）
’オリジナル 849秒
’改良後 720秒

’改良箇所
’①参照設定をしてVariantの代わりにその型を使う
’②引数をByValで渡す
’③引数でFolderを渡す

VB.NET を使うともっと速くできます。

Imports System.Collections.Concurrent
Imports System.IO

Module Module1

    Private FileNameBag As New ConcurrentBag(Of String)

    Sub Main()
        Dim sw = Stopwatch.StartNew
        Scan(New DirectoryInfo("C:\"))
        Dim fileNames = FileNameBag.ToArray
        Array.Sort(fileNames)
        Dim scanTime = sw.Elapsed.TotalSeconds
        sw.Restart()
        For Each fileName In fileNames
            Console.WriteLine(fileName)
        Next
        Dim outputTime = sw.Elapsed.TotalSeconds
        Console.WriteLine("ファイル数=" & fileNames.Length & " スキャン時間=" & scanTime & " 出力時間=" & outputTime)
        Console.ReadLine()
    End Sub

    Private Sub Scan(directory As DirectoryInfo)
        Try
            Parallel.ForEach(directory.GetDirectories, Sub(subDir) Scan(subDir))
            For Each file In directory.GetFiles
                FileNameBag.Add(file.FullName)
            Next
        Catch
        End Try
    End Sub

End Module

’実行結果
’ファイル数 358,553個
’スキャン時間 5.98秒
’出力時間 16.37秒

上記はサンプルですが、Windows アプリにして、コマンドラインパラメータ経由でスキャンするディレクトリ名を入力し、一時ファイルに結果を出力すればコマンドプロンプトを出さずにVBAから容易に利用できると思います。

Comments

[退会済みユーザー]

とてもご丁寧なご回答ありがとうございます。
助かります！

Answer 2

Sample1 ですが、VBAではなくWindowsの機能を使っているので実行速度は速いですが、マクロとしては
「使わない方がいい」ですね(コードの可読性・セキュリティが低くなる)。

もし出力先を「Debug.Print」にするSample2でしたら、
(前提:ブックのVBEで「ツール」→「参照設定」→「Microsoft Scripting Runtime」にチェックを入れる)

Sub Sample2()
    Call FileSearch("C:\Temp")
End Sub

Sub FileSearch(Path As String)
    Dim FSO As New FileSystemObject, Folders As Folders, Folder As Folder, Files As Files, File As File
    'Set FSO = CreateObject("Scripting.FileSystemObject")→テキストでは
  '「オブジェクト参照回数の増加により、マクロ実行速度低下の原因」となるとのこと。
    Set Folders = FSO.GetFolder(Path).SubFolders
    For Each Folder In Folders
       ' Call FileSearch(Folder.Path)→自身のプロシージャを再帰呼び出ししているため、
    '低下の原因となっている。
    
      For Each File In Folder.Files
        Debug.Print File.Path
      Next File

    Next Folder

End Sub

こちらで実験しましたが、実行速度及び結果も問題無いと思います。
いかがでしょうか?

Answer 3

VBAのDir関数を使って、フォルダー配下を再帰的に呼び出してフォルダー階層を取得するサブルーチン(WalkFolderList)を作ってみました。
Dir関数の使い方については、Dir関数でサブフォルダを取得するで調べるのが良いと思います。

作成した関数は、探索するフォルダーの最上位のフォルダーを"C:\Program Files\Windows NT"のように引数で指定するとその配下のフォルダーをカンマで繫いで表示する。WalkFolderList関数です。

[例]
WalkFolderList("C:\Program Files\Windows NT\で呼び出すとその配下のフォルダーをカンマで繫いで、次のような文字列で返却するものです。
"C:\Program Files\Windows NT,C:\Program Files\Windows NT\Accessories,...

コードは以下のようになります。Dir関数を用いて指定されたパス直下のファイル名やフォルダー名からフォルダー名を抜き出し、新しくそのフォルダー名からパスを作り出し自分自身(WalkFolderList)を呼び出すものです。

Public Function WalkFolderList(ByVal s As String) As String
    Dim i As Integer
    Dim v() As String
    Dim folderList As String
    Dim buf As String
    
    ' 指定されたパスがディレクトリでなかったら何もせずに空文字列を返却する。
    If (GetAttr(s) And vbDirectory) = vbDirectory Then
        WalkFolderList = s
    Else
        WalkFolderList = ""
        Exit Function
    End If
    
    ' 該当フォルダー直下のフォルダーを動的配列の「v」に格納する。
    buf = Dir(s, vbDirectory)
    i = 0
    Do While buf <> ""
        If buf <> "." And buf <> ".." Then
            If (GetAttr(s & buf) And vbDirectory) = vbDirectory Then
                ReDim Preserve v(i)
                v(i) = s & buf
                i = i + 1
            End If
        End If
        buf = Dir()
    Loop
    If i <> 0 Then
        '該当フォルダー直下のフォルダーの下にフォルダーがあるか自分自身の関数「WalkFolderList」を呼び出す
        For i = LBound(v) To UBound(v)
            WalkFolderList = WalkFolderList & "," & _
                WalkFolderList(v(i) & "\")
        Next i
    End If
End Function

Answer 4

質問②に対する回答ですが、
FSOよりDirを使った方が、数倍早くなります。

後は、検索用に再帰の関数を作って、
サブディレクトリの中も処理していけば、
指定パス以下、全ファイルのパスが取得できるようになります。
※ある程度のプログラミング技術が必要です。

Answer 5

質問１:
Exec()を使うと、コマンドプロンプトは隠せないようです。
代わりに、Run()を使うように、と先行事例で書いてありました。
stackoverflow

質問２:
ueiさんの回答（細かくてバッチリですね！）を参照ください。

Comments

[退会済みユーザー]

2006年のマイクロソフトの回答も同じようなことが書いてありました。
例が分かりにくいのでURLは端折ります。

[退会済みユーザー]

Runメソッドは戻り値が整数(終了コードかな？)なので、Dirコマンドで取得したファイル一覧を出力することができないです・・・。
一時ファイルにDirコマンドの結果を出力して、そのファイルを読み込んで出力するしかないですかね。

[退会済みユーザー]

使ったことはないのですが、
You'd have to redirect the output to a temporary file that your VBScript could then open, read, and delete.
Yet another possibility is to use the Windows clipboard. You can pipe the output of your command to the clip.exe utility. Then, retrieve the text via any number of available COM objects that can access the contents of the clipboard.
runを使うと答えも隠れてしまうので、VBSに出力するか、クリップボードにしまうといいよ、とのことでしたので書いた次第です。
（フォルダリストでもできるかどうかの真偽は不明です。）

[退会済みユーザー]

クリップボードの仕組みは全然詳しくないですが・・・
クリップボードだとマクロ実行している間に、ユーザに他のアプリでクリップボードを使用されてしまうと上書きされてしまうような懸念があります(>_<)

[退会済みユーザー]

コマンドプロンプト（クリップボード無し）で完結させようとすると以下の感じでしょうか。
dir /s /b *.*>list.txt
# ファイルを書き出してから云々はやっぱり美しくないですね。

[退会済みユーザー]

そうですよね。私もそう思います。
VBSの出力って具体的にどうやるんですかね。