どんな方法でフォームが閉じられても、入力途中のレコードが保存されないようにしたい

Question

実現したいこと

・フォームのbtn_閉じる（コマンドボタン）のクリック時
・フォーム自体の✕ボタン
・Access自体の✕ボタン

いずれの方法でフォームが閉じられても、フォームで入力途中のレコードがテーブルに保存されないようにしたい。

発生している問題・分からないこと

入力途中のレコードが保存されてしまう。

該当のソースコード

Private Sub Form_Unload(Cancel As Integer)

    If Me.Dirty Then
    
        Me.Undo
        
    End If
    
End Sub

Private Sub btn_閉じる_Click()

    DoCmd.Close

End Sub

試したこと・調べたこと

• teratailやGoogle等で検索した
• ソースコードを自分なりに変更した
• 知人に聞いた
• その他

上記の詳細・結果

レコードが保存されてしまう

補足

特になし

Comments

[sazi]

連結フォームですよね？
>フォームで入力途中のレコードがテーブルに保存されないようにしたい。
逆に保存される契機としているのは何で、そこではどのような処理をしていますか？

Answer 1

すでにコメントで指摘されてますがUnloadイベント時では更新は終了してますので手遅れですね。
更新を止めるにはフォームの更新前処理でイベントをキャンセルすることになります。

'フォームの更新前処理
Private Sub Form_BeforeUpdate(Cancel As Integer)
    Cancel = True
End Sub

これで、下記の場合でもレコード保存されません。

・フォームのbtn_閉じる（コマンドボタン）のクリック時
・フォーム自体の✕ボタン
・Access自体の✕ボタン

ただし、更新中に、フォーム自体の✕ボタン、Access自体の✕ボタンで閉じると「レコードを保存できません」というシステムメッセージが出ます。これを出したくない場合は、フォームの「エラー時」に下記のコードを設定します。

Private Sub Form_Error(DataErr As Integer, Response As Integer)
    If DataErr = 2169 Then
        Response = acDataErrContinue ’エラー メッセージを出さすに続行
    End If
End Sub

ただし、こうするといっさいレコード保存ができなくなります。それでは困りますよね。
そこで、「保存」ボタンを配置してそのクリック時にのみレコード保存できるようにします。

'保存ボタンクリック時
Private Sub cmd保存_Click()
    Me.BeforeUpdate = ""
    DoCmd.RunCommand acCmdSaveRecord
    Me.BeforeUpdate = "[イベント プロシージャ]"
End Sub

Comments

[sazi]

DoCmd.RunCommand acCmdSaveRecord
だと、対象が明確ではなく、どのような画面構成かも分かりませんので、
If Me.Dirty Then Me.Dirty = False
の方が良くありませんか？
まあ、ボタンクリックの処理なので、アクティブは限定されているとは言えそうですが。

[PyPyPython]

できました！

Answer 2

もし更新ボタンといったデータを更新するUIのみでデータの更新を行うというのであれば

Private Sub Form_BeforeUpdate(Cancel As Integer)
    If Me.Dirty Then
        DoCmd.RunCommand acCmdUndo
     End If
End Sub

といった感じでBeforeUpdateイベントでデータの更新をキャンセルするようにして
下記のように更新ボタンでの処理でBeforeUpdateイベントのイベントを無効⇒データ更新⇒BeforeUpdateイベントを有効といった処理を行えばいけるのではないでしょうか。

Private Sub btn_更新_Click()
    Me.BeforeUpdate = ""
    DoCmd.RunCommand acCmdSaveRecord
    Me.BeforeUpdate = "[イベント プロシージャ]"
End Sub

Comments

[PyPyPython]

できました！

Answer 3

単純に表の更新をキャンセルするのは？

Private Sub Form_Unload(Cancel As Integer)
    ' 保存をキャンセルする例
    If Me.Dirty Then
        Me.Undo
    End If
End Sub

Comments

[dodox86]

Form_Unloadでの例は、質問の「該当のソースコード」のところで同様のものが示されていませんでしょうか。
※入力しても終了の方法、タイミングでMe.Dirtyがセットされないケースがあるのかなと思って私も注視している質問です。
[脱字修正済み]

[YAmaGNZ]

ぱっと調べた感じではUnloadイベントが発生するタイミングでは更新が終わっているようです。
https://support.microsoft.com/ja-jp/topic/%E3%83%87%E3%83%BC%E3%82%BF%E3%83%99%E3%83%BC%E3%82%B9-%E3%82%AA%E3%83%96%E3%82%B8%E3%82%A7%E3%82%AF%E3%83%88%E3%81%AE%E3%82%A4%E3%83%99%E3%83%B3%E3%83%88%E3%81%AE%E9%A0%86%E5%BA%8F-e76fbbfe-6180-4a52-8787-ce86553682f9#bm3

BeforeUpdateイベントのタイミングでは閉じられる途中でのイベントなのかを認識できない為このイベント単独でも対応は難しいこととなります。
なのでBeforeUpdateイベントで更新前のデータを覚えておくなどして、Unloadイベント時に元に戻すといった処理になるのではないかと思われます。
BeforeUpdateイベント後にデータを確定するタイミングをどうすればいいのかはぱっと思いつきませんが・・・

[MasahikoHirata]

失礼しました。
変な回答になってしまい申し訳ございません。

もっと考えてみます。

[PyPyPython]

だめでした！