ExcelVBAのFunctionを利用して、コマンドボタンを有効にしたい

Question

Excel VBAについて

ユーザーフォームで
名前⇒txtTextBox1
年齢⇒txtTextBox2
電話番号⇒txtTextBox3

上記のTextBoxに、全て値が入ったら、コマンドボタンを押せるようにしたいです。

入力漏れを判定

Public Function 入力漏れ無() As Boolean
Dim myCtrl As Control
For Each myCtrl In Me.Controls
If myCtrl.Name Like "txt*" Then
If Len(myCtrl.Value) = 0 Then
入力漏れ無 = True
End If
End If
Next

入力漏れ無 = False
End Function

3つのテキストボックスの値が変わったときの判定

Sub textbox_change()
Dim myCtrl As Control

For Each myCtrl In UserForm1.Controls
If myCtrl.Name Like "txt*" Then
EnableCB1Button myCtrl.Name
End If
Next
End Sub

コマンドボタンを押す判定

Private Sub EnableCB1Button(ByVal txtData As String)
Dim myCtrl As Control
For Each myCtrl In Me.Controls

If Len(txtData) = 0 Then
CB1 = False
ElseIf 入力漏れ無 = False Then

CB1.Enabled = True
End If
Next
End Sub

どうしてもコマンドボタンが有効になりません。

どこを修正するのが、お手数ですが、ご教示をお願いします。

Answer 1

Private Sub txtTextBox1_Change()
CB1.Enabled = 入力漏れ無
End Sub
この部分ですが、TextBoxの数だけ、書かなければならないのでしょうか？

既に、解決済みですが
この部分を１か所にまとめる方法です。
ただし、ほかの記述が増えるので、TextBoxが３個では、割に合わないかもしれません。
（１００個ほどあるならありがたみがあるかと）

１．クラスジュール（Class1とします）へ以下を記述

Option Explicit
'複数イベントを１つにまとめる
Private WithEvents TextEv As MSForms.TextBox

Public Sub NewClass(ByVal Tbox As MSForms.TextBox)
    'コンストラクタ処理
    Set TextEv = Tbox
End Sub
Private Sub TextEv_Change()
    Call CB1Enable
End Sub

２．標準モジュールへ以下を記述

Option Explicit

Public Sub CB1Enable()
    UserForm1.CB1.Enabled = 入力漏れ無
End Sub

Public Function 入力漏れ無() As Boolean
    Dim myCtrl As Control
    入力漏れ無 = True
    For Each myCtrl In UserForm1.Controls
        If myCtrl.Name Like "txt*" Then
            If Len(myCtrl.Value) = 0 Then
                入力漏れ無 = False
                Exit Function
            End If
        End If
    Next
End Function

３．フォームモジュールへ以下を記述します。フォーム名は UserForm1とします。

Option Explicit


Private NumText(1 To 3) As New Class1

Private Sub UserForm_Initialize()
    'インスタンスの生成
    Dim i As Long
    For i = 1 To 3
        NumText(i).NewClass Controls("txtTextBox" & i)
    Next
End Sub

以上で、期待した結果になるかと思います。

Comments

[ikedaikegami]

思い通りの結果になりました。
本当にありがとうございました。

Answer 2

ユーザーフォームのモジュールに下記でどうでしょう。

Option Explicit

Private Sub UserForm_Initialize()
    CB1.Enabled = False 'コマンドボタンを使用不可に(プロパティで設定してあるなら不要)
End Sub

Private Sub txtTextBox1_change()
    EnableCB1Button
End Sub

Private Sub txtTextBox2_change()
    EnableCB1Button
End Sub

Private Sub txtTextBox3_change()
    EnableCB1Button
End Sub

Private Sub EnableCB1Button()
    Dim Ctl As Control
    CB1.Enabled = True
    For Each Ctl In Me.Controls
        If Ctl.Name Like "txt*" Then
            If Ctl.Value = "" Then
                CB1.Enabled = False
                Exit For
            End If
        End If
    Next
End Sub

Answer 3

セルが変更された場合に実行したいということであれば、シートモジュールに以下のように記載していただければ動いてくれます。
Worksheet_Changeで変更されたことを検知して、Target.Name.Nameでセル名を取得、比較して対象であれば処理が動くという書き方になります。

Private Sub Worksheet_Change(ByVal Target As Range)
  '変数の宣言
  If Target.Name.Name Like "txt*" Then
    '実行したい処理
  End If
End Sub

Comments

[ikedaikegami]

回答ありがとうございました。

[ikedaikegami]

回答ありがとうございました。

Answer 4

Option Explicit
Public Function 入力漏れ無() As Boolean
Dim myCtrl As Control
入力漏れ無 = True
For Each myCtrl In Me.Controls
If myCtrl.Name Like "txt*" Then
If Len(myCtrl.Value) = 0 Then
入力漏れ無 = False
Exit Function
End If
End If
Next
End Function

Private Sub txtTextBox1_Change()
CB1.Enabled = 入力漏れ無
End Sub

Private Sub txtTextBox2_Change()
CB1.Enabled = 入力漏れ無
End Sub

Private Sub txtTextBox3_Change()
CB1.Enabled = 入力漏れ無
End Sub

Comments

[ikedaikegami]

回答ありがとうございます。

Private Sub txtTextBox1_Change()
CB1.Enabled = 入力漏れ無
End Sub

Private Sub txtTextBox2_Change()
CB1.Enabled = 入力漏れ無
End Sub

Private Sub txtTextBox3_Change()
CB1.Enabled = 入力漏れ無
End Sub

この部分ですが、TextBoxの数だけ、書かなければならないのでしょうか？
お手すきの時に回答いただけたら幸いです。

[yorozuya]

基本的にはそうなります。

[ikedaikegami]

ありがとうございました。