【バッチ処理】エラーフラグがたってないのにエラー時の処理をしてる原因がわからない

Question

実現したいこと

エラーフラグが立っていないときはエラーの処理をスルーして削除コマンドを実行してほしい。

発生している問題・分からないこと

TortoiseSVNの削除コマンドを実行するバッチを作成しました。

■動作
バッチを実行するとファイルパスが記載されたテキストファイル（dlt_list.txt)を読み込んで、上から順番に削除コマンドを実行するというものです。

削除コマンド実行前にファイルパスが合ってるか確認し、一致しないものが有る場合はエラーを吐きます。
エラー発生時は続行するかどうか（Y/N)の入力を求めます。

■参考
バッチとテキストファイルは同じフォルダに配置してます。

該当のソースコード

@echo off
echo SVNリポジトリからファイルを削除します...

REM TortoiseSVNのインストールディレクトリのパスを設定します
set SVN_PATH="C:\Program Files\TortoiseSVN\bin\TortoiseProc.exe"

REM 現在のバッチファイルのディレクトリを取得
set CURRENT_DIR=%~dp0

REM ログファイルのパスを設定します
set LOG_DIR=%CURRENT_DIR%log
if not exist "%LOG_DIR%" mkdir "%LOG_DIR%"
set LOG_FILE=%LOG_DIR%\log_%date:~-10,4%%date:~-5,2%%date:~-2%_%time:~0,2%%time:~3,2%%time:~6,2%.txt

echo ファイルパスの確認を開始します... >> "%LOG_FILE%"

REM エラーフラグを設定
set ERROR_FOUND=0

REM エラーリストファイルを初期化
echo エラーリスト: > %LOG_DIR%\error_list.txt

REM ファイルリストを読み込む
for /f "tokens=*" %%f in (dlt_list.txt) do (
    if not exist %CURRENT_DIR%%%f (
        echo エラー: %%fは存在しません。 >> "%LOG_FILE%"
        echo %%f >> %LOG_DIR%\error_list.txt
        set ERROR_FOUND=1
    )
)

if %ERROR_FOUND%==0 (
    echo すべてのファイルパスが正しいことを確認しました。 >> "%LOG_FILE%"
)

if %ERROR_FOUND%==1 (
    type %LOG_DIR%\error_list.txt
    echo エラーが見つかりました。処理を続行しますか？ (y/n)
    set /p CONTINUE=
    if /i "%CONTINUE%"=="n" (
        echo 処理を中止します。 >> "%LOG_FILE%"
        goto end
    )
)

echo SVNリポジトリからファイルを削除します... >> "%LOG_FILE%"

REM ファイルリストを再度読み込む
for /f "tokens=*" %%f in (dlt_list.txt) do (
    if exist %CURRENT_DIR%%%f (
        echo %%fを削除しています... >> "%LOG_FILE%"
        %SVN_PATH% /command:remove /path:"%CURRENT_DIR%%%f" /notempfile /closeonend:1
        if errorlevel 1 (
            echo 削除中にエラーが発生しました。処理を中止します。 >> "%LOG_FILE%"
            goto end
        )
    )
)

echo 削除が完了しました。 >> "%LOG_FILE%"
goto final

:end
echo 処理が中止されました。 >> "%LOG_FILE%"

:final
pause

■発生事象
ファイルパスが合っている（%ERROR_FOUND%=0）がカーソルが点滅して入力待ちの状態になってしまう。

ただ、エラー時のように「エラーが見つかりました。処理を実行しますか?(y/n)」というメッセージの表示は出ない。

カーソル点滅時にyやエンターを押すとコマンドプロンプトが閉じる。(svnの削除コマンドは実行される）
カーソル点滅時にnを押すとコマンドプロンプトが閉じる。（svnの削除コマンドは実行されない)

試したこと・調べたこと

• teratailやGoogle等で検索した
• ソースコードを自分なりに変更した
• 知人に聞いた
• その他

上記の詳細・結果

■試したこと
1）%ERROR_FOUND%=0のメッセージ表示後に「goto dltsvn」を追加して強制的に削除の処理へ進める。（svn削除の処理の部分に「:dltsvn」を追加）

途中は同じなので省略

if %ERROR_FOUND%==0 (
    echo すべてのファイルパスが正しいことを確認しました。 >> "%LOG_FILE%"
    goto dltsvn　　　←これを追加して飛ばしてる
)

if %ERROR_FOUND%==1 (
    type %LOG_DIR%\error_list.txt
    echo エラーが見つかりました。処理を続行しますか？ (y/n)
    set /p CONTINUE=
    if /i "%CONTINUE%"=="n" (
        echo 処理を中止します。 >> "%LOG_FILE%"
        goto end
    )
)

:dltsvn　　←ファイルパス確認して正常ならここに飛ばす
echo SVNリポジトリからファイルを削除します... >> "%LOG_FILE%"

REM ファイルリストを再度読み込む
for /f "tokens=*" %%f in (dlt_list.txt) do (
    if exist %CURRENT_DIR%%%f (
        echo %%fを削除しています... >> "%LOG_FILE%"
        %SVN_PATH% /command:remove /path:"%CURRENT_DIR%%%f" /notempfile /closeonend:1
        if errorlevel 1 (
            echo 削除中にエラーが発生しました。処理を中止します。 >> "%LOG_FILE%"
            goto end
        )
    )
)

echo 削除が完了しました。 >> "%LOG_FILE%"
goto final

:end
echo 処理が中止されました。 >> "%LOG_FILE%"

:final
pause

2）ファイルパスのエラー発生時に続行するかの確認処理を入れずに「goto end」へ飛ばして処理を中断する。

途中は同じなので省略

echo ファイルパスの確認を開始します... >> "%LOG_FILE%"

REM ファイルリストを読み込む
for /f "tokens=*" %%f in (dlt_list.txt) do (
    if not exist %CURRENT_DIR%%%f (
        echo エラー: %%fは存在しません。処理を中止します。 >> "%LOG_FILE%"
        goto end
    )
)

echo すべてのファイルパスが正しいことを確認しました。 >> "%LOG_FILE%"

echo SVNリポジトリからファイルを削除します... >> "%LOG_FILE%"

REM ファイルリストを再度読み込む
for /f "tokens=*" %%f in (dlt_list.txt) do (
    echo %%fを削除しています... >> "%LOG_FILE%"
    %SVN_PATH% /command:remove /path:"%CURRENT_DIR%%%f" /notempfile /closeonend:1
    if errorlevel 1 (
        echo 削除中にエラーが発生しました。処理を中止します。 >> "%LOG_FILE%"
        goto end
    )
)

echo 削除が完了しました。 >> "%LOG_FILE%"
goto final

:end
echo 処理が中止されました。 >> "%LOG_FILE%"

:final
pause

一応動作は望むものになったのですが、根本の解決にはなってないのでどなたか原因がわかれば教えてほしいです。

2024.12.5追記

カーソル点滅時、yを入力したあとのログ

カーソル点滅時、nを入力したあとのログ

Comments

[setoppu]

ログファイルにはどういう記録が残っているんですか？
コマンドライン（多分バッチファイルでも）ではファイル名に半角スペース含んだりする場合は！""で全体を囲む必要がありますが、そのあたりはどうでしょう？

https://qiita.com/yz2cm/items/f808e4380faa3bd51a98

[choco_mint]

回答ありがとうございます。
補足にカーソル点滅時にyまたはn入力後のログ画像を追加しました。

また、参考のリンクもありがとうございます。
こちらも試してみます。

Answer 1

エラー時のメッセージが原因でした。
（y/n）の部分が悪さをしてたようで、ダブルコーテーションで囲ったら望み通りの挙動になりました。

 echo エラーが見つかりました。処理を続行しますか？ ”(y/n)”

setoppuさん、参考リンクありがとうございました。
リンクの記事内容を見てこの閃きに繋がりました。

Comments

[otn]

1文しか書けないところに複数の文を書くために、複数の文を「(」と「)」 で囲んだ場合には、
「(」の次に、クォートされていない「)」が出てきたらそれが閉じ括弧と見做されます。
echo だけじゃなくて、set X=(ABC) のようなケースでも同様ですね。

「)」をクォートする場合、引用符で囲んでも良いのですが、それだと引用符も対象文字列に含まれてしまうので、
それを避けたい場合は、普通は「直後の1文字だけのクォート」を行う「^」という記号を使います。
多くの言語での「\」と同じような意味でで、「構文上の閉じ括弧」を、単なる「)」という文字に変えます。

echo エラーが見つかりました。処理を続行しますか？ (y/n^)

[choco_mint]

otnさん
そういう決まりがあったんですね。
補足ありがとうございます！！