質問をすることでしか得られない、回答やアドバイスがある。

15分調べてもわからないことは、質問しよう!

ただいまの
回答率

90.48%

  • VBA

    2372questions

    VBAはオブジェクト指向プログラミング言語のひとつで、マクロを作成によりExcelなどのOffice業務を自動化することができます。

VBAでアンケート結果を振り分けたい

解決済

回答 2

投稿

  • 評価
  • クリップ 0
  • VIEW 2,467

michiaki

score 21

前提・実現したいこと

excelにてアンケート集計表を作成しています。
入力シートの各行の回答群を違うシートにコピーするVBAを書いていますがうまくいきません。

全シートはアンケート入力シートと各チーム(A~E)の振り分け後のシートと集計シートです。

各チームのシートの最終行にデータを入れ込むよう考えてます。
入力はランダムで書かれるのですが、別にそのシートでソートしてコピーが手っ取り早いとは思いますが
勉強であえて作っています。
3行目でのrangeでfor文のIを使って行をずらしつつ、コピー先を変えたいです。
今はコピーする行が固定なので、できそうなんですがfor文を入れるとどうしたらいいのかわかりません。

発生している問題・エラーメッセージ

自分の望む動作ができない

該当のソースコード

VBA

Sub copy()
    Dim i, n As Integer

    For i = 3 To 13
        If Worksheets("入力").Cells(i, 3).Value = "1.Aチーム" Then
        n = Worksheets("").Cells(Rows.Count, "A").End(xlUp).Row + 1
        Worksheets("入力").Range("d3:ag3").copy Destination:=Worksheets("Aチーム").Range("A" & n)

        ElseIf Worksheets("入力").Cells(i, 3).Value = "2.Bチーム" Then
        n = Worksheets("Bチーム").Cells(Rows.Count, "A").End(xlUp).Row + 1
        Worksheets("入力").Range("D3:ag3").copy Destination:=Worksheets("Bチーム").Range("A" & n)

        ElseIf Worksheets("入力").Cells(i, 3).Value = "3.Cチーム" Then
        n = Worksheets("Cチーム").Cells(Rows.Count, "A").End(xlUp).Row + 1
        Worksheets("入力").Range("D3:ag3").copy Destination:=Worksheets("Cチーム").Range("A" & n)

        ElseIf Worksheets("入力").Cells(i, 3).Value = "4.Dチーム" Then
        n = Worksheets("Dチーム").Cells(Rows.Count, "A").End(xlUp).Row + 1
        Worksheets("入力").Range("D3:ag3").copy Destination:=Worksheets("Dチーム").Range("A" & n)

        ElseIf Worksheets("入力").Cells(i, 3).Value = "5.Eチーム" Then
        n = Worksheets("Eチーム").Cells(Rows.Count, "A").End(xlUp).Row + 1
        Worksheets("入力").Range("D3:ag3").copy Destination:=Worksheets("Eチーム").Range("A" & n)

        End If
    Next i
End Sub

試したこと

rowやcells("d"&i:"AG"&i)等試しましたが、コンパイルエラーが出ます。

補足情報(言語/FW/ツール等のバージョンなど)

office365

  • 気になる質問をクリップする

    クリップした質問は、後からいつでもマイページで確認できます。

    またクリップした質問に回答があった際、通知やメールを受け取ることができます。

    クリップを取り消します

  • 良い質問の評価を上げる

    以下のような質問は評価を上げましょう

    • 質問内容が明確
    • 自分も答えを知りたい
    • 質問者以外のユーザにも役立つ

    評価が高い質問は、TOPページの「注目」タブのフィードに表示されやすくなります。

    質問の評価を上げたことを取り消します

  • 評価を下げられる数の上限に達しました

    評価を下げることができません

    • 1日5回まで評価を下げられます
    • 1日に1ユーザに対して2回まで評価を下げられます

    質問の評価を下げる

    teratailでは下記のような質問を「具体的に困っていることがない質問」、「サイトポリシーに違反する質問」と定義し、推奨していません。

    • プログラミングに関係のない質問
    • やってほしいことだけを記載した丸投げの質問
    • 問題・課題が含まれていない質問
    • 意図的に内容が抹消された質問
    • 広告と受け取られるような投稿

    評価が下がると、TOPページの「アクティブ」「注目」タブのフィードに表示されにくくなります。

    質問の評価を下げたことを取り消します

    この機能は開放されていません

    評価を下げる条件を満たしてません

    評価を下げる理由を選択してください

    詳細な説明はこちら

    上記に当てはまらず、質問内容が明確になっていない質問には「情報の追加・修正依頼」機能からコメントをしてください。

    質問の評価を下げる機能の利用条件

    この機能を利用するためには、以下の事項を行う必要があります。

回答 2

checkベストアンサー

+1

質問文から以下の通り解釈しました。

・1レコードはC列からAG列までに入力され、C列が振り分けのキーとなる「チーム名」である。
・レコード数がどのくらいになるかは分からない。
・C列のチーム名を見て、貼り付け先のワークシートを決める。
・貼り付け先ワークシートはA列から貼り付けたい。
・ただし、既に貼り付けられているものに追加する。
※「集計シート」はソースコードのどこにも出てこなかったので無視しています。

その前提でコードを書いてみました。(2016/11/6 14:10編集)

Sub Copy()
    Dim i As Integer
    Dim DstSheet As String
    Dim DstRows As Integer

    For i = 1 To Sheets("入力").Range("C1").CurrentRegion.Rows.Count
        Select Case Sheets("入力").Cells(i, 3).Value
        Case "1.Aチーム"
            DstSheet = "Aチーム"
        Case "2.Bチーム"
            DstSheet = "Bチーム"
        Case "3.Cチーム"
            DstSheet = "Cチーム"
        Case "4.Dチーム"
            DstSheet = "Dチーム"
        Case "5.Eチーム"
            DstSheet = "Eチーム"
        End Select

        DstRows = Sheets(DstSheet).Range("A1").CurrentRegion.Rows.Count + 1
        Sheets("入力").Range(Cells(i, 3), Cells(i, 33)).Copy Destination:=Sheets(DstSheet).Cells(DstRows, 1)
    Next
End Sub


ポイントは以下の通りです。

貼り付け元、貼り付け先でデータ行の範囲の末尾を取得するのにCurrentRegionを使っています。
これで貼り付け元のレコード数が増減しても問題ありません。

チーム名ごとの処理の分岐ですが、If/ElseIfがあまりに冗長なのでCase文を使っています。
貼り付け先シート名が異なるだけでやっていることは全て同じなので、貼り付け先シート名を変数化しています。

貼り付け先のセル番地取得にもCurrentRegionを使っています。
既にレコードが入っている行番号+1の場所に貼り付けるようにしています。

お困りだった「rowやcells("d"&i:"AG"&i)等」の部分の指定はコードをご覧ください。

※レコードはC列からAG列のようですが、転記は本当にD列からAG列なのでしょうか?(私のコードはC列からコピーする書き方にしています)
※Office365ではテストしていないです。済みません。Excel2013で確認してます。

投稿

編集

  • 回答の評価を上げる

    以下のような回答は評価を上げましょう

    • 正しい回答
    • わかりやすい回答
    • ためになる回答

    評価が高い回答ほどページの上位に表示されます。

  • 回答の評価を下げる

    下記のような回答は推奨されていません。

    • 間違っている回答
    • 質問の回答になっていない投稿
    • スパムや攻撃的な表現を用いた投稿

    評価を下げる際はその理由を明確に伝え、適切な回答に修正してもらいましょう。

  • 2016/11/06 10:37

    本当に実践的な書き方で教えて頂き、勉強になります。
    私の下手な説明を補完して、コード書いて頂き誠にありがとうございます。
    レコードはその通りD列からAG列までです。
    CurrentRegionは自分もネットで調べて使用していたのですが、”入力”シート全体が選択されるので、使い方が分かりませんでした。行だけ選択したい場合の使い方が分からなかったので、コードで使用していただいて知識が広がりました。

    実際入力したのですが,Dstrowsの値を取得する場所で、インデックスが有効範囲にありませんとでますが、私の範囲指定が間違ってるみたいです。
    本当はシートごと載せたかったのですが、わからなかったので・・・。
    もう少し勉強してうまく動くよう頑張ってみます。

    キャンセル

  • 2016/11/06 10:40

    Dstrowsの値が0になっているのは、範囲が間違っているからでしょうか?デバックモードでdstrowsにマウスを持っていくと0を指しています。うまく取得できていないみたいです。

    キャンセル

  • 2016/11/06 10:48

    CurrentRegionですが、基準セルを含む矩形範囲を選択します。
    なので、貼付先シートが空白でエラーになっているのかもしれません。
    貼付先シートの一行目をタイトルにするなどして、何か入力された状態にしてみてはいかがでしょうか。

    キャンセル

  • 2016/11/06 10:58

    少しお時間もらえればこちらでも確認してみます。

    キャンセル

  • 2016/11/06 14:15

    コード修正しました。
    "Sheets"と書くべきところを"Worksheets"となっていました。コピペミスです。済みません。
    また再確認したところ、貼り付け先シートの1行目には見出しを入れておかないと意図した通りに動かないので、そこはご注意いただければと思います。

    あと、D列からコピーの場合は

    Sheets("入力").Range(Cells(i, 3), Cells(i, 33)).Copy Destination:=Sheets(以下略)



    Sheets("入力").Range(Cells(i, 4), Cells(i, 33)).Copy Destination:=Sheets(以下略)

    としていただければと思います。

    ※今回もExcel2013で確認してます。

    キャンセル

  • 2016/11/08 18:19

    私の至らない質問に即した返答を頂き、また書き方まで指導していただいたのでynakanoさんをベストアンサーにさせて頂きます。

    キャンセル

+1

まずynakanoさん提示のCurrentRegionについての補足になりますが、これは入力されているデータ範囲を自動で特定してくれる便利な機能です。
便利な機能ではありますが、自動選択される範囲は指定セルを含む、空セルで囲まれた範囲、という仕様上の制約があります。

今回のデータシートが、例えば先頭行が見出し項目で空白なく埋められており、通し番号の列や必須項目の列があるため空行は存在しない、という状況なら問題なく取得できます。

A列  B列 C列 D列 E列 F列
==========================
No.  Q1  Q2  Q3  Q4  Q5
1    A1  A2      A4  A5
2    A1          A4  
3                A4  A5
4    A1  A2          A5
5    A1  A2      A4  A5


⇒A1セルの指定により、A1:F6のセル範囲が取得できます。

しかし、見出し行がなく、5項目中の3項目目でたまたま未入力が連続したデータなどでは、2項目目までしか範囲選択されなくなる可能性もありますのでご注意ください。

A列 B列 C列 D列 E列 F列
==========================
1   A1  A2      A4  A5
2   A1          A4  
3               A4  A5
4   A1  A2          A5
5   A1  A2      A4  A5


⇒A1セルの指定により、A1:C5のセル範囲しか取得されません。


上記のような制約があることから、私は「データが存在する範囲」の最終行を取得する場合の操作として.End(xlUp)をお勧めしています。

'C列の最終データ行までループ処理
For i = 1 To Sheets("入力").Cells(Sheets("入力").Rows.Count, "C").End(xlUp).Row
    '・・・(中略)
Next

補足ですが、.End(xlUp)も「指定した列の中で最下行の入力セルが取得できる」というだけで、「シート内の最終データ行」が取得できるわけではありません。

今回は必須項目と思われるチーム名の列がありますので、この列の.End(xlUp)で最終データを探せばよいと思います。
確実に目的のデータ範囲が取得できることがわかっているようでしたら、CurrentRegionを利用してもよいでしょう。

目的のデータ範囲が取得できるよう、データ範囲の選択方法を検討してください。

追記

私が動作確認したソースです。
ynakanoさん提示のソースに少し手を加えた内容です。

Dim shtRead As Worksheet
Set shtRead = Sheets("入力")

Dim iReadRow As Integer
Dim iWriteRow As Integer

Dim strShtName As String

'入力シートのデータをループ処理
For iReadRow = 3 To shtRead.Cells(Rows.Count, 3).End(xlUp).Row

    Select Case shtRead.Cells(iReadRow, 3).Value
    Case "1.Aチーム"
        strShtName = "Aチーム"

    Case "2.Bチーム"
        strShtName = "Bチーム"

    Case "3.Cチーム"
        strShtName = "Cチーム"

    Case "4.Dチーム"
        strShtName = "Dチーム"

    Case "5.Eチーム"
        strShtName = "Eチーム"

    Case Else
        strShtName = ""

    End Select

    'シート名が取得できたらコピーを行う
    If strShtName <> "" Then
        '出力シートの最終行+1を取得
        iWriteRow = Sheets(strShtName).Cells(Rows.Count, 1).End(xlUp).Row + 1
        '入力シートから出力シートへコピー
        shtRead.Range(shtRead.Cells(iReadRow, 3), shtRead.Cells(iReadRow, 33)).Copy Destination:=Sheets(strShtName).Cells(iWriteRow, 1)
    End If
Next

投稿

編集

  • 回答の評価を上げる

    以下のような回答は評価を上げましょう

    • 正しい回答
    • わかりやすい回答
    • ためになる回答

    評価が高い回答ほどページの上位に表示されます。

  • 回答の評価を下げる

    下記のような回答は推奨されていません。

    • 間違っている回答
    • 質問の回答になっていない投稿
    • スパムや攻撃的な表現を用いた投稿

    評価を下げる際はその理由を明確に伝え、適切な回答に修正してもらいましょう。

  • 2016/11/07 19:34

    下記のynakanoさんのプログラムを私のPCで入力し、debugしてみました。
    FOR文でのTO以下の記入されたデータを取得する部分のSheets("入力").Range("C3").CurrentRegion.Rows.Countではうまく動作しています。(チーム名が並んでいるだけなので、取得できています)
    CASE分のDstsheet名もうまく取得できています。
    次のDstRows = Sheets(DstSheet).Range("A1").CurrentRegion.Rows.Count + 1の部分が”インデックスが有効範囲に有りません”と表示されます。

    今再デバッグしてみたところ、currentRegionでもEnd(xlup)でも同じ値が取得できていますので、
    ここに問題はなさそうです。
    取得するデータが、行番号なので、私が勘違いしている可能性が高そうです。もう一度再チェックしてみます。

    キャンセル

  • 2016/11/07 20:03

    >次のDstRows = Sheets(DstSheet).Range("A1").CurrentRegion.Rows.Count + 1の部分が”インデックスが有効範囲に有りません”と表示されます。

    ynakanoさん提示のコードに私から回答するのも恐縮なのですが、”インデックスが有効範囲にありません”と言われるということは、コード中のどこかでコレクションから値が取得できなかったということです。

    上記コード内では`Sheets(DstSheet)`の部分か`Range("A1")`の部分がコレクションから値を探している部分ですが、Range("A1")がないということはあり得ませんので、`Sheets(DstSheet)`の部分の問題と思われます。
    DstSheetにはCase文により"Aチーム"などのシート名が格納されていると思いますが、エラーが発生する際、このシート名と(全角/半角等含めて完全に)一致するシート名が存在するか確認してみてください。

    >currentRegionでもEnd(xlup)でも同じ値が取得できていますので、ここに問題はなさそうです。

    現在使っているデータでは大丈夫そうですね。
    今後、「ある質問の回答が全データで未回答」のような状態になった場合でもcurrentRegionとEnd(xlup)が同じ動きをするようであれば問題ないと思います。
    試しに数件のサンプルデータを作成して、異常動作とならないか確認してみるといいですよ。

    キャンセル

  • 2016/11/07 21:30

    >jawaさん
    フォローありがとうございます(笑)

    >michiakiさん
    私の方でも試してみたのですが、貼り付け先シートに見出しがなかったとしても少なくともエラーにはなりませんでした。
    ただテストデータは私の想定で作成したものなので、差し支えなければデータを記載いただければと思います。

    キャンセル

  • 2016/11/07 22:27

    私もうまく皆さんに伝えられなくて申し訳ございません。
    デバッグを続けていたら、どうもrow.countは1048576を指していました。
    又xlup.lowは-4162を指していました。
    n = Sheets(DstSheet).Cells(Rows.Count, 1).End(xlUp).Rows
    Dstrows = Sheets(DstSheet).Cells(n, 1)
    多分ここらへんに原因があるかと思います。
    シートはc列にチーム名ですがデータは3行目からです。(ここら辺は修正してVBA的には問題ないと思います)
    CurrentRegion.Rows.Countのほうは私の技量不足でうまく取得できないみたいです。
    お手数かけてすいませんです。

    キャンセル

  • 2016/11/08 09:57

    >row.countは1048576
    Rows.Countは、Excelのシート上で利用できる最大行番号を返します。
    Excel2003までは65535でしたが、Excel2007以降は1048576になりました。

    >xlup.lowは-4162
    ⇒おそらくxlUpの値を見られたのだと思いますが、xlUpはExcelVBAで使える定数のひとつで、その値が-4162だということです。
    値自体に意味はありません。.End(-4162)と書いても同じ動作(Ctrl+↑)をしますが、覚えにくいですよね。
    それをわかりやすくするための定数xlUpです。

    どちらも異常値ではありません。

    n = Sheets("シート名").Cells(Rows.Count, 1).End(xlUp).Rows
    の意味を理解いただくために、少し解説しますね。

    ===
    まず、`Sheets("シート名")`の部分は、「対象シート」の指定です。

    次の`.Cells(Rows.Count, 1)`の部分は、「対象シート」のセルを座標で指定しています。
    前述のとおりRows.Countは最大行番号(つまりそのシートで利用できる最終行、シートの下端行)です。
    第2引数の1は列番号ですので、A列ということになります。

    つまり、`.Cells(Rows.Count, 1)`は「A列の最終行のセル」を指します。

    次の`.End(xlUp)`の部分は、先ほどの指定セル(A列最終行)からCtrl+↑カーソルを操作した位置を指します。
    実際にA列最終セルからCtrl+↑を入力してみると、下から探して最初に見つけたデータの入力されているセルに移動すると思います。
    この操作をVBAで行なっているというわけです。

    つまり、「A列のデータが入力されているセルの中で最下行のセル」を指します。

    最後の.Rowは、指定したセルの行番号を取得します。
    つまり、「A列のデータが入力されているセルの中で最下行のセルの行番号」ということです。

    まとめると、
    n = Sheets("シート名").Cells(Rows.Count, 1).End(xlUp).Rows
    は「A列のデータが入力されているセルの中で最下行のセルの行番号」を変数nに格納しているというわけです。

    目的の行が取得できているかを確認したいのであれば、nの値を確認しましょう。

    キャンセル

  • 2016/11/08 10:20 編集

    「インデックスが見つかりません」のエラーについては
    ①Case文で設定したシート名("Aチーム"~"Eチーム")と実際のシート名に差異がある
    ②Case文でどの分岐にも入らなかった(C列のチーム名が"1.Aチーム"~"5.Eチーム"のどれとも一致しなかった)
    いずれかの可能性が高いのではないかと予想しています。

    ①の場合、例えばC列が"1.Aチーム"だった場合に"Aチーム"という名称のシートを探しますが、実際に存在するシート名が"Aシート"(全角)とか"A シート"(間にスペース)のように完全に一致しないシート名になっているとシートが見つからずエラーが発生します。
    対応としては、実際のシート名またはCase文で指定しているシート名を修正し、一致させればよいです。

    ②の場合、空文字""のシート名を探すことになり、これもシート名が見つからずエラーが発生することになります。
    対応としては、Case文の条件を追加するか、Case文に一致しないデータはスキップする、などが考えられます。

    エラー発生時のシート名と、C列チーム名を確認してみてください。

    キャンセル

  • 2016/11/08 19:26

    すごく丁寧に説明して頂いているのに、ベストアンサーynakanoにして申し訳ございません。
    ベストアンサー2つ付けれたらいいのに・・・。

    コードでの質問なんですが、n = Sheets(DstSheet).Cells(Rows.Count, 1).End(xlUp).Rows
    でDstSheetにマウスをホバーさせると正しい値が表示されます。取得できています。
    なのできちんと働いていたらnには何らかの値が入ると思います。
    しかしnの値をマウスでホバーさせるとn=0と表示されます。
    行番号を得る式 Dstrows = Sheets(DstSheet).Cells(n, 1)ではn=0なので存在しないとなっているのでしょうか?
    シート名は、CASE文の文字列をコピーしているので、間違いはないと思います。もう一度見てみます。sheet番号がずれているのが気になりますが・・・。

    キャンセル

  • 2016/11/09 09:51

    >ベストアンサーynakanoにして申し訳ございません。
    BAもポイントもランキングもオマケ要素でしかないと思ってますので、そこは気になさらずに。(^-^)b
    今回の回答もynakanoさんの回答が主体で、私は補足させていただいているだけですので、ynakanoさんがBAでよかったと思っています。

    大切なのは質問者さんが納得のいく回答が得られることです。
    そういう意味では、納得のいく形で解決できるまでBAを決める必要はないと思いますよ(^_^;

    ===
    >n = Sheets(DstSheet).Cells(Rows.Count, 1).End(xlUp).Rows

    すみません。私もコードを実際に動かして回答していたわけではなかったため、ひとつ誤りがあることに気が付きませんでした。

    指定セルの行番号を取得するのは、.Rowsではなく.Rowです。
    (.Rowsは指定のセル範囲に含まれるRowのコレクションです)

    ```
    n = Sheets(DstSheet).Cells(Rows.Count, 1).End(xlUp).Row
    ```
    として動作させてみてください。

    私が動作確認したソース(ynakanoさんのソースに手を加えたもの)を回答に追記しておきます。
    ご参考までに。

    キャンセル

  • 2016/11/09 19:09

    有り難いご返事ありがとうございます。
    デバックをつづけた結果以下のようになりました。
    n = Sheets(DstSheet).Cells(Rows.Count, 1).End(xlUp).Row
    Dstrows = Sheets(DstSheet).Cells(n, 1).Row + 1
    ここまでは考えている値が取得できるところまできました。(式を分解して分かりやすくしただけです)
    Sheets("入力").Range(Cells(i, 4), Cells(i, 33)).copy Destinathion:=Sheets(DstSheet).Cells(Dstrows, 1)
    行も取得できあとコピーだけですが、アプリケーション定義又はオブジェクト定義のエラーです。と表示されます。
    全ての変数に自分の考えた値が入っているのに、エラーがでてきます。あと少しなんですが、式の中にエラーが含まれるように思えません。何か見落としているのでしょうか?

    キャンセル

  • 2016/11/09 19:26

    コピー部分のロジックはこちらで動作確認したときにもエラーが発生しました。
    その時のエラー原因は、Range内でのセル範囲指定でシートを明示していなかったことに起因していました。
    ```
    Sheets("入力").Range(Cells(i, 4), Cells(i, 33)).copy
    ```
    の部分を
    ```
    Sheets("入力").Range(Sheets("入力").Cells(i, 4), Sheets("入力").Cells(i, 33)).copy
    ```
    としてご確認ください。
    回答欄に提示したサンプルソースも、この対応も含めた記述になっていますのでご参考ください。

    キャンセル

  • 2016/11/10 20:13

    データが表示されるようになりました。少しバグみたいなのは残っていますが
    誠にありがとうございます。

    キャンセル

同じタグがついた質問を見る

  • VBA

    2372questions

    VBAはオブジェクト指向プログラミング言語のひとつで、マクロを作成によりExcelなどのOffice業務を自動化することができます。