UserForm1.Showのエラー

Question

前提・実現したいこと

標準モジュールで「シート1」のコマンドボタンからユーザフォームを起動して、「シート2」「シート4」からデータをリストボックスに反映して、リストボックスから選択したものを、「シート1」に転記するマクロを作成中。
ユーザフォームを起動する標準モジュールがうまく作動せず、以下のエラーメッセージが発生しました。

発生している問題・エラーメッセージ

なぜか「シート4」でしかユーザーフォームが起動してくれない。
実行時エラー’1004’：
アプリケーション定義またはオブジェクト定義のエラー

Option Explicit
Sub ボタン1_Click()
    UserForm1.Show vbModeless
End Sub
↑標準モジュール
↓ユーザーフォーム
Option Explicit
Dim TextRow As Long
Dim i As Long
Dim h As Long
Dim LastRow As Long

Private Sub CommandButton2_Click()
Unload Me
End Sub

Private Sub ListBox1_Change()
ListBox2.Clear
With Worksheets("Sheet2")
Select Case ListBox1
  Case ListBox1.List(0)
  ListBox2.List = .Range("C4:C20").Value
  Case ListBox1.List(1)
  ListBox2.List = .Range("D4:D20").Value
  Case ListBox1.List(2)
  ListBox2.List = .Range("E4:E20").Value
  End Select
  End With

    With UserForm1.ListBox2
'         複数選択可
        .MultiSelect = fmMultiSelectMulti
        
End With
End Sub

Private Sub UserForm_Initialize()

    With Worksheets("Sheet4")

 'セル範囲のデータをリストボックスに表示
        ListBox1.List = .Range(Cells(3, 3), Cells(20, 3)).Value
    End With

End Sub

Private Sub CommandButton1_Click()
    
    'テクストボックスに入力された値から+2行の位置に入力
    TextRow = UserForm1.TextBox1 + 2

    For i = 0 To ListBox2.ListCount - 1

        If ListBox2.Selected(i) Then
            With Worksheets("Sheet1")

                'セルへ転記
                .Cells(TextRow, 6) = ListBox2.List(i)
                TextRow = TextRow + 1

            End With
        End If
    Next

End Sub


エクセル　VBA

ソースコード

試したこと

UserForm_Initialize()のプロシージャを消去すると、UserForm1.Showが作動してくれる

エクセル2016
ここにより詳細な情報を記載してください。

Answer 1

定番のFAQですね。

Private Sub UserForm_Initialize()

    With Worksheets("Sheet4")

        'セル範囲のデータをリストボックスに表示
'        ListBox1.List = .Range(Cells(3, 3), Cells(20, 3)).Value
        ListBox1.List = .Range(.Cells(3, 3), .Cells(20, 3)).Value
    End With

End Sub

.Range(Cells(3, 3), Cells(20, 3)).Valueだと、
Worksheets("Sheet4").Range(ActiveSheet.Cells(3, 3), ActiveSheet.Cells(20, 3)).Valueという意味になり、Sheet4がアクティブでないと、Rangeの外と中で別のシートを指定することになりエラーになります。

Comments

[yuyu36]

ありがとうございました。このような動作になること勉強になりました。