VBA setステートメント使用時の処理待ち方法

Question

はじめまして。失礼な点が有りましたら申し訳有りません。

前提・実現したいこと

VBAでIEを起動し、google翻訳の結果を取得しセルに出力する。
上記は実現できたが、エラー回避の方法について改善できないか相談したい。

発生している問題・エラーメッセージ

Class要素から翻訳結果のテキストを取り出す際に、実行時エラー91が発生することがあります。
しかし、「デバッグ」→「継続」で処理を進めるとそのまま処理ができること、
また、Sleep関数で遅延させても回避できることから、Setステートメントの処理が完了していないと想像しています。
On Error Resume nextで処理を繰り返すことで回避したのですが、出来ればエラーを発生させたくないです。
Setステートメントが終了していることを確認して進めるような方法や、
その他エラーを回避できる方法が有りましたら教えていただけないでしょうか。
該当箇所は★で目印をつけております。

実行時エラー'91'
オブジェクト変数またはWithブロック変数が定義されていません。

該当のソースコード

Sub test()
Dim objIE As New InternetExplorer
Dim sl, tl, tgText, tgURL, URL As String '翻訳先URLを作成するための文字列
Dim Class1 As Object　'翻訳結果が記述されるClass
Dim ResultText1, ResultText2 As String ' 翻訳された文字列

sl = "ja" '翻訳元の言語
tl = "en" '翻訳先の言語

'IE(InternetExplorer)のオブジェクトを作成する
Set objIE = CreateObject("InternetExplorer.Application")

For i = 1 To 10
tgText = Cells(i, 1).Value '翻訳対象
tgURL = Excel.Application.WorksheetFunction.EncodeURL(tgText) '翻訳対象をURLエンコード
URL = "https://translate.google.co.jp/?sl=" & sl & "&tl=" & tl & "&text=" & tgURL ' & "op=translate"

Call ieView(objIE, URL) 'IEでGoogle翻訳にアクセスする処理

Set Class1 = objIE.document.getElementsByClassName("NqnNQd")
タグ1:
On Error Resume Next'★ここを置き換えたい
ResultText1 = Class1(0).innerText'★エラーが発生する箇所
If Err.Number <> 0 Then
 Err.Clear
 GoTo タグ1
End If

Cells(i, 2).Value = ResultText1
Next i

objIE.Quit
Set objIE = Nothing

End Sub

Sub ieView(objIE As InternetExplorer, _
           URL As String, _
           Optional viewFlg As Boolean = False)

  'IE(InternetExplorer)を表示・非表示
  objIE.Visible = viewFlg

  '指定したURLのページを表示する
  objIE.navigate URL
 
  'IE(InternetExplorer)が完全表示されるまで待機
  Call ieCheck(objIE)

End Sub

Sub ieCheck(objIE As InternetExplorer)

  Dim timeOut As Date

'完全にページが表示されるまで待機する
  timeOut = Now + TimeSerial(0, 0, 20) 'タイムアウト時間の設定

  Do While objIE.Busy = True Or objIE.readyState <> 4
    DoEvents
    Sleep 1
    If Now > timeOut Then 'タイムアウト処理
      objIE.Refresh
      timeOut = Now + TimeSerial(0, 0, 20)
    End If
  Loop

  timeOut = Now + TimeSerial(0, 0, 20)

  Do While objIE.document.readyState <> "complete"
    DoEvents
    Sleep 1
    If Now > timeOut Then 'タイムアウト処理
      objIE.Refresh
      timeOut = Now + TimeSerial(0, 0, 20)
   End If
   Loop

End Sub

試したこと

If then でclass1に情報があるか判別する回路に置換してみたのですが、エラー回避ができませんでした。
If class1 is nothing then
Goto タグ1
end if
ResultText1 = Class1(0).innerText
※この場合はfor文の先頭でClass1 の初期化処理も追加しています。

補足情報（FW/ツールのバージョンなど）

Excel 2016

ここにより詳細な情報を記載してください。

Comments

[mo-mo-mo]

objecrt変数についての理解が深まってエラーが発生した根本の原因がわかった（気がする）ので追記しておきます。
元々、IEで読込が終わっていないならSetの時点でエラーが出るのでは？と考えていましたが、
object変数（今回のコードで言うClass1)は保管した変数へたどり着くための目印のようなものと理解しました。そのため、Setでは目印をつけただけなので異常は出ない。そしてClass1のテキスト情報を読み出そうとした時、実際にはページの読込途中で存在していない、IEのテキスト情報を読み出す処理を行っているためにエラーが発生しているということでした。

下記が参考になりました。
https://excel-ubara.com/excelvba4/EXCEL_VBA_423.html

Answer 1

IE待機処理でループを抜ける条件を厳しくし、エラー軽減できる可能性があります。

Sub IEWait(ByRef ie As Object)

    Dim timeout As Date
    Dim cnt As Integer
    Dim IEretry As Boolean

    timeout = DateAdd("s", 20, Now())
    Do
        DoEvents: Sleep 1: DoEvents
        '下記ステータス連続一致確認
        If ie.Busy = False And ie.readyState = 4 Then 'READYSTATE_COMPLETE = 4
            cnt = cnt + 1
            If cnt >= 50 Then
                Exit Do
            End If
        End If
        'タイムアウトチェック
        If timeout < Now() Then
            If IEretry = False Then
                '１回限りでIE再読み込み
                IEretry = True
                ie.Refresh
                timeout = DateAdd("s", 20, Now())
            Else
                Exit Do
            End If
        End If
    Loop

    timeout = DateAdd("s", 10, Now())
    Do While ie.Document.readyState <> "complete"
        DoEvents: Sleep 1: DoEvents
        'タイムアウトチェック
        If timeout < Now() Then Exit Do
    Loop
End Sub

Comments

[mo-mo-mo]

ご回答ありがとうございます。
教えて頂いたコードでエラー発生回数が0回になりました。
（改善前は１件あたり600回でした）
ベストアンサーにさせていただきます。

下記、参考までに教えていただきたいです。
Setを１回しか実行していないのでIE側は関係無いものと思い込んでいたのですが、実際にはIE側の読込（生成？）に追従してSetの処理が進んでいるということでしょうか？
ソフトウェア側の仕様なのかなとも思いますが、解説のあるサイト等ご存知でしたらご紹介いただけますと幸いです。

[TanakaHiroaki]

良かったです。
経験的なことしか言えないのですが、下記サイトのページの読み込みが完了していない
のに「readyState」が「4（完了）」を返して待機処理のループを抜け、Setの処理で
実行時エラー'91'となるのではないでしょうか。
https://rabbitfoot.xyz/post-354/

[mo-mo-mo]

readyStateが変化する可能性があるのですね…。
サイトの紹介もありがとうございます。
大変勉強になりました。