【Word VBA】表のセル内に画像があるか確認したい

Question

実現したいこと

Word VBAにて、表の各セル内に画像があるか確認したいです。

セル内のテキスト取得は調べて出てくるのですが、
オブジェクトの取得・判定については情報がなく、お力添えをいただきたいです。

該当のソースコード

Sub test()

Dim tbl as Table
Dim cel as Cell
Dim txt as String

'表を走査
For Each tbl In ActiveDocument.Tables

'表のセルを走査
    For  Each cel In tbl.Range.Cells

'セル内のテキスト取得方法を例示
'本来はここで、セル内に画像が含まれるかの判定を行いたい
        txt = cel.Range.Text

    Next cel
Next tbl

End Sub

補足情報（FW/ツールのバージョンなど）

Windows10
Word Microsoft 365 バージョン2311

Answer 1

Word VBAにて、表の各セル内に画像があるか確認

• ある文字列範囲に含まれる「文字列レイヤーの図形（ InlineShape オブジェクト）」の個数を調べたい場合は Range オブジェクトの InlineShapes プロパティが返す InlineShapes オブジェクト（コレクション）の Count プロパティの値を参照する。

• 更に検索対象となる図形の種類を「図（静止画像）」に限定したい場合は、InlineShapes オブジェクト（コレクション）の個々のアイテム（ InlineShape オブジェクト）の Type プロパティの値によって判別する。

Sub Test2()

    Dim tbl As Table
    Dim cel As Cell
    Dim ishp As InlineShape

    For Each tbl In ActiveDocument.Tables
        For Each cel In tbl.Range.Cells
            Set ishp = FindFirstInlinePicture(cel.Range)
            If Not ishp Is Nothing Then
                ishp.Select
                Exit Sub
            End If
        Next cel
    Next tbl

    MsgBox "このドキュメント内のテーブルに静止画像は挿入されていません。", _
           vbInformation, _
           "検索完了"

End Sub

Function FindFirstInlinePicture(Target As Word.Range) As Word.InlineShape

    If Target.InlineShapes.Count = 0 Then
        Exit Function
    End If
    
    Dim ishp As Word.InlineShape
    
    For Each ishp In Target.InlineShapes
        Select Case ishp.Type
            Case wdInlineShapePicture, _
                 wdInlineShapeLinkedPicture, _
                 wdInlineShapePictureHorizontalLine, _
                 wdInlineShapeLinkedPictureHorizontalLine
                
                Set FindFirstInlinePicture = ishp
                Exit Function
            
            Case Else
                '何もしない
        
        End Select
    Next

End Function

Comments

[netz-eng]

ご回答ありがとうございます。
cel.Range内のInlineShape確認で、有無を判定することができました。