VBAでdata URIのimg要素をダウンロードしたい。

Question

https://app.codegrid.net/entry/datauri-basic#toc-0
上記のサイトの画像のように、img要素のsrcが「http://~~~」ではなく、「data:~~~」の場合の画像を、VBAから保存するにはどうすれば良いでしょうか？
IEを起動せずに行いたいです。
URLDownloadToFileの取得先URLに対して、img要素のsrcの内容を指定しても、ダウンロードできませんでした。

以下は実行ソースのサンプルです。

Declare Function URLDownloadToFile Lib "urlmon" Alias _
    "URLDownloadToFileA" (ByVal pCaller As Long, _
    ByVal szURL As String, _
    ByVal szFileName As String, _
    ByVal dwReserved As Long, _
    ByVal lpfnCB As Long) As Long

Declare Function DeleteUrlCacheEntry Lib "wininet" _
    Alias "DeleteUrlCacheEntryA" (ByVal lpszUrlName As String) As Long
Public Sub subA()
    '--------------------------
    ' 画像のdata URI取得
    '--------------------------
    Dim objXML As New MSHTML.HTMLDocument
    Dim htmlDoc As New MSHTML.HTMLDocument
    Dim objITEM As Object

    ' srcが「data:～～」形式のimg要素が一つのみ存在するページとします
    Set htmlDoc = objXML.createDocumentFromUrl("http://example.com/hogehoge.html", vbNullString)
    Call untilReady(htmlDoc)

    Dim strDataURL As String
    strDataURL = htmlDoc.getElementsByTagName("img")(0).src

    '--------------------------
    ' ダウンロード処理
    '--------------------------
    Dim fileName As String
    Dim savePath As String
    Dim cacheDel As Long, result As Long
    
    '画像ファイル名
    fileName = "test.jpeg"
    
    '画像保存先(+画像ファイル名）
    savePath = "C:\Users\user\Desktop\" & fileName
    
    ' キャッシュクリア
    cacheDel = DeleteUrlCacheEntry(strDataURL)
    
    '画像ダウンロード
    result = URLDownloadToFile(0, strDataURL, savePath, 0, 0)

  If result = 0 Then
    MsgBox "ダウンロードできました"
  Else
    MsgBox "ダウンロードできませんでした" '※※result = -2147024774 でここに来ます※※
  End If

    Set objITEM = Nothing
    Set htmlDoc = Nothing
    Set objXML = Nothing

End Sub

Sub untilReady(htmlDoc As MSHTML.HTMLDocument)
    Do Until htmlDoc.readyState = "complete"
        DoEvents
    Loop
    DoEvents
End Sub

IEを起動しない方法であれば、どのような形でも良いです。
なにか方法はありますでしょうか？

Answer 1

data URI というのは初めて知りましたが、調べてみると、画像ファイルをBase64でテキストに変換して、HTML内に埋め込むというものですね。

img要素のsrcはURLではなくテキスト変換された画像データなので、URLDownloadToFile でダウンロードしても意味ないですよね。

ということで下記のような手順になるでしょう。

提示のコードで取得したimg要素のsrcのdata:image/gif;base64,以降を切り出して、Base64デコードして、ファイルに保存する。デコードは下記のリンク先の方法でできます。

ファイルをBase64エンコード・デコードするVBAマクロ | 初心者備忘録

リンク先の DecodeBase64関数をコピーしてモジュールに貼り付けて、提示コードの
' ダウンロード処理
を下記のように変更したら画像ファイルとして保存できました。

    '--------------------------
    ' base64デコード
    '--------------------------
    Dim fileName As String
    Dim savePath As String
    Dim cacheDel As Long, result As Long

    '画像ファイル名
    fileName = "test.gif"    ' "test.jpeg"

    '画像保存先(+画像ファイル名）
    savePath = "C:\test\" & fileName    '"C:\Users\user\Desktop\" & fileName


    '画像変換
    result = DecodeBase64(Mid(strDataURL, InStr(strDataURL, "base64,") + 7), savePath)

    If result Then
        MsgBox "画像変換できました"
    Else
        MsgBox "画像変換できませんでした"
    End If

Comments

[Zoohomi]

無事保存できました！
ありがとうございました^^