複数条件で絞り込む検索ボタンを作成したい

Question

実現したいこと

商品名・メーカー名の複数条件でレコードを抽出したい

前提

非連結のテキストボックス（①商品名から検索_txb、②メーカー名から検索_txb)に入力した文字を含むレコードを抽出する検索ボタンを持つフォームを作成しています。現行のプログラムでは、商品名テキストボックスを入力するとメーカー名テキストボックスがクリアされ、メーカー名テキストボックスを入力すると商品名テキストボックスがクリアされ
、1種類の抽出条件でしか絞り込めないようになっています。こちらのプログラムを変更し、商品名・メーカー名のand検索を出来るようにしたいです。

発生している問題・エラーメッセージ

こちらのサイトを参考にコードを記述しましたが、検索ボタンをクリックしてもレコードの絞り込みが行われませんでした。

該当のソースコード

Private Sub 検索_Click()

    Dim filter_txt As String
    
    If Me!商品名から検索 <> "" Then
    
        If filter_txt = "" Then
        
            filter_txt = "商品名 like '*" & Me!商品名から検索 & "*'"
            
        Else
        
            filter_txt = filter_txt & "and 商品名 like '*" & Me!商品名から検索 & "*'"
            
        End If
    
    End If
    
    If Me!メーカー名から検索 <> "" Then
    
        If filter_txt = "" Then
        
            filter_txt = "メーカー名 like '*" & Me!メーカー名から検索 & "*'"
            
        Else
        
            filter_txt = filter_txt & "and メーカー名 like '*" & Me!メーカー名から検索 & "*'"
            
        End If
        
    End If
    
End Sub

試したこと

上記コードを試しました。商品名から検索する部分の記述だけでテストした際は正常に絞り込みが行われましたが、メーカー名から検索する部分を記述してテストしたところ、検索ボタンを押してもレコードの絞り込みが行われませんでした。

補足情報（FW/ツールのバージョンなど）

MicrosoftAccess2019

Answer 1

提示のコードは変数filter_txtに抽出条件式を代入するコードです。
それだけでは、何も起こりません。
その条件をフォームに適用するコードが必要です。

抽出結果を表示するフォームのフォームヘッダーかフッターに抽出条件を入力する非連結テキストボックスがあるのなら、自身のフォームに抽出条件を適用する必要があります。
参考にしたリンク先のコードの最後のIf文の部分がフォームに抽出条件を適用するコードになります。
下記の部分です。

    Me.Filter = filter_txt
    Me.FilterOn = True

抽出条件の生成は提示のコードでうまくできていますので、とりあえずは、このコードを最後に追加すれば絞り込みができるはずです。

---

ちなみに、自分が書くなら下記のようなコードになります。

Private Sub 検索_Click()
    Dim filter_txt As String
    
    If Me!商品名から検索 <> "" Then
        filter_txt = " and 商品名 like '*" & Me!商品名から検索 & "*'"
    End If
    
    If Me!メーカー名から検索 <> "" Then
        filter_txt = filter_txt & " and メーカー名 like '*" & Me!メーカー名から検索 & "*'"
    End If
    
    Me.Filter = Mid(filter_txt, 6) '先頭の余分な" and "を削除してFilterプロパティに代入
    
    If filter_txt = "" Then
        Me.FilterOn = False 'フィルター解除
    Else
        Me.FilterOn = True 'フィルター適用
    End If
    
End Sub

Comments

[退会済みユーザー]

提示していただいた2行のコードを追加したら動作しました！
スマートな記述の例も提示していただきありがとうございました！！

Answer 2

上記コードを試しました。
商品名から検索する部分の記述だけでテストした際は正常に絞り込みが行われましたが、

掲載されているイベントプロシージャ内のどこにも、そのフォームのFilterプロパティおよびFilterOnプロパティの値を設定するコードが記述されていませんので、そのプロシージャによってフォームフィルターが実行されるはずなどないのですが。

Private Sub 検索_Click()

    Dim filter_txt As String

    If Nz(Me![商品名から検索].Value) <> "" Then
        filter_txt = filter_txt & " and [商品名] like '*" & Replace(Me![商品名から検索].Value, "'", "''", , , vbBinaryCompare) & "*'"
    End If

    If Nz(Me![メーカー名から検索].Value) <> "" Then
        filter_txt = filter_txt & " and [メーカー名] like '*" & Replace(Me![メーカー名から検索].Value, "'", "''", , , vbBinaryCompare) & "*'"
    End If

    filter_txt = Mid(filter_txt, 6)

    Me.Filter = filter_txt
    Me.FilterOn = (filter_txt <> "")

End Sub

Comments

[退会済みユーザー]

フィルターが実行されたと思いましたが、商品名から検索テキストボックスの更新後処理にも絞り込み用のコードを記述しており、そちらが実行されていただけでした！お騒がせ致しました。

[sk.exe]

> 商品名から検索テキストボックスの更新後処理に記述していたコードが実行されていただけでした

それぞれのテキストボックスの[更新後処理]イベントが発生した際に同じフィルター処理を実行したい、ということなのであれば、フィルター処理を実行するSubプロシージャを別途設けておき、各イベントからCallするようになさればよろしいでしょう。

[退会済みユーザー]

まさにそうです！
Callで呼び出せるように記述して実行試してみます！
ありがとうございました