VBA 関数の戻り値が値かオブジェクトか分からない場合の受け方

Question

### 前提・実現したいこと

VBAで　あるライブラリを使用しているのですが、
その中の関数が、結果によってオブジェクトと値のどちらを返してくるか
実行してみるまで分からない仕様となっており
呼び出し側で戻り値をどう受ければよいか困っております。

とりあえず値が戻ると仮定して一度呼び出して、
エラーになれば再度オブジェクトとして受けるように呼び出すという手段もあるかと思いますが
関数の背後で通信が発生しているため、あまり頻繁な呼び出しは避けたいと思っています。

なにか良い方法はありますでしょうか？

（該当のライブラリはBSDライクのライセンスなので、受け手でどうにもならない場合は
ライブラリのコードに手を入れることも考えています）

Accepted Answer

どうやるのが一般的か知らないですが思い付いた方法を回答します。

まず、以下のクラスを作成します。
```VBA
Public X As Variant
Public IsObject As Boolean

Public Sub SetX(v As Variant)
    If VBA.Information.IsObject(v) Then
        Set X = v
        IsObject = True
    Else
        X = v
        IsObject = False
    End If
End Sub
```
使い方は次の通り
```VBA
Public Sub test()
    Dim t_Container As New Container_Class
    Dim t_X As Variant
    
    ' オブジェクトの場合
    t_Container.SetX Sheet1
    If t_Container.IsObject Then
        Set t_X = t_Container.X
    Else
        t_X = t_Container.X
    End If

    ' 値の場合
    t_Container.SetX 1
    If t_Container.IsObject Then
        Set t_X = t_Container.X
    Else
        t_X = t_Container.X
    End If
End Sub
```

関数の引数にすれば、オブジェクトでも値でも受けれるので
それを利用した感じです。
別にクラスを作らなくても出来ますが、まぁ一例ということで。

Answer

xail2222さんの「関数の引数にすれば、オブジェクトでも値でも受けれる」という素晴らしいアイデアを拝借して、

```vba
'外部ライブラリのつもり
Public Function GetX(i As Long)
    If i = 0 Then
        Set GetX = Sheet1
    Else
        GetX = i + 1
    End If
End Function

Public Sub SetX(ByRef X, V)
    If IsObject(V) Then
        Set X = V
    Else
        X = V
    End If
End Sub

Public Sub test()
    Dim X As Variant
    
    SetX X, GetX(0)
    Debug.Print TypeName(X)
    If IsObject(X) Then
        Debug.Print X.Name
    Else
        Debug.Print X
    End If
    
    SetX X, GetX(1)
    Debug.Print TypeName(X)
    If IsObject(X) Then
        Debug.Print X.Name
    Else
        Debug.Print X
    End If
    
End Sub
```

ベストアンサーは辞退します。

Answer

値なのかオブジェクトなのかをどう判別するかは分かりませんが
取り合えず、Variant型で受け取って、それを使って諸々の判定を行えば良いのではないでしょうか

例えば、値が数値ならば、IsNumericで判定した後でCIntやCLngで変換すれば良いでしょうし