２行以上連続で追加行を増やしたい

Question

###実現したいこと

【要望】 データ管理をしているエクセルです。
社員データを追加したい場合、一番下の行に追加するのではなく、間に行を追加して入力していきたいのです。１行ずつ追加するのを可能になりました。
そこで、連続した２行を選択して２行新規で追加したい場合は、どうしたらよいでしょうか？？？

おわかりになる方いらっしゃいますでしょうか？

VBAは初心者です。

##流れ

╋━━━━━╋
┃行の削除 ┃→ボタン
╋━━━━━╋

列ｌＦｌ  Ｋ ｌ Ｌ  ｌ   Ｍ   ｌ   Ｎ    ｌ    Ｑ
----------------------------------------------------
 7ｌNo 表示順 社員番号 名前	   電話番号		  部屋番号
 8ｌ1	1	1212	花田 ○○子	99-9999-9999		S
 9ｌ2	2	7833	花田 ××子	99-9999-10000		A
10ｌ3	3	6137	花田 ○○男	99-9999-10001		B
11ｌ4	4	5773	花田 ××男	99-9999-10002		C
12ｌ5	1	5187	花田上 ○○子	99-9999-10003		D
13ｌ6	2	3587	花田上 ××子	99-9999-10004		E
14ｌ7	3	1799	花田上 ○○男	99-9999-10005		F
15ｌ8	4	7387	花田上 ××男	99-9999-10006		G
	

☆名前の欄や電話番号は、VLOOKUPで自動的に表示しています。

###該当のソースコード
'指定の行番号を調べる
For Each rng In Selection.Rows
Row(cnt) = rng.Row
cnt = cnt + 1
Next rng

    '行を追加する
    For cnt = 99 To 0 Step -1
        If Row(cnt) <> "" Then
            Rows(Row(cnt)).Copy
            Rows(Row(cnt)).Insert Shift:=xlDown
            .Range("K" & Row(cnt) & ":" & "L" & Row(cnt)) = ""
            .Range("O" & Row(cnt) & ":" & "X" & Row(cnt)) = ""
            .Range("L" & Row(cnt)).Select
        End If
    Next cnt
    

    
    'NOを振り直す
    Row_ALL = 1
    For i = 8 To Cells(Rows.Count, "H").End(xlUp).Row
        If .Range("H" & i).Value = "" Then
            Exit For
        End If
        
        If 配送エリア退避 <> .Range("H" & i).Value Then
            配送エリア退避 = .Range("H" & i).Value
            Row_CNT = 0
        End If
            
        .Range("F" & i).Value = Row_ALL
        .Range("K" & i).Value = Row_CNT
        Row_ALL = Row_ALL + 1
        Row_CNT = Row_CNT + 1
    
    Next

どうぞよろしくお願いいたします。

##補足

わかりにくくてすみません。。
行を追加するのは、できるのですが、
選択している行がどこかROWを取得するのが、できないのです。。。

Answer 1

例えば下記コードで 2 行追加できます。

Range("A1").Resize(2).EntireRow.Insert

2 行選択する状態を再現させるために Resize() 関数を使っています。

Comments

[haruto4649]

早速、お答えいただきありがとうございます。
ちなみに・・・
Resize関数で２行以上や複数（シフトキー）選択した場合は、どのようになるのでしょう？？？

なんどもすみません。。

Answer 2

選択されている行に空行を挿入したい、という質問であると認識して、下記回答致します。

Selection.Row.Insert

質問の意図を読み違えていたら、スルーして下さい。
よろしくお願いします。

---

追記確認致しました。

選択されている行数は以下で取得出来ます。
※イミディエイトウィンドウに表示されます。

Dim r As Variant
For Each r In Selection.Rows
  Debug.Print r.Row
Next r

また、例えば、選択されている行のC列に5を入れる場合は、

Dim r As Variant
For Each r In Selection.Rows
  r.Cells(3).value = 5
Next r

のようになります。

---

さらに追記確認しました。

上記と組み合わせてお使い頂ければある程度は対応できると思います。

' 選択範囲のコピー
Selection.Copy
' 選択範囲行数分の挿入
Selection.Insert
' 選択範囲の貼り付け
Selection.PasteSpecial

---

さらに、さらに追記確認しました。

BAが付いた後ですが、下記で出来ます。

' 関数名は適当です。
Sub test3()
    ' 選択されている行数を格納
    Dim col As New Collection
    Dim v As Variant
    For Each v In Selection.Rows
        col.add v.Row
    Next v
    ' 行数を昇順にソート
    Set col = getAscSort(col)
    Dim r As Variant
    Dim add As Long
    ' 選択されている行数はcolの中に入っているので
    ' ループで回しつつ上から順番に1行ずつコピーして貼り付けを繰り返す（※）
    For Each r In col
        r = r + add
        Rows(r).Copy
        Rows(r).Insert
        Rows(r).PasteSpecial
        add = add + 1
    Next r
End Sub

' ソート用関数 戻り値はCollection型
Function getAscSort(ByVal col As Collection) As Collection
    Dim result As New Collection
    Dim id As Long, i As Long
    Do Until (col.Count = 0)
        id = 1
        For i = 2 To col.Count
            If col(id) > (col(i)) Then
                id = i
            End If
        Next i
        result.add col(id)
        col.Remove id
    Loop
    Set getAscSort= result
End Function

Comments

[haruto4649]

Batoh33789さん。
早速、回答いただきありがとうございます！
行を挿入することはできるのですが、
ボタンを押す際に、どの行を選択しているかがわからないのです。。。

[Batoh33789]

こういうことでしょうか？

[haruto4649]

Batoh33789さま。
はい！できました！選択行を取得することができました！
ただ、、、その選択した行に、行を追加したい場合、
今選択した行をコピーして、コピーした内容を挿入という形にしたいのです。
Rows(r).Copy
では、コピーできませんでした。。。

[Batoh33789]

１．行を選択してコピー
２．行を挿入
３．１でコピーした内容を挿入したところに貼り付け
を実施したら上記の通りになりましたが、これであってますか？

[haruto4649]

Batoh33789さん！
出来ました～！！
すごいです！！
もう１点だけお尋ねしてもよろしいでしょうか？

１行や連続する２行の追加はできました。
ただ、シフトキーで、とびとびで選択した行で追加したい場合がうまくいかなかったのです。。。
何度もすみません。。。
お時間あるときでけっこうです。
よろしければ、教えてください。

[Batoh33789]

更新しました。上記ので恐らく動作するかと思います。
また※印部分の補足ですが、仮に選択されている行数が２，４，６行目だった場合
下記のような手順で行う必要があります。
１．2行目をコピー
２．2行目に空行を挿入
３．2行目に貼り付け
４．（元々は4行目だったが、2行目に1行増やしたので）5行目をコピー
５．5行目に空行を挿入
６．5行目に貼り付け
７．（元々は6行目だったが、2,5行目に1行増やしたので）8行目をコピー
・・・
といった形で進める必要があり、結果として上記のような形にしました。
かなりゴリ押しなので、他にも方法があるかもしれません。

[haruto4649]

Batoh33789さん。。。

本当に何度も何度もありがとうございました。
再度、ﾁｬﾚﾝｼﾞしてみます！
勉強されて、すごいです！
参考にさせていただきます！！
また、どうぞよろしくお願いいたします！