F#の文字の色の変更方法

Question

###前提・実現したいこと
F#初心者です
4つの数字を入力して平均より下の数字を赤く表示するものを作ろうとしています
C#と同じ感覚だとできなかったのでだれか助けて下さい・・・

###発生している問題・エラーメッセージ

このletに続くブロックが完了していません。式が必要です。

###該当のソースコード

open System

let a=double(Console.ReadLine())
let b=double(Console.ReadLine())
let c=double(Console.ReadLine())
let d=double(Console.ReadLine())
let e=(a+b+c+d)/4.0

if(e>a)  then let←ここ p =Console.ForegroundColor = ConsoleColor.Red

System.Console.WriteLine(a)       
  
以下同じ事の繰り返し

###試したこと
一応
val it : unit=()
を使ったりはしましたが上手くいきません
どうしたらいいでしょうか

###補足情報(言語/FW/ツール等のバージョンなど)
Visual Studio２０１５を使っています

Answer 1

open System
[<EntryPoint>]
let main argv = 
    let a = double(Console.ReadLine())
    let b = double(Console.ReadLine())
    let c = double(Console.ReadLine())
    let d = double(Console.ReadLine())
    let e = (a+b+c+d)/4.0

    if(e>a) then
        Console.ForegroundColor <- ConsoleColor.Red //F#で再代入は"<-"

    a |> printfn "%A"

    Console.ReadLine() |> ignore //待機用
    0

ただ、平均より下を赤くする(以上なら別の色)ということなら
これだと一度赤になったらなりっぱなしなので
工夫してください

こんな感じ?

open System
[<EntryPoint>]
let main argv = 


    let a = double(Console.ReadLine())
    let b = double(Console.ReadLine())
    let c = double(Console.ReadLine())
    let d = double(Console.ReadLine())
    let avg = (a+b+c+d)/4.0

    let disp x =
        let color x =
            match avg < x with
            | true ->  ConsoleColor.White
            | false -> ConsoleColor.Red
        Console.ForegroundColor <- color x
        x |> printfn "%A"


    disp a
    disp b
    disp c
    disp d

    Console.ReadLine() |> ignore
    0

open System
[<EntryPoint>]
let main argv = 

    let xs = [1..4] |> List.map( fun _ -> double(Console.ReadLine()))
    
    let avg = xs |> List.average

    let disp x =
        let color x =
            match avg < x with
            | true ->  ConsoleColor.White
            | false -> ConsoleColor.Red
        Console.ForegroundColor <- color x
        x |> printfn "%A"


    xs |> List.iter disp

    Console.ReadLine() |> ignore
    0

---

ちなみに質問のコードの何が(再代入を除いて)文法的にまずかったのかです。

まず、F#のifは式です。何かしらの値を返さなければいけません。
elseを省略するとunitを返すことが求められます。

次に

let f x =
    let y = x + 1 // letが云々エラー

この書き方は、何を返すのか指定していないのでエラーになります。

let f x =
    let y = x + 1
    y

または

let f x =
    x + 1

こう書く必要があります。