VBAでドロップダウンを双方向に連動させたい

Question

ドロップダウン１とドロップダウン２があるとします。
ドロップダウン１には選択肢AとBが格納されています。
ドロップダウン１でAを選んだ場合は、ドロップダウン２で複数の選択肢を表示させます。
ドロップダウン１でBを選んだ場合は、ドロップダウン２で選択肢は表示させず、NULLを受け取りたいです。（全角スペースで何もないように見せるのは無し）

現在ですが、ドロップダウン１でAを選びドロップダウン２で選択したあと、ドロップダウン１をBに変えてもドロップダウン２の選択肢がそのまま残ってしまいます。
ドロップダウン２に既にデータが入っていたとしても、その後でドロップダウン１をBに変更した場合セルをクリアさせたいです。

また、空白の選択肢を作る（もしくは選択肢を表示させない）場合の対処法として、よく全角スペースを入れる手段があると思いますが、今回の場合はこれを避けたいです。

別ウィンドウでコンボボックスを出したりするのではなく、セル内のドロップダウンで上記のような仕組みを作ることは可能でしょうか？

現在以下のようなコードを書いてみたのですが、双方向の連動ということしかできず、この形式だと下のような問題点が発生していまいます。
・選択肢１つに対して連動する選択肢も１つであること
・選択肢なしにするということが達成できていないこと

Option Explicit
Private Sub Worksheet_Change(ByVal Target As Range)
Dim myRow As Long

If Not Intersect(Target, Range("A1:B1")) Is Nothing Then
Application.EnableEvents = False
If Target.Address(0, 0) = "A1" Then
myRow = WorksheetFunction.Match(Range("A1"), Columns(4), 0)
Range("B1") = Range("E" & myRow)
Else
myRow = WorksheetFunction.Match(Range("B1"), Columns(5), 0)
Range("A1") = Range("D" & myRow)
End If
Application.EnableEvents = True
End If
End Sub

Comments

[moh1ee]

セル内のドロップダウンというのは入力規則のリストのことでよろしいでしょうか？

[yokopiyo]

はい、そうです。
データの入力規制の欄から「リスト」で設定できるものと同じものです。

Answer 1

仕様が不明瞭なので、下記のようだと仮定して回答します。

A1セルに入力規則で A,B のリストが設定されている。
A1セルでリストからAを選択（または入力）したら、B1セルで複数のリストが選択できるようにする。
A1セルでリストからBを選択（または入力）したら、B1セルの値をクリアして、入力規則のリストも削除する。

A1セルの値を削除してブランクにした場合は、どうしたいのか不明なので、リストを削除するだけにしてます。

Private Sub Worksheet_Change(ByVal Target As Range)
    If Not Intersect(Target, Range("A1")) Is Nothing Then
        Application.EnableEvents = False
        With Range("B1").Validation
            .Delete
            Select Case Range("A1").Value
            Case "A"
                .Add Type:=xlValidateList, _
                     Operator:=xlEqual, _
                     Formula1:="CCC,DDD,EEE"
            Case "B"
                Range("B1").Value = Null
            End Select
        End With
        Application.EnableEvents = True
    End If
End Sub

---

追加の質問で申し訳ないのですが、ドロップダウン１でBを選択した時、B1のセルを入力禁止にすることは可能でしょうか。

セルのロックとシートの保護を使えばいいでしょう。

Private Sub Worksheet_Change(ByVal Target As Range)
    If Not Intersect(Target, Range("A1")) Is Nothing Then
        Application.EnableEvents = False
        If ProtectContents Then Unprotect Password:="1234"
        Cells.Locked = False
        With Range("B1").Validation
            .Delete
            Select Case Range("A1").Value
            Case "A"
                .Add Type:=xlValidateList, _
                     Operator:=xlEqual, _
                     Formula1:="CCC,DDD,EEE"
                Range("B1").Locked = False
            Case "B"
                Range("B1").Value = Null
                Range("B1").Locked = True
                Protect Password:="1234"
            End Select
        End With
        Application.EnableEvents = True
    End If
End Sub

Comments

[yokopiyo]

ご回答ありがとうございます。
作りたいものと非常に近くなっており、大変助かります。
追加の質問で申し訳ないのですが、ドロップダウン１でBを選択した時、B1のセルを入力禁止にすることは可能でしょうか。
現在自分が試している方法だと、リスト以外のものを入力禁止にすることはできるのですが、セルをクリアかつ入力禁止というのが難しく、苦戦しています。

[hatena19]

回答に追記しましたので参照してください。

Answer 2

＞エクセルのドロップダウンを双方向に連動させることは可能ですか？

はい。