VBAでの中央値計算

Question

実現したいこと

以下のような表があるときにエクセルVBAで中央値を計算したいです。

前提

n数カウントは同じ種類のデータをかかった時間を小さい順にまとめたときに順にカウントアップしていきます。
例）A11からA21の１１個のデータでかかった時間の中央値を求めたい
これをこのシートの最終行まで行いたいです。
ｎ数カウント1で終了している行はその種類しかデータがありませんでした。

試したこと

ExcelワークブックのMEDIAN関数を使用して算出しようかと思いましたが、
VBA上ではうまくできませんでした。
何かいい方法があればご教示ください。

Comments

[Zuishin]

http://officetanaka.net/excel/vba/speed/s9.htm

Answer 1

Sub Test1()

    Dim wsSource As Worksheet
    Dim rngTarget As Range
    Dim lngRow As Long
    Dim lngFirstRow As Long
    Dim lngLastRow As Long
    Dim lngSequenceStart As Long
    Dim lngSequenceHeight As Long
    
    Set wsSource = ThisWorkbook.Worksheets(1)
    
    With wsSource
        
        lngFirstRow = 2
        lngLastRow = .Cells(.Rows.Count, 1).End(xlUp).Row
        
        If lngFirstRow > lngLastRow Then
            Set wsSource = Nothing
            Exit Sub
        End If
        
        .Range(.Cells(lngFirstRow, 3), _
               .Cells(lngLastRow, 4)).ClearContents
        
        lngSequenceStart = lngFirstRow
        lngSequenceHeight = 1
        
        For lngRow = lngFirstRow To lngLastRow
            If .Cells(lngRow, 1).Value < .Cells(lngRow + 1, 1).Value Then
                lngSequenceHeight = lngSequenceHeight + 1
            Else
                '集計範囲の参照
                Set rngTarget = .Cells(lngSequenceStart, 2).Resize(lngSequenceHeight, 1)
                '中央値の出力
                .Cells(lngRow, 3).Value = WorksheetFunction.Median(rngTarget)
                '検算用に数式も設定
                .Cells(lngRow, 4).Formula = "=MEDIAN(" & rngTarget.Address & ")"
                Set rngTarget = Nothing
                lngSequenceStart = lngRow + 1
                lngSequenceHeight = 1
            End If
        Next
    
    End With
    
    Set wsSource = Nothing

以上のようなコードを実行できればよい、ということでしょうか。