ExcelVBAで、IDをペーストしたら、氏名だけが検索結果として出るマクロの作り方があればご教示いただけないでしょうか。

Question

前提・実現したいこと

左の列から、「ID、氏名（漢字）、氏名（カタカナ）」と並んでいる
名簿一覧表に対して、Excelマクロで、ユーザーフォームを作成し、

■IDをtextbox1にペーストしたら、氏名（カタカナ）がtextbox2に検索結果としてでてくる。

もしくは、

■IDをtextbox1にペーストしたら、MsgBoxで、「氏名（カタカナ）です」。

のように、検索できるマクロを組みたい。

該当のソースコード

現状、自力で作成できているのは、以下のようなコードです。

Private Sub CommandButton1_Click()
Dim i As Long
For i = 2 To Cells(Rows.Count,3).End(xlUp).Row
If TextBox1.Value = Cells(i,3) Then
Cells(i,3).Select
MsgBox Cells(i,3).Row & "行目にあります"
End If
Next
End Sub

試したこと

表のレイアウトとして、
ID・・B列
氏名（漢字）・・Ｃ列
氏名（カタカナ）・・Ｄ列

Ａ列は空白の状態です。

上述のコードだと、「〇行目にあります」と出てくれるので、
これでもわかりやすいといえばわかりやすいのですが、
業務をより効率化するために、textBox1にＩＤをペーストしたら、
「氏名（カタカナ）です」検索結果としてでるようにしたい。

ただ、この課題については、いろいろググったりして、
自分でもコードを書いてみましたが、正直、行き詰ってしまい、
どうコードを書けばよいか、わからなくなってしまいました。

補足情報（FW/ツールのバージョンなど）

使用しているのは、Excel2016になります。

ExcelVBA初心者なので、多々わかっていないこともあると思います。
ですので、質問の仕方も、わかりにくいところがあるかもしれません。

できる限り、自分なりに、わかりやすく書かせていただいたつもりです。
もし、不明な点があれば、ご教示をおねがいします。

以上、どうか、みなさんの知恵を拝借させていただきたく、
よろしくお願い申し上げます。

Answer 1

Match関数で検索するコード例

Private Sub TextBox1_Change()
    With Range("B2", Cells(Rows.Count, 2).End(xlUp))
        Dim i
        i = Application.Match(Me.TextBox1.Value, .Cells, 0)
        If Not IsError(i) Then
            MsgBox .Cells(i, 2).Value & "(" & .Cells(i, 3) & ")"
        End If
    End With
End Sub

ID が数値だった場合は、Me.TextBox1.Value は Val(Me.TextBox1.Value) としてください。

Comments

[study.vba-22_o]

ご返事が遅くなり、まことに申し訳ありません。
この度は、ありがとうございました。
やはりプロに聞くのが一番です。実際コードを書いてみたら、しっかり動きました。ありがとうございました。

Answer 2

やりたいのはたぶんこんな感じでしょうか。

Private Sub TextBox1_Change()
    Dim ws As Worksheet
    Set ws = ThisWorkbook.Worksheets(1)
    
    Dim i As Long
    For i = 2 To ws.Cells(ws.Rows.Count, 3).End(xlUp).Row
    If CStr(TextBox1.Value) = CStr(ws.Cells(i, 2).Value) Then
        TextBox2.Value = ws.Cells(i, 3).Value & "(" & ws.Cells(i, 4).Value & ")"
        Exit Sub
    End If
    Next
    TextBox2.Value = ""
End Sub

Comments

[study.vba-22_o]

まずは、ご返事が遅くなり、申し訳ありませんでした。
いろいろご意見をいただき、コードの書き方も様々で、大変参考になりました。
ですが、今回は、あなたさまをベストアンサーに選択させていただきました。
理由としては、「私が欲しい内容そのものだった」からです。
このコードを参考にし、日々の業務やVBAの学習にいそしんでいきたいとおもいます。
また何かありました際は、よろしくお願い申し上げます。

Answer 3

VLOOKUP関数というのを調べてみよう