パワーポイントVBAで複数のスライドをPDF出力したい

Question

実現したいこと

ExportAsFixedFormatやActivePresentation.PrintOutにて、複数のスライドをPDF出力する機能を作りたい

発生している問題・分からないこと

ExportAsFixedFormatのRangeTypeをppPrintSlideRangeに設定した際に、スライド番号をセットする方法がわからない

該当のソースコード

Sub ExportSlideAsPDF()
    '保存先のパスを設定
    Dim saveFilePath As String
    saveFilePath = Environ("USERPROFILE") & "\Desktop\" & "testpdf" & ".pdf"
    
    'ex)1-3番目のスライドのみをPDFとして出力
    With ActivePresentation
    .ExportAsFixedFormat _
        Path:=saveFilePath, _
        FixedFormatType:=ppFixedFormatTypePDF, _
        RangeType:=ppPrintSlideRange, _
        PrintSlideRange:=Array(1, 3)
    End With
    
End Sub

With ActivePresentation
    With .PrintOptions
    .RangeType = ppPrintSlideRange
            With .Ranges
            .ClearAll
            .Add 1, 1
            .Add 3, 3
            End With
    End With
    .PrintOut
End With

試したこと・調べたこと

• teratailやGoogle等で検索した
• ソースコードを自分なりに変更した
• 知人に聞いた
• その他

上記の詳細・結果

PrintSlideRange:=Array(1, 3)にて、名前付き引数が見つかりませんと出てしまいます。
ppPrintSlideRangeの値セットのコードを試してみましたが、できませんでした。

RangeType:=ppPrintCurrentの場合は現在のスライドがPDF出力されることを確認できました。

有識者の方がいらっしゃればアドバイスいただけますと大変助かります。

補足

実行はボタン配置したスライドを「スライドショーの開始」でボタンを押して発火することを想定しています。

Answer 1

ExportAsFixedFormatのRangeTypeをppPrintSlideRangeに設定した際に、スライド番号をセットする方法

引数 RangeType に定数 ppPrintSlideRange を渡す場合

Sub Sample1()
    
    Dim objWSH As Object
    
    Set objWSH = CreateObject("WScript.Shell")
    
    Dim saveFilePath As String
    
    saveFilePath = objWSH.SpecialFolders("Desktop") & "\" & _
                   "testpdf1" & ".pdf"
                   
    Set objWSH = Nothing
    
    With ActivePresentation
        
        '印刷オプションの設定
        With .PrintOptions
            .RangeType = ppPrintSlideRange
            With .Ranges
                .ClearAll
                '1番目から3番目までのスライド範囲を追加
                .Add 1, 3
            End With
        End With
        
        '印刷オプションに追加された1つめのスライド範囲を PDF 出力
        .ExportAsFixedFormat _
            Path:=saveFilePath, _
            FixedFormatType:=ppFixedFormatTypePDF, _
            RangeType:=ppPrintSlideRange, _
            PrintRange:=.PrintOptions.Ranges(1)
            
    End With
    
End Sub

引数 RangeType に定数 ppPrintSelection を渡す場合

Sub Sample2()
    
    Dim objWSH As Object
    
    Set objWSH = CreateObject("WScript.Shell")
    
    Dim saveFilePath As String
    
    saveFilePath = objWSH.SpecialFolders("Desktop") & "\" & _
                   "testpdf2" & ".pdf"
    
    Set objWSH = Nothing
    
    With ActivePresentation
        
        '1番目のスライドと3番目のスライドを選択する（2番目および4番目以降は含まれない）
        .Slides.Range(Array(1, 3)).Select
        
        '選択中のスライドをPDF出力する
        .ExportAsFixedFormat _
            Path:=saveFilePath, _
            FixedFormatType:=ppFixedFormatTypePDF, _
            RangeType:=ppPrintSelection, _
            PrintRange:=Nothing
            
    End With
    
End Sub