Excel_VBAのフォントの色コピーを教えて下さい。

Question

Excel_VBAのフォントの色コピーを教えて下さい。
'(参考)クリップボードを使わないセルのCopy｜ExcelマクロVBA技術解説
'http://excel-ubara.com/excelvba4/EXCEL254.html
'----------------------------------------------------------------------------------------
'セルの文字(一部だけ色)をコピーする。
'入力
'A列1行 '123
'2だけ赤色,1と3は黒色
'出力実行結果
'B列1行 '123全部黒色になります。
'Charactersの使い方を教えて下さい。よろしくお願いします。
'
Sub sample()
Call sample_sub(Range("A1:A7"), Range("B1"))
End Sub
Sub sample_sub(fromRange As Range, toRange As Range)
Dim s As String
Dim i As Long
Dim j As Long
For i = 1 To fromRange.Rows.Count
For j = 1 To fromRange.Columns.Count
toRange.Cells(i, j).Value = fromRange.Cells(i, j).Value
For k = 1 To Len(fromRange.Cells(i, j).Value)
toRange.Cells(i, j).Characters(k, k).Font.ColorIndex = fromRange.Cells(i, j).Characters(k, k).Font.ColorIndex
Next
Next
Next
End Sub

Answer 1

使い方

Charactersの使い方は以下に記載されています。
⇒Range.Characters プロパティ (Excel)

原因

上記ページを見ていただければわかると思いますが、引数の1つ目が文字列の取得位置、2つ目が取得する長さとなっています。

今回の処理では、文字列から文字を１文字ずつ取得して文字色を写していきたいのだと思いますが、提示いただいたコードでは、
fromRange.Cells(i, j).Characters(k, k).Font.ColorIndex
のように2つ目の引数まで変数ｋの値としてしまっています。

これだと、仮にセルの値が"ABCDEFG"という文字列だった場合に
kループ1回目：Characters(1, 1)⇒"A"
kループ2回目：Characters(2, 2)⇒"BC"
kループ3回目：Characters(3, 3)⇒"CDE"
・・

といった具合に、取得する文字列の長さも増えていってしまいます。

例えばループ２週目で取得した文字列"BC"がともに赤ならFont.ColorIndexは赤(3)を取得できますが、BとCで色が異なる場合はFont.ColorIndexはNullとなり、結果的に黒文字として反映されてしまいます。

改修コード

期待する動作とするためには、問題の部分を以下のように修正すればよいと思います。

toRange.Cells(i, j).Characters(k, 1).Font.ColorIndex = fromRange.Cells(i, j).Characters(k, 1).Font.ColorIndex
```
ご確認ください。

Comments

[mrrclb48z]

式.Characters(Start, Length)
ありがとうございました。

Answer 2

一文字ずつ処理していくコードに見えますので期待する動作は以下ではないでしょうか。

誤：
toRange.Cells(i, j).Characters(k, k).Font.ColorIndex = fromRange.Cells(i, j).Characters(k, k).Font.ColorIndex

正：
toRange.Cells(i, j).Characters(k, 1).Font.ColorIndex = fromRange.Cells(i, j).Characters(k, 1).Font.ColorIndex