ユーザーフォームの最大、最小化コード

Question

VBAのユーザーフォームに最大化、最小化ボタンを付けたくてネットを調べたところ
コードが記載されていました。
コードを転記したところ、ユーザーフォームに最大最小ボタンが追加されました。

教えて頂きたいことはVBAのコード内でユーザーフォームを最大化、最小化する為のコードが
分かりません。

下記のコードからVBAのコード内でユーザーフォームを最大化、最小化する為のコードを
教えて頂けませんか？

'標準モジュールに下記のコードを追記します。
Option Explicit
'ユーザーフォームの最大最小ボタン追加

Private Const GWL_STYLE = (-16)
Private Const WS_THICKFRAME = &H40000
Private Declare Function GetWindowLong Lib "user32" _
      Alias "GetWindowLongA" _
      (ByVal hwnd As Long, _
      ByVal nIndex As Long) As Long
Private Declare Function SetWindowLong Lib "user32" _
      Alias "SetWindowLongA" _
      (ByVal hwnd As Long, _
      ByVal nIndex As Long, _
      ByVal dwNewLong As Long) As Long
Private Declare Function GetActiveWindow Lib "user32" () As Long
Private Declare Function DrawMenuBar Lib "user32" (ByVal hwnd As Long) As Long

Public Function CustomizeForm()

  Dim Ret As Long
  Dim hwnd As Long
  Dim Wnd_STYLE As Long
  
  hwnd = GetActiveWindow()
  Wnd_STYLE = GetWindowLong(hwnd, GWL_STYLE)
  Wnd_STYLE = Wnd_STYLE Or WS_THICKFRAME Or &H30000
  Ret = SetWindowLong(hwnd, GWL_STYLE, Wnd_STYLE)
  Ret = DrawMenuBar(hwnd)

End Function

'ユーザーフォームに下記コードを追加します。
Private Sub UserForm_Activate()
  CustomizeForm
End Sub

Answer 1

APIでできました。
サンプルなのでShowWindowの第一引数はGetActiveWindow()にしていますが、CustomizeForm()で取得しているhwndをグローバル化して使いまわした方がすっきりするかもしれません。お好みで。

Const SW_SHOWNORMAL = 1
Const SW_SHOWMINIMIZED = 2
Const SW_SHOWMAXIMIZED = 3
Private Declare Function ShowWindow Lib "User32" (ByVal Hwnd As Long, _
    ByVal nCmdShow As Long) As Long

Private Sub test()
    ' 通常
    Call ShowWindow(GetActiveWindow(), SW_SHOWNORMAL)
    ' 最小化
    Call ShowWindow(GetActiveWindow(), SW_SHOWMINIMIZED)
    ' 最大化
    Call ShowWindow(GetActiveWindow(), SW_SHOWMAXIMIZED)
End Sub

Comments

[cd987456]

回答ありがとうございます。
上手く処理できました。