processingに関して

Question

雪が降るプログラムの中に星と動く文字を追加したいです。
現時点でこのようなプログラムを作成したのですが、エラーがでてしまい上手く作動しません。
unexpected token: void のエラーが出てしまいます。
プログラミング初心者で分からないことが多いので、エラーが出てしまう部分を改善して正しいプログラミングを教えて頂きたいです。宜しくお願い致します。

class Snowflake {
float x; //x axis
float y; //y axis
float s; //size
color c; //color
float dy; //speed
Snowflake() { //Function to create snowflake
x = random(width); //initial x point is random
y = random(height);
dy = random(0, 3); // Falling speed is random between 3 and 10
s = 5 * dy / 4.0; //Size is small if initial speed is slow
c = #ffffff; //white snow
}
void drop() { //create snow and move
y += dy;
if (y > height) y = 0; //if snow gets the bottom of the screen, return to top
noStroke(); //no outline
fill(c);
ellipse(x, y, s, s);
}
}
Snowflake[] sf = new Snowflake[5000]; //prepare the area for 1000 snow object
void setup(){
size (600,600);
noCursor();
for (int i = 0; i < 2000; i++) {
sf[i] = new Snowflake();
}
}
void draw() {
background(12,15,32);
for(int i = 0; i < 2000; i++) {
sf[i].drop();
}

for(int i=0;i<10;i++){
fill((i%2+1)128,(i%2+1)128,0);
float r=iTAU/10-PI/2;
float d=100-i%250;
float e=100-(i+1)%2*50;
triangle(120,120,cos(r)*d+120,sin(r)*d+120,cos(r+TAU/10)*e+120,sin(r+TAU/10)*e+120);

float x;
PFont font;
String msg = "Winter";
float speed = -1;
String msgLine="";
float msgWidth;

void setup () {
size(400, 200);
//font = loadFont("Calibri-BoldItalic-48.vlw");
font = createFont("Calibri Bold Italic",48);
textFont(font);
textSize(32);
x = width;
msgWidth=textWidth(msg);
for(int i=0;i<(int)(width/msgWidth)+2; i++){
msgLine+=msg;
}
}

void draw() {
background(255);
fill(0);
text(msgLine, x, height/2);
x = x+speed;
if(x<-msgWidth){
x=0;
}
}

Comments

[thkana]

ProcessingのIDEであれば、Ctrl+Tでソースの整形をしてくれます。
少なくとも、{}の対応が合っていない、なんていうのはそれでかなりチェックできるはずですので、習慣としたほうがいいと思います。
(IDEでなくても、大抵のテキストエディタがそういう機能を持っていると思います。メモ帳じゃ無理だけど...)

Answer 1

雪が降るプログラムの中に星と動く文字を追加したいです。

２つのプログラムを合体させようとしているわけですね？
単に２つのプログラムをコピペするだけでは動きません。

size (600,600)・size(400, 200)となっていては、どっちのサイズで表示すればいいかわかりませんよね？（そしてsetup()とdraw()は、複数書けません）

つまりそれぞれのsetup()・draw()を、ひとつのsetup()・draw()に適切に合体させる必要があります。

draw()では後に描くほど上になりますから、コードの順番も非常に重要になります。
とりあえず雪を最初に描きましたが、順番を変えてみたりしてください。

Snowflake[] sf = new Snowflake[2000];
float x;
PFont font;
String msg = "Winter";
float speed = -1;
String msgLine = "";
float msgWidth;


void setup() {
  size(600, 600);
  noCursor();

  for (int i = 0; i < sf.length; i++) {
    sf[i] = new Snowflake();
  }

  font = createFont("Calibri Bold Italic", 48);
  textFont(font);
  textSize(32);
  x = width;
  msgWidth = textWidth(msg);
  for (int i = 0; i < (int) (width / msgWidth) + 2; i++) {
    msgLine += msg;
  }
}

void draw() {
  //background(255);
  background(12, 15, 32);

  for (int i = 0; i < sf.length; i++) {
    sf[i].drop();
  }

  for (int i = 0; i < 10; i++) {
    fill((i % 2 + 1) * 128, (i % 2 + 1) * 128, 0);
    float r = i * TAU / 10 - PI / 2;
    float d = 100 - i % 2 * 50;
    float e = 100 - (i + 1) % 2 * 50;
    triangle(120, 120, cos(r) * d + 120, sin(r) * d + 120, cos(r + TAU / 10) * e + 120, sin(r + TAU / 10) * e + 120);
  }

  //  fill(0);
  fill(255);
  text(msgLine, x, height / 2);
  x = x + speed;
  if (x < -msgWidth) {
    x = 0;
  }
}


class Snowflake {
  float x = random(width);
  float y = random(height);
  float dy = random(0, 3);
  float s = 5 * dy / 4.0;
  color c = #ffffff;

  void drop() {
    y += dy;
    if (y > height) y = 0;
    noStroke();
    fill(c);
    ellipse(x, y, s, s);
  }
}

---

他変更点

• sfを2000個しか使っていないようなので、[2000]に変更（ループもsf.lengthに）
• 変数は上にまとめる
• クラスは下に（あるいは別タブに）
• Snowflakeのコンストラクタでの初期化が冗長なので宣言時に

Answer 2

processing はよくわかりませんが…

void draw() {

の終わりのほうに閉じ括弧がふたつほど足りない気がします。