【VB.NET】DataTableを結合する

Question

お世話になっております。
現在、VB.NETでの開発を行っています。
その中で、二つのDataTableがあり、SQLでいうところのLEFT JOINのようなことをDataTableで行えないかと思っています。

「AAA」
No. Name Remark

1 ○○○
2 ××× ---
3 △△△

「BBB」
No. Group

1 赤
2 青
3 黄

「NewTable」
No. Name Remark Group

1 ○○○ 赤
2 ××× --- 青
3 △△△ 黄

上記のようにある項目に紐づけて二つのDataTableを一つにしたいです。
分かる方いらっしゃいましたら教えてください。
よろしくお願いいたします。

Answer 1

確認できていないけど、こんな感じで

Dim ds As New DataSet
ds.Tables.Add(AAA)
ds.Tables.Add(BBB)

ds.Relations.Add("NewTable", AAA.Columns("No"), BBB.Columns("No"))

-追記-
ただ結果のDataTableが欲しいだけなら
前提が

Dim AAA As New DataTable
Dim BBB As New DataTable
Dim newtable As New DataTable

AAA.Columns.Add("No")
AAA.Columns.Add("Value")
AAA.Rows.Add(1, "a")
AAA.Rows.Add(2, "b")
AAA.Rows.Add(3, "c")


BBB.Columns.Add("No")
BBB.Columns.Add("Value")
BBB.Rows.Add(1, "A")
BBB.Rows.Add(2, "B")
BBB.Rows.Add(3, "C")

newtable.Columns.Add("No")
newtable.Columns.Add("Value1")
newtable.Columns.Add("Value2")

みたいなのだと思いますが

Dim joinresult = AAA.AsEnumerable.Select(Function(x) New With {
    .No = x.Item("No"),
    .Value1 = x.Item("Value"),
    .Value2 = BBB.AsEnumerable.Where(Function(y) y.Item("No") = x.Item("No")).FirstOrDefault?.Item("Value")
 })

For Each item In joinresult.ToList
    newtable.Rows.Add(item.No, item.Value1, item.Value2)
Next

みたいにしてもいいかもしれません

Comments

[programer]

回答ありがとうございます。
関連付けたものをDatatableにしたいのですが、ここからどのようにすればいいのでしょうか。
AddされたDatasetをDatatableに変換すればいいのでしょうか。

[dojikko]

出先なので
DataSet と DataRelation を使って DataTable の外部結合 Join ？
https://saiminjutsu.wordpress.com/2010/06/15/dataset-%E3%81%A8-datarelation-%E3%82%92%E4%BD%BF%E3%81%A3%E3%81%A6-datatable-%E3%81%AE%E5%A4%96%E9%83%A8%E7%B5%90%E5%90%88%E3%80%80join-%EF%BC%9F/
辺りを参考に

[programer]

Dim newTable As DataTable = ds.Tables(0)のようにしてみましたが、やり方が悪かったのか、うまく結合されていませんでした。この記事をもう少し読み込んでみます。

Answer 2

多分、もっといい方法があると思うのですが、別の質問のほうも考慮してサンプルを・・・

    Private Sub Test()
        Dim ds As New DataSet
        Dim dt1 As New DataTable
        Dim dt2 As New DataTable
        Dim newtable As New DataTable

        dt1.Columns.Add("No")
        dt1.Columns.Add("T1C1")
        dt1.Columns.Add("T1C2")
        dt1.Columns.Add("T1C3")
        dt1.Columns.Add("T1C4")
        dt1.Columns.Add("T2No")

        dt2.Columns.Add("No")
        dt2.Columns.Add("T2C1")
        dt2.Columns.Add("T2C2")
        dt2.Columns.Add("T2C3")
        dt2.Columns.Add("T2C4")

        For i = 0 To 100
            dt1.Rows.Add(i, String.Format("C1-{0}", i), String.Format("C2-{0}", i), String.Format("C3-{0}", i), String.Format("C4-{0}", i), i + 1000)
            dt2.Rows.Add(i + 1000, String.Format("T2C1-{0}", i), String.Format("T2C2-{0}", i), String.Format("T2C3-{0}", i), String.Format("T2C4-{0}", i))
        Next

        ds.Tables.Add(dt1)
        ds.Tables.Add(dt2)
        ds.Relations.Add("Test", dt2.Columns("No"), dt1.Columns("T2No"))

        '結合結果のDataTableを作成
        newtable.Columns.Add("No")
        newtable.Columns.Add("T1C1")
        newtable.Columns.Add("T2C3")

        For Each r As DataRow In dt1.Rows
            Dim t2r As DataRow = r.GetParentRow("Test")
            newtable.Rows.Add(r.Item("No"), r.Item("T1C1"), t2r.Item("T2C3"))
        Next

        '結果を出力
        For Each r As DataRow In newtable.Rows
            Console.WriteLine(String.Join(",", r.ItemArray))
        Next

    End Sub

Comments

[programer]

別の質問も考慮していただき、ありがとうございます。
行をループさせてやるやり方が結局は一番単純でいいのかもしれませんね。

Answer 3

二つのDataTableがあり、SQLでいうところのLEFT JOINのようなことを

その「二つのDataTable」をどのように作成したのですか？

もし、SQL Server などの DB から ADO.NET の DataAdapter などを使用して生成したものであれば、DB から直接「SQLでいうところのLEFT JOINのようなことを」して取得してはいかがですか？

Comments

[programer]

そのSQLが複雑で重いため、データグリッドのDatasouseから列で取得したいと思っています。

[退会済みユーザー]

「データグリッドのDatasouse」というのが「二つのDataTable」と理解していますが、それから取得しようとすると、自分が考え付くのは、AsEnumerable メソッドで IEnumerable<DataRow> オブジェクトを取得し、LINQ で join して・・・ということですが、それはさらに複雑で重くなると思うのですが。