processingでの画像のフェードイン・フェードアウトについて

Question

現在、processingでソフトを制作している、デザイン学生です。画像をフェードインしてから3秒表示させ、その後フェードアウトして次の画面を表示させる方法がわからず困っています。

自身でコードをかいてみましたが、画像が出てこず、元の状態に戻そうとしても
void setup(){のところにDuplicate methodと出てしまい、戻らなくなってしまいました。参考として、
http://mslabo.sakura.ne.jp/WordPress/make/processing%E3%80%80%E9%80%86%E5%BC%95%E3%81%8D%E3%83%AA%E3%83%95%E3%82%A1%E3%83%AC%E3%83%B3%E3%82%B9/%E7%94%BB%E5%83%8F%E3%82%92%E9%80%8F%E6%98%8E%E3%81%AB%E3%81%99%E3%82%8B%E3%81%AB%E3%81%AF/
を使用しました。どなたか助けていただけませんでしょうか。よろしくお願いします。

以下、コードです。
float alpha;
boolean cngAlpha;
boolean fadeMode;

void setup(){
size(1980, 1080);
background(0);

PImage tonto = loadImage("1-01.png");
PImage device = loadImage("1-02.png"); //kesuyatu
image(device,0,500,500,500);

//tukauyattu

cngAlpha = false;
fadeMode = false;
//
if( cngAlpha == true ){
if( fadeMode == true ){
fadeIn();
} else {
fadeOut();
}
}

tint(255f,alpha);
image(tonto,450,450,500,500);
}
void fadeIn(){

alpha = alpha + 4f;

if( alpha > 255f ){
alpha = 255f;
cngAlpha = false;
}
}
void fadeOut(){

alpha = alpha - 4f;

if( alpha < 0f ){
alpha = 0f;
cngAlpha = false;
}
}

Answer 1

setup()はいわば初期設定を行うメソッドですので、動的に動かそうとするロジックはdraw()に書くのが一般的ではないかと思います。

float     alpha=0.0F;   
boolean   fadeMode;
PImage[] imgs;
int cnt = 0;  // 3秒待機用
int mcnt =0;  // 画像カウンタ

// 初期設定 
void setup(){ 
  size(1000, 500); 
  frameRate(20);  // とりあえず20フレーム/秒で指定
  imgs = new PImage[]{loadImage("1-01.png"),loadImage("1-02.png")};
  fadeMode = true; 
}

// 描画の記載
void draw() {
  background(0);
  if(mcnt <= imgs.length-1){
    execFade(imgs[mcnt]); 
  } else {
  //すべての動画を表示した後はプログラム終了
    for (PImage img : imgs) {
      img = null;
    }
    exit();
  }
} 

//引数にしている画像をFadeIn→3秒停止→FadeOutする処理
//FadeOutしたらmcntを1つ上げて、次の動画の処理を行えるようにする
void execFade(PImage img){
  tint(255f,alpha); 
  image(img,mcnt*500,0,500,500);
  // 秒数はFrameRateを考慮する必要があります。
  if (cnt >= frameRate*3) {
    fadeMode = !fadeMode;
    cnt = 0;
  }
  if (fadeMode) {
    // IN 
    if (alpha < 255.0F) {
      alpha = alpha + 4f;
      cnt = 0;
    } else {
      alpha = 255f;
      cnt++;
    }
  } else {
    // OUT
    if (alpha > 0.0F) {
      alpha = alpha - 4f;
      cnt = 0;
    } else {
      println("next!!");
      fadeMode = !fadeMode;
      cnt =0;
      mcnt++;      // 次の画像に進むためのカウンタを+1
    }
  }    
} 

適当に書きましたのでちょっと蛇足ぎみの箇所もあるとは思いますが、とりあえず、「指定した動画を順にFadeIn/Outさせて表示する」というのは、実現できていると思います。(versionは2.0です。)
思ったのと違った場合は、すいません。