フォーム内のテキストボックスの値が変更されたら、別のフォームのテキストボックスにその値が反映される

Question

コントロールタブ内に設置された二つのフォームがあります。
フォーム1（ページ1タブ内）のテキストボックスtxt作成日の値に対応して
フォーム2（ページ2タブ内）のテキストボックス３か所の値が決まります。
フォーム読み込み時と、txt作成日の値が変更される場合、両方の場合に
同じ処理になります。

(フォーム1)
Private Sub Form_Load()
    txt作成日 = Date
End Sub

Private Sub txt作成日_AfterUpdate()
    [Forms]![メインフォーム]![フォーム2]![txt当日] = txt作成日
    [Forms]![メインフォーム]![フォーム2]![txt１か月後] = DateAdd("m", 1, txt作成日)
    [Forms]![メインフォーム]![フォーム2]![txt２か月後] = DateAdd("m", 2, txt作成日)
End Sub

(フォーム2)
Private Sub Form_Load()
    txt当日 = [Forms]![メインフォーム]![フォーム1]!txt作成日
    txt１か月後 = DateAdd("m", 1, [Forms]![メインフォーム]![フォーム1]!txt作成日)
    txt２か月後 = DateAdd("m", 2, [Forms]![メインフォーム]![フォーム1]!txt作成日)
End Sub

そこで次のように、標準モジュール内の関数を呼び出すように
コードを書き換えました。

(フォーム1)
Private Sub txt作成日_AfterUpdate()
    EnterDate
End Sub

(フォーム2)
Private Sub Form_Load()
    EnterDate
End Sub

Sub EnterDate()
    [Forms]![メインフォーム]![フォーム2]!txt当日 = [Forms]![メインフォーム]![フォーム1]!txt作成日
    [Forms]![メインフォーム]![フォーム2]!txt１か月後 = DateAdd("m", 1, [Forms]![メインフォーム]![フォーム1]!txt作成日)
    [Forms]![メインフォーム]![フォーム2]!txt２か月後 = DateAdd("m", 2, [Forms]![メインフォーム]![フォーム1]!txt作成日)
End Sub

ただ、処理はフォーム2内のテキストボックスの変更なので、
コードは、標準モジュールではなくフォーム2に書ければと思っています。
フォーム2の方で、フォーム1のtxt作成日の変化を検知する方法があれば、
その方法を使ってフォーム2に書きたいです。
そのような方法はありますでしょうか。

Answer 1

WithEventsをつけてテキストボックス変数を宣言すれば、別フォームのコントロールのイベントも記述できます。

フォーム2のモジュール

Option Compare Database
Option Explicit
Dim WithEvents tb As TextBox

Private Sub Form_Load()
    EnterDate
    Set tb = Me.Parent![フォーム1]!txt作成日
    tb.AfterUpdate = "[イベント プロシージャ]"
End Sub

Sub EnterDate()
    Me!txt当日 = Me.Parent![フォーム1]!txt作成日
    Me!txt１か月後 = DateAdd("m", 1, Me!txt当日)
    Me!txt２か月後 = DateAdd("m", 2, Me!txt当日)
End Sub

Private Sub tb_AfterUpdate()
    EnterDate
End Sub

Comments

[mnbwqz]

ありがとうございます。
フォーム2（ページ2タブ内）のコードだけで、フォーム1の変更を反映するようになりました。