sqlcmdの戻り値の確認方法

Question

バッチファイルを作っています。
sqlcmdの正常なら0、エラーなら1などの戻り値をもとに条件分岐をしたいのですが、戻り値を確認する方法がわかりません。
sqlcmdの下にecho errorlevelと書いたら「それだとこのsqlcmdの戻り値かどうかわからない」と言われました。

@echo off

REM #####################
REM ★接続情報
REM #####################
REM サーバー名(サーバーのPC名\インスタンス名)
SET dbServer=
REM データベース名
SET dbName=
REM ユーザー名
SET userName=
REM パスワード
SET password=
REM 実行するSQLコマンドファイル(フルパスで指定し、拡張子は.sql)
SET sqlCmdFilePath=
REM 実行するSQLコマンド
SET sqlcmd=sqlcmd -S %dbServer% -d %dbName% -U %userName% -P %password% -i %sqlCmdFilePath%

REM #####################
REM SQL Server認証の場合
REM #####################

SET /P ANSWER="実行します。よろしいですか? (Y/N)"

IF /i %ANSWER%==y (

 echo 処理を開始します。

 REM ★SQLファイルを実行
 sqlcmd -S %dbServer% -d %dbName% -U %userName% -P %password% -i %sqlCmdFilePath% 

) ELSE (

 echo 処理をせずに終了します。

)
pause

Comments

[maisumakun]

> sqlcmdの下にecho errorlevelと書いたら「それだとこのsqlcmdの戻り値かどうかわからない」と言われました。

それが唯一の正しい手段だと思うのですが。

Answer 1

分岐には、直後にif errorlevelを使います。

IF /i %ANSWER%==y (
 echo 処理を開始します。
 REM ★SQLファイルを実行
 sqlcmd -S %dbServer% -d %dbName% -U %userName% -P %password% -i %sqlCmdFilePath% 
 if errorlevel 1 (
   echo 戻り値が1以上だった
 ) else (
   echo 戻り値が1未満0だった
 )
) ELSE (
 echo 処理をせずに終了します。
)

指定した数値と等しいときじゃなくて、以上の時なので、間違えないようにしましょう。

echo errorlevelだと、戻り値は関係なくて単にerrorlevelという文字列が表示されます。

Answer 2

sqlcmdの下にecho errorlevelと書いたら「それだとこのsqlcmdの戻り値かどうかわからない」と言われました。

もしかして、指摘された方の意図としては sqlcmd コマンドに -b オプションを付けないと、SQL エラーが拾えない、ということを言っているのではないでしょうか？
例えば、SQL の構文エラーがあったとしても -b を付けない場合 sqlcmd コマンド自体は正常「0」を返します。

■ sqlcmd ユーティリティ
https://docs.microsoft.com/ja-jp/sql/tools/sqlcmd-utility

エラー報告のオプション

-b
エラーが発生したときに、 sqlcmd を終了し、DOS ERRORLEVEL 値を返します。 SQL Server のエラー メッセージの重大度が 10 よりも高い場合、DOS ERRORLEVEL 変数に返される値は 1 です。それ以外の場合は、0 が返されます。

Comments

[imaiw]

ありがとうございます。勉強になります。
ちなみにsqlcmdを変数に入れて、その変数を使って条件分岐するやり方はできますか？調べてもerrorlevelしか出てきませんでした。

[cx20]

> sqlcmdを変数に入れて
どういう意味でしょうか？

> 調べてもerrorlevelしか出てきませんでした
はい。戻り値の判定は errorlevel を使います。
sqlcmd.exe の実行結果は errorlevel変数に返却されます。
otn さんの回答にある書き方か、比較演算子を用いるのであれば、以下のような書き方になりなります。
--------------------------
　if %errorlevel% geq 1 (
　　echo 戻り値が1以上だった
　) else (
　　echo 戻り値が1未満0だった
　)
--------------------------
※ 読みやすさの為、全角スペースでインデントを入れています。

＜参考＞
■ SQLCMDコマンドの実行結果をログファイルに出力しよう
/ どうやってSQLCMDコマンドのエラーを検知するの？
https://qiita.com/erik_t/items/9f4a123dfa2ecb3e1129

[otn]

> 比較演算子を用いるのであれば、以下のような書き方になりなります。
括弧の中ではお書きの書き方では駄目なので、触れませんでした。
（遅延環境変数含め丁寧に説明すれば良いのですが）

[cx20]

> 括弧の中ではお書きの書き方では駄目なので、触れませんでした。
> （遅延環境変数含め丁寧に説明すれば良いのですが）

otn さん、ご指摘ありがとうございます。
括弧の中の処理であったことを失念していました。括弧の中だと以下のような対応が必要ですね。

＜丸括弧の中で errorlevel 環境変数を使う場合＞
・先頭に「@setlocal enabledelayedexpansion」を追加
・以下に変更
　変更前）%errorlevel%
　変更後）!errorlevel!

＜参考＞
■ バッチファイル界の魔境『遅延環境変数』に挑む（おまけもあるよ）
https://qiita.com/plcherrim/items/c7c477cacf8c97792e17

[imaiw]

ありがとうございます。別で質問しようとしていたことが解決しました。