Excel VBAのListviewの値をチェックボックスで選択してDBのレコードを削除するには?

Question

Excel VBAでListviewを作成し、各行の左端にチェックボックスを設けています。
チェックボックスをチェックしてコマンドボタンを押下するとチェックした行と同じ値のレコードをDBから削除する処理を描きたいです。

ググってもListviewに関する情報が少なく困っております。

一例を挙げていただけなでしょうか?

Comments

[kpiyohiko]

回答に長々と書いてしまうと、可読性が下がるのでこちらに。１、削除とはどこから削除することを想定していますか。（例、画面上のみ、DBのみなど）２、VBAのイベント発生時（ボタンクリック時）の該当箇所にソースコードを記載することは可能ですか。３、ListviewがVBAのどこでどのように動作しているかは特定できておりますでしょうか

Answer 1

自分で作成されたコードの提示がない質問にサンプルコードを提供するのはあまり好ましいとは思えませんが、回答がなかなかつかないようでしたので一例としてサンプル提供いたします。
次回からは多少なりとも自分で手を動かしたところを見せていただけるとうれしいです。

---

自分もExcelではListViewを使ったことがない、というかフォーム自体Excelではあまり利用したことがありません。
多くの場合シート上で何とかなったりしますし、こったことをするならVB.NETからExcelを操作したほうがよくなってしまったりしますしね(^-^;

VBAのListViewに関する情報が少ないのも、そういった経緯で利用する人が少ないからかもしれません。

今回のサンプルは主に下記のサイトを参考にして作成しました。
⇒参考

まずフォーム生成時にリストビューを作成します。
（サンプルコードではシート1からリストデータを取得するようにしています。）

'フォーム表示
Private Sub UserForm_Initialize()

    'ListViewサンプル
    With ListView1
        .AllowColumnReorder = True
        .BorderStyle = ccFixedSingle
        .OLEDragMode = ccOLEDragAutomatic
        .OLEDropMode = ccOLEDropManual
        .Gridlines = True
        .View = lvwReport
        .CheckBoxes = True
        
        'ビューの先頭列の表示
        .ColumnHeaders.Add 1, "CHK", "", 20
        .ColumnHeaders.Add 2, "KEY", "CODE", 50
        .ColumnHeaders.Add 3, "NM", "名前", 150
    End With
    
    'リストデータをシートから取得
    For i = 2 To 6
        With ListView1.ListItems.Add
            .Text = ""  'チェック列は空欄
            .SubItems(1) = Sheet1.Cells(i, 1)   'KEY
            .SubItems(2) = Sheet1.Cells(i, 2)   '名前
        End With
    Next i
End Sub

以下が今回の質問の本題となる、ボタン押下時のチェックボックス判定のサンプルです。

'ボタン押下処理
Private Sub CommandButton1_Click()

    Dim lstitem As ListItem
    
    'ListViewのすべての行をループ処理
    For Each lstitem In ListView1.ListItems
        'チェックがついていたら
        If lstitem.Checked = True Then
            'キー項目で削除（サンプルではメッセージ表示のみ）
            MsgBox "Delete " & lstitem.SubItems(1)
        End If
    Next
    
End Sub

ListVIewの全ての行をループして、チェック状態を調べ、チェックがついていたら削除キー項目を抜き出しています。
※サンプルではメッセージボックスでキー情報を表示しているだけですが、ここで取得したキー情報を使って削除処理を実行すればよいと思います。

参考になれば幸いです。

Comments

[st_woz_jobs]

ご返信遅くなり申し訳ありません。
ご回答ありがとうございます！

そうですよね。
自分で書いたコードを載せるべきですよね。

今回は、急ぎでサンプルをご提供いただきたくてあのような質問になってしまいました。

次回からはなるべくコードを載せるようにします。

処理のほうは無事解決できました。
ありがとうございました。

また、機会がありましたらご教授ください。

Answer 2

VBAからdelete文を実行するではだめでしょうか。
Listviewはすでに作成されているとのことですので、
そのListviewのイベント（ボタンを押したとき）にsqlを実行するように
VBAで処理を記載すれば対応が可能だと思うのですが、いかがでしょうか

Listviewについてではなく、DBへの接続方法でしょうか。
最後の2文で何を聞きたいのかがわからなくなっているようにも見受けられます。

Comments

[st_woz_jobs]

ご回答ありがとうございます。
わかりづらい文章で申し訳ありません。

画像等を載せられればよいのですが、
諸事情により難しい状態です。

listviewのプロパティ？でチェックボックスを各行の左側に表示させることができると思います。

表示させたチェックボックスをチェックすることで、行を選択状態にして、コマンドボタンを押すことでDBから選択した行のレコードを削除したいのです。

DBの接続方法については大丈夫です。

ちなみにlistviewに表示させているデータはDBから取得したものです。

初心者のため、用語等、よく分かっていない部分が多くあります。
説明不足で申し訳ありません。

[st_woz_jobs]

色々とご協力いただきまして、ありがとうございました。

情報修正のご依頼をいただいていましたが、ご返信できておりませんでした。

処理のほうは無事解決できました。

今回、いただいたアドバイスでどのように質問すれば良いのかが分かりました。

まだ使い慣れていないので分かりにくい点が多々あったとおもいますが、丁寧なご回答ありがとうございました。

今後も機会がありましたらご教授ください。