ユーザフォームで３つのコンボを連動させたい

Question

前提・実現したいこと

VBA初心者です。

現在受注リストをユーザフォームで作成できるエクセルを作成しています。
そのユーザフォームの項目で、一部、コンボボックスで
1.商品ID（コンボボックス名：ProdID）
2.商品名（コンボボックス名：ProdName）
3.単価　（コンボボックス名：Price）
それぞれ連動したコンボボックスを追加したいと思っていますが
UserForm_Initialize()、change()に　ADDITEM（）に
どうコードを記載したらいいのか頭を抱えてます。

それぞれのマスタは"リスト"というシートに

商品ID	商品名	単価
0	オフィス用コーヒー	2000
0	家庭用コーヒー	1000
0	オフィス用カフェラテ	3000
1	コーヒー豆	10000
2	オフィス用カフェラテ	3000
2	コーヒー豆	10000

といった感じで作成しています。
同じ番号の重複をせずに表示させて、なおかつ、商品名・単価は左の項目に連動させるような
コードをお教えいただけると幸いです。

該当のソースコード

ソースコード

試したこと

ネットでSQLを使って作成する方法をみつけて試みましたが、
実際に使うPCがSQL使用禁止のものだったので、純粋にEXCELの標準機能だけで動かせる方法があれば助かります。

補足情報（FW/ツールのバージョンなど）

EXCEL　OFFICE365

Answer 1

こんな感じでどうでしょうか。

Option Explicit
    
Dim dic 'As Scripting.Dictionary

Private Sub UserForm_Initialize()
    Set dic = CreateObject("Scripting.Dictionary")
    Dim ws As Worksheet
    Set ws = ThisWorkbook.Worksheets(1)
    
    Dim sID As String
    Dim ro As Range
    For Each ro In ws.UsedRange.Rows
        sID = ro.Cells(1, 1)
        If dic.Exists(sID) Then
            Set dic(sID) = Union(ro, dic(sID))
        Else
            Set dic(sID) = ro
        End If
    Next
    
    With ComboBox1
        .List = dic.Keys
        .ListIndex = 0
    End With
End Sub

Private Sub ComboBox1_Change()
    ComboBox2.Clear
    ComboBox3.Clear
    Dim rng As Range
    Set rng = dic(ComboBox1.Value)
    Dim ro As Range
    For Each ro In rng.Rows
        ComboBox2.AddItem ro.Columns(2)
    Next
    ComboBox2.ListIndex = 0
End Sub

Private Sub ComboBox2_Change()
    ComboBox3.Clear
    Dim rng As Range
    Set rng = dic(ComboBox1.Value)
    Dim ro As Range
    For Each ro In rng.Rows
        If ComboBox2.Value = ro.Columns(2) Then
            ComboBox3.Value = ro.Columns(3)
        End If
    Next
End Sub

Comments

[yogina]

早速ありがとうございます！

Answer 2

いろいろな方法があると思いますが、

OFFICE365 ということなので、Unique関数, Filter関数を使った例です。

まず、リストをテーブル化しておきます。テーブル化しておくと、データを、項目名で取得できるので読みやすいコードになります。

詳細は下記などで学習してください。

【VBA】テーブルから値を取得する方法まとめ【“構造化参照”と“ListObjects”の比較】

ユーザ―フォームのモジュール

Option Explicit

Private Sub UserForm_Initialize()
    Me.ProdID.List = WorksheetFunction.Unique(Range("商品リスト[商品ID]"))
End Sub

Private Sub ProdName_Enter()
    With WorksheetFunction
        If Me.ProdID.Value <> "" Then
           Me.ProdName.List = _
            .Unique(.Filter(Range("商品リスト[商品名]"), _
                    Evaluate("商品リスト[商品ID]=" & Me.ProdID.Value)))
        End If
    End With
End Sub

Private Sub Price_Enter()
    With WorksheetFunction
        If Me.ProdID.Value <> "" And Me.ProdName.Value <> "" Then
            Me.Price.List = _
            .Unique(.Filter(Range("商品リスト[単価]"), _
                    Evaluate("(商品リスト[商品ID]=" & Me.ProdID.Value & ")" & _
                             "*(商品リスト[商品名]=""" & Me.ProdName & """)")))
        End If
    End With
End Sub

一応、商品ID → 商品名 → 価格 という順で選択するのが前提のコードです。
※追記　テーブルの名前は「商品リスト」としてください。

Comments

[yogina]

リストを使ったやり方があるのは知りませんでした。解説もご丁寧に解説もつけてくださりありがとうございます。助かります！
ただ、商品IDはスムーズに出たのですが、実行エラー1004でWorksheetFunctionクラスのFilterプロパティが取得できないと出てしまいます；；何が原因なのかいろいろ調べているのですが、もしご存じでしたら教えて戴けると助かります。（あつかましくスミマセン。。）

[hatena19]

テーブルの名前を「商品リスト」にしてますか。
（回答にこの点の説明がなかったので追記しておきました。）

[hatena19]

あっ、でも、商品ID はうまくいったのなら、それではないか。
うーん、ちょっと原因は分からないですね。

[yogina]

お返事ありがとうございます。はい、商品リストにしております。

[yogina]

ありがとうございます。自分でもう少し調べてみます。

[yogina]

質問させていただいた表は無事連動することができました????また考え方についても勉強になりました、
本当にありがとうございました????