ACCESS VBAを用いて最上階層の親フォームを閉じたい。

Question

閲覧頂きありがとうございます。

AccessでVBAを用いて最上階層の親フォーム（親がN）を閉じ方はありますか？
また、ある場合ヒントでよいのでご教示頂ければと思います。

'// 親->子の場合は、以下でフォームを閉じる
DoCmd.Close acFrom, Me.Parent.Name

'// 親->親->子の場合は？

Answer 1

すでに提案されてますが、
やはりParent がエラーになるまでループで遡るというのがシンプルだと思います。

    Dim pfrm As Form

    Set pfrm = Me

    On Error Resume Next
    Do Until Err.Number <> 0
        Set pfrm = pfrm.Parent
    Loop
    On Error GoTo 0

    DoCmd.Close acForm, pfrm.Name

※コメントで指摘を受けた部分を修正しました。

Comments

[nakit]

私も真っ先に思いついたのはエラーまで辿る方式でした。
ただ、On Error Resume Next を使用する場合、その後 On Error Goto 0 をするなど考慮しないと他のエラーを無視してしまう可能性があります。
特定のエラーのみトラップするという考え方は、そのような副作用の考慮が面倒であり個人的にはシンプルでないため、次善策をあげさせて頂いた次第です。

また動作には影響しませんが Err <> 0 は Err.Number <> 0 とした方が個人的には分かり易いです。
一見、型が異なるものを比較しているように見える人もいるかも知れませんし、Numberが既定のプロパティだと知らない人もいるかも知れませんので。

[hatena19]

規定のプロパティを省略するかどうかは、プログラマーの好みですが、
確かに、厳密性、可読性を重視するなら省略しないほうがいいですね。

On Error Resume Next は使う場合は、最小限の範囲に止めて、最後に
On Error Goto 0 でリセットしておくべきというのはそのとおりだと思います。

できれば、On Error Resume Next はさけて、Err.Number で場合分けしてエラー処理すべきですが、今回は、Set pfrm = pfrm.Parent の1行だけですのエラー無視しても、
悪影響はないかなと考えてます。

Answer 2

Parentプロパティの値がエラーとなるまで判定する方法も考えられますが、
以下のようにApplication全体の最上位フォームに含まれているかで判定する方法はいかがでしょうか。

Dim frmTops As Forms    '最上階層フォーム一覧
Dim frmTop  As Form     '最上階層フォーム候補
    
    Set frmTops = Application.Forms
    Set frmTop = Me
    Do
        '候補のフォームが最上階層フォーム一覧に含まれていればループを抜ける
        For Each frmWatch In frmTops
            If frmTop Is frmWatch Then
                Exit Do
            End If
        Next
        
        '含まれていなければ親フォームを候補とする
        Set frmTop = frmTop.Parent
        
    Loop
    
    '最上階層フォームを閉じる
    DoCmd.Close AcObjectType.acForm, frmTop.Name