windows7でsbtコマンドを実行するとコンソール上にsbtconfig.txtが見つからないというエラーが出るので、sbtファイルを探しましたが無いので困っています！

Question

###前提・実現したいこと
python,scala超初心者でございます。
windows7環境下で、競馬情報をスクレイピングする目的でstockedge/netkeiba-scraper を起動させるために、
sbt "run collecturl"という、sbtコマンドを実行させたところ、下記のような
エラーメッセージが返ってきました。

###発生している問題・エラーメッセージ

Microsoft Windows [Version 6.1.7601]
Copyright (c) 2009 Microsoft Corporation.  All rights reserved.

C:\Users\satoru>cd horse

C:\Users\satoru\horse>cd netkeiba-scraper-master

C:\Users\satoru\horse\netkeiba-scraper-master>sbt "run collecturl"
ファイル C:\Users\satoru\horse\netkeiba-scraper-master\\..\conf\sbtconfig.txt が見つかりません。
Getting org.scala-sbt sbt 0.13.5 ...
downloading http://repo.typesafe.com/typesafe/ivy-releases/org.scala-sbt/sbt/0.13.5/jars/sbt.jar ...

        [SUCCESSFUL ] org.scala-sbt#sbt;0.13.5!sbt.jar (4134ms)

###該当のソースコード

ここにご自身が実行したソースコードを書いてください

###試したこと
このことについて、少し調べたところ、以下のようなことを書いてあるサイトを見つけました。

Windowsのsbtスクリプトは、sbtconfig.txtを使っていない。

sbtコマンドを実行するとコンソール上にsbtconfig.txtが見つからないというエラーが出ていると思います。

sbtconfig.txtの設定値を有効にするため、sbtファイルの以下の個所を修正する。
•143行目辺りのコメントアウトされたJAVA_OPTSをアンコメントする。
•WDIR変数が宣言されていないので、「WDIR=${sbt_home}」をJAVA_OPTSの行より前に追加する。
•JAVA_OPTS中のsbtconfig.txtのパスに「/conf」を追加する。

sbt\bin\sbt

-- Windows behavior stub'd
WDIR=${sbt_home}
JAVA_OPTS=$(cat "$WDIR/conf/sbtconfig.txt" | sed -e 's/\r//g' -e 's/^#.*$//g' | sed ':a;N;$!ba;s/\n/ /g')

・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・
試してみようと思いましたが、**該当してそうなsbtファイルが、stockedge/netkeiba-scraperの中に見つかりません。
sbtファイルは、build.sbt位しか、なく、このファイルの中身を見ても、**143行目もあるようなファイルではありませんでした。
stockedge/netkeiba-scraper ファイルから、build.sbt以外の該当するsbtファイルの場所、
探し方を御教示いただきたく思っております。

よろしくお願いいたします。

###補足情報(言語/FW/ツール等のバージョンなど)
python2.7 scala sbt

Answer 1

実行したコードを何も示していないため、この質問を読んで回答しようと思う人はほとんどいないでしょう。stockedge/netkeiba-scraper を検索してみたらgithubにコードがあったので調べてみましたが、質問者さんが使用したものと同じコードかどうかは知りません。

https://github.com/stockedge/netkeiba-scraper

netkeiba-scraper
├─src
│  └─main
│      └─scala
│          └─netkeiba-scraper
│              └─Main.scala
├─.gitignore
├─analyze.R
├─build.sbt
├─race_url.txt
├─README.md
├─sbt-launch.jar
├─sbt.bat
└─sqlite3.exe

以下の通り実行してみた。

> git clone [e-mail]:stockedge/netkeiba-scraper.git
> cd netkeiba-scraper
> sbt "run collecturl"

ファイル C:\Users\Public\repos\git\netkeiba-scraper\\..\conf\sbtconfig.txt が見つかりません。

実行したファイル（sbt.bat）の内容は以下の通り。

≪省略≫
 12 @echo off
 13 set SBT_HOME=%~dp0
 14
 15 rem FIRST we load the config file of extra options.
 16 set FN=%SBT_HOME%\..\conf\sbtconfig.txt
 17 set CFG_OPTS=
 18 FOR /F "tokens=* eol=# usebackq delims=" %%i IN ("%FN%") DO (
 19   set DO_NOT_REUSE_ME=%%i
 20   rem ZOMG (Part #2) WE use !! here to delay the expansion of
 21   rem CFG_OPTS, otherwise it remains "" for this loop.
 22   set CFG_OPTS=!CFG_OPTS! !DO_NOT_REUSE_ME!
 22 )
≪省略≫

13行でsbt.batの格納フォルダをSBT_HOMEに設定している。
16行でリポジトリ管理外のファイル..\conf\sbtconfig.txtを参照してエラーになっている。

sbt.batの内容から..\conf\sbtconfig.txtにはsbt用のjavaオプションが記入してあると考えられますが、実際の内容は作成者に問い合わせないとわかりません。

【参考】

自分で使用しているsbt.batの起動ファイルを使用して.\sbt.bat "run collecturl"が動くことだけ確認してみました。

@echo off
set SCRIPT_DIR=%~dp0

set SBT_OPTS=-Xms256M -Xmx512M -Xss1M
set SBT_OPTS=%SBT_OPTS% -XX:MaxMetaspaceSize=256M -XX:ReservedCodeCacheSize=64M
set SBT_OPTS=%SBT_OPTS% -XX:+CMSClassUnloadingEnabled -XX:-UseGCOverheadLimit
set SBT_OPTS=%SBT_OPTS%  -Dinput.encoding=Cp1252

set SBT_JAR="%SCRIPT_DIR%sbt-launch.jar"

java %JAVA_OPTS% %SBT_OPTS% -jar %SBT_JAR% %*

Comments

[akakage13]

tkmtmkt様、はじめまして、こんばんは、
御教示くださりまして、本当にありがとうございます。

小生、初心者のため、今一度、御教示していただきたいです。

sbt.bat の　どの部分を変更したら、\..\conf\sbtconfig.txt が見つかりません。が
クリアーされるのでしょうか。

下記にソースコードを貼り付けますので、訂正箇所を御教示いただけますと幸いです。
よろしくお願いいたします。EmEditorからコピペしております。

@REM SBT launcher script
@REM
@REM Envioronment:
@REM JAVA_HOME - location of a JDK home dir (mandatory)
@REM SBT_OPTS - JVM options (optional)
@REM Configuration:
@REM sbtconfig.txt found in the SBT_HOME.

@REM ZOMG! We need delayed expansion to build up CFG_OPTS later
@setlocal enabledelayedexpansion

@echo off
set SBT_HOME=%~dp0

rem FIRST we load the config file of extra options.
set FN=%SBT_HOME%\..\conf\sbtconfig.txt
set CFG_OPTS=
FOR /F "tokens=* eol=# usebackq delims=" %%i IN ("%FN%") DO (
set DO_NOT_REUSE_ME=%%i
rem ZOMG (Part #2) WE use !! here to delay the expansion of
rem CFG_OPTS, otherwise it remains "" for this loop.
set CFG_OPTS=!CFG_OPTS! !DO_NOT_REUSE_ME!
)

rem We use the value of the JAVACMD environment variable if defined
set _JAVACMD=%JAVACMD%

if "%_JAVACMD%"=="" (
if not "%JAVA_HOME%"=="" (
if exist "%JAVA_HOME%\bin\java.exe" set "_JAVACMD=%JAVA_HOME%\bin\java.exe"
)
)

if "%_JAVACMD%"=="" set _JAVACMD=java

rem We use the value of the JAVA_OPTS environment variable if defined, rather than the config.
set _JAVA_OPTS=%JAVA_OPTS%
if "%_JAVA_OPTS%"=="" set _JAVA_OPTS=%CFG_OPTS%

:run

"%_JAVACMD%" %_JAVA_OPTS% %SBT_OPTS% -cp "%SBT_HOME%sbt-launch.jar" xsbt.boot.Boot %*
if ERRORLEVEL 1 goto error
goto end

:error
@endlocal
exit /B 1

:end
@endlocal
exit /B 0

[tkmtmkt]

回答の【参考】に記載したsbt.batを使用してみてください。

元のファイルについては、必要な情報（sbtconfig.txt）が不足していることが問題なので、作成者に連絡して修正してもらうのがよいです。https://github.com/stockedge にメールアドレスが記載されています。

あと、タグに「Python 2.7」がついてますが、関係ないようなので外しておいたほうがよいと思います。Javaを使用するので代わりに「Java」を付けておくとよいです。

[akakage13]

tkmtmkt様、こんばんは、いつもありがとうございます。

早速【参考】のsbt.batを差し替えて、試しましたところ、以下のようなエラーが出てまいりました。

C:\Users\satoru\horse\netkeiba-scraper-master>sbt "collecturl"
Error occurred during initialization of VM
Could not reserve enough space for 1572864KB object heap

C:\Users\satoru\horse\netkeiba-scraper-master>

恐縮ではございますが、再度の御教示をよろしくお願いいたします。

失礼します。

[tkmtmkt]

メモリ不足のメッセージです。回答欄のスクリプトを修正しました。

自分のPCのメモリサイズは8MBなので、多めに割り当てていましたが、本件の対象プログラムはそれほどメモリを使用しないものなので、メモリ割り当てを小さくしました。

※わざわざBATファイルにしなくても、以下のように直接javaコマンド実行してもデフォルト設定のパラメータで動くようです。

java -jar .\sbt-launch.jar "run collecturl"

[akakage13]

tkmtmkt様、無事に動き始めました。

今回は、数回にわたります、懇切丁寧な御教示、本当にありがとうございました。
とても感謝しております。

今後とも、よろしく御指導お願いいたします。
重ねて御礼申し上げます。