VBA カレンダーの日付エラー処理

Question

コンボボックスに入力された日付をもとにカレンダーを作成するVBAを作成しています。カレンダーの始まりと終わりの日付を入力するので始まりと終わりが逆に入力された場合にエラーとして処理したいです。現在のコードが下記になります。
論理演算子の使い方があまりわかっていないので教えてください。
ngpで年月日になっています。

Dim n, g, p As String
Dim n2, g2, p2 As String
Dim h, h2 As String
n = ComboBox1.Text
g = ComboBox2.Text
p = ComboBox3.Text
h = n & " / " & g & " / " & p
Range("G5").Value = h

n2 = ComboBox4.Text
g2 = ComboBox5.Text
p2 = ComboBox6.Text
h2 = n2 & " / " & g2 & " / " & p2
If n > n2 Then
    MsgBox "正しい日付を入力してください"
    Unload Me
    Exit Sub
    End If
If n = n2 And g > g2 Then
    MsgBox "正しい日付を入力してください"
    Unload Me
    Exit Sub
    End If
If n = n2 And g = g2 And p > p2 Then
    MsgBox "正しい日付を入力してください"
    Unload Me
    Exit Sub
    End If
Unload Me

Answer 1

色々と突っ込み処が。。

Dim n, g, p As String

上記はpがstringでn,gは型の指定が省略されているのでVariantとなります。
意図通りにするには

Dim n As String, g As String, p As String

となります。
次に日付で扱うのですから、Date型で扱った方が比較は楽になります。
また、年月日それぞれで入力するのですから、有効な日付かどうかのチェックも必要だと思います。
※リファクタリングはしておらず、冗長ですけど

Dim n As String, g As String, p As String
Dim n2 As String, g2 As String, p2 As String
Dim h As Date, h2 As Date

n = ComboBox1.Text
g = ComboBox2.Text
p = ComboBox3.Text
If IsDate(n & " / " & g & " / " & p) Then
  h = CDate(n & " / " & g & " / " & p)
  Range("G5").Value = Format(h, "yyyy/mm/dd")
Else
  MsgBox "正しい日付を入力してください"
  Unload Me
  Exit Sub
End If

n2 = ComboBox4.Text
g2 = ComboBox5.Text
p2 = ComboBox6.Text
If IsDate(n2 & " / " & g2 & " / " & p2) Then
  h2 = CDate(n2 & " / " & g2 & " / " & p2)
Else
  MsgBox "正しい日付を入力してください"
  Unload Me
  Exit Sub
End If

If h > h2 Then
  MsgBox "正しい日付を入力してください"
  Unload Me
  Exit Sub
End If

Unload Me

Comments

[321Kurumins]

回答ありがとうございます。突っ込みどころが多くてすみません。
コード全体正常に動作しました。ありがとうございます。