processingで音楽プレーヤーのスキップ機能を作成したいです。

Question

音楽プレーヤーのようなものを作成していました。
これに曲のスキップ機能をつけたいと思っております。マウスでクリックしたときに次の曲または前の曲を再生する方法が分からず困っています。どなたかご教授ください。
全体のプログラムは以下の通りです。

import ddf.minim.*;
import ddf.minim.analysis.*;
import ddf.minim.effects.*;
import ddf.minim.signals.*;
import ddf.minim.spi.*;
import ddf.minim.ugens.*;

int a = 50;
int b = 440;
int mode;

PImage img;
Minim minim;
AudioPlayer player1;
AudioPlayer player2;
AudioPlayer player3;
AudioPlayer player4;
AudioPlayer player5;
Teishi teishi;
Saisei saisei;



void setup(){
  size(357, 600);
  PFont font = createFont("Meiryo",50);
  textFont(font);
  img = loadImage("586.jpg");
  minim = new Minim(this);
  teishi = new Teishi();
  saisei = new Saisei();
  player1 = minim.loadFile("01 Tides.mp3");
  player2 = minim.loadFile("02 Shivers.mp3");
  player3 = minim.loadFile("03 First Times.mp3");
  player4 = minim.loadFile("04 Bad Habits.mp3");
  player5 = minim.loadFile("05 Overpass Graffiti.mp3");
  saisei.display();
}

void draw(){
}

void mouseClicked(){  
    if (a-1 < mouseX && mouseX < a + 30 && b-1 < mouseY && mouseY < b + 30) {
      saisei.display();
      if (player4.isPlaying()) {
      player4.pause();
    } else {
      player4.loop();
      teishi.display();
    }
  }
  
}

class Saisei{
  void display(){
    background(255);
    image(img, width*1.17/7, height/12, width*2/3, height*2/5);
    strokeWeight(5);
  line(0, (height*3/5)-10, width, (height*3/5)-10);
  fill(0);
  textSize(30);
  text("曲名", 40, 400);
  textSize(15);
  text("artist", 40, 425);
  text("1/1",width/2-10, height/2+30);
  fill(255);
  rect(b,a,b,a);
  fill(0);
  triangle(a,b,a,b+30,a+30,b+15);
  
    triangle(200,425,215,415,215,435);
  triangle(218,425,233,415,233,435);
  
  triangle(300,425,285,415,285,435);
  triangle(318,425,303,415,303,435);
  }
}
      
class Teishi{
  void display(){
    background(255);
      image(img, width*1.17/7, height/12, width*2/3, height*2/5);
      strokeWeight(5);
  line(0, (height*3/5)-10, width, (height*3/5)-10);
  fill(0);
  textSize(30);
  text("曲名", 40, 400);
  textSize(15);
  text("artist", 40, 425);
  text("1/1",width/2-10, height/2+30);
   fill(255);
  rect(b,a,b,a);
  fill(0);
  line(a,b,a,b+30);
  line(a+15,b,a+15,b+30);
  
  triangle(200,425,215,415,215,435);
  triangle(218,425,233,415,233,435);
  
  triangle(300,425,285,415,285,435);
  triangle(318,425,303,415,303,435);
  }
}

Comments

[thkana]

まだ内容まで見ていませんが、
「できなくなりました」
というのは、全く同じプログラムなのに以前はできた、今はできない、という意味ですか?

[thkana]

ソースコードの部分は https://teratail.com/help/question-tips#questionTips3-5 を参考に、マークダウンの処置をしてください。

[bump_of_pool]

回答していただきありがとうございます。全く同じプログラムなのに以前はできた、今はできない、という意味であっております。ですが、全く同じプログラムで新規作成したらエラーがなくなったので自己解決してしまいました。

[bump_of_pool]

なので、質問内容を変更させていただきました。勝手ながら申し訳ございません。

[thkana]

> 質問内容を変更
まぁ、回答がついてないからギリいいのかな。もしかしたら、あの人とかあの人が回答を一所懸命考えてたかもしれないけれど。自己解決の回答をつけてクローズ、別の質問を新たに作成、というのがよかった気がします。

あ、一応この欄は「質問への追記・修正の依頼」ということで回答ではない、解決に直接寄与するのでない、情報の提供やなんかを質問者にお願いする欄、ということのようです。質問/回答掲示板でしばしば見かける、情報が足りなくて解にたどり着けないような質問に「回答欄」で情報の提供を求めると「答えがわからないなら黙ってろ」と暴言を吐かれるような事態への対応ということでしょうかね。

Answer 1

  player1 = minim.loadFile("01 Tides.mp3");
  player2 = minim.loadFile("02 Shivers.mp3");
  player3 = minim.loadFile("03 First Times.mp3");
  player4 = minim.loadFile("04 Bad Habits.mp3");
  player5 = minim.loadFile("05 Overpass Graffiti.mp3");

この辺を「配列」にするとプログラム中で前後の概念を表すのが容易になると思います。

Processing Ver.2までで使われていたminimでも全然問題ないですけど、ProcessingのVer.3ではSoundFileとかいうのができたのでそっちを使うのが「標準」かも知れません。

Answer 2

おそらくボタンが並ぶことになるでしょうから、ControlP5とかを使ったほうが楽じゃないですかね？
AudioPlayerを複数持つとだいぶメモリの無駄に感じますので、都度loadFileしたほうがよさそうです。

無駄にこだわってしまって長くなったのでボタンだけ^^;
ボリューム・シークバーは、Sliderが使えます。

import controlP5.*;
import ddf.minim.*;

Minim minim;
AudioPlayer player;

ArrayList<String> files = new ArrayList<String>();
int current;
int length;

PImage img;

ControlP5 cp5;
Button playPause;
boolean isPlaying;

void setup() {
  size(400, 400);

  minim = new Minim(this);
  cp5 = new ControlP5(this);

  cp5.addButton("prevTrack")
    //.setImages(loadImage("normal.png"), loadImage("hover.png"), loadImage("pressed.png"))
    .setImages(getPrevTrackImage())
    .setPosition(125, 330)
    .setSize(40, 40);

  playPause = cp5.addButton("playPause")
    .setImages(getPlayImage())
    .setPosition(175, 325)
    .setSize(50, 50);

  cp5.addButton("nextTrack")
    .setImages(getNextTrackImage())
    .setPosition(235, 330)
    .setSize(40, 40);

  selectFolder("フォルダを選択", "folderSelected");
}

void draw() {
  background(255);

  if (img != null) image(img, 0, 0, width, height);

  fill(0, 128);
  noStroke();
  rect(0, 300, width, 100);

  if (player == null) return;

  if (!isPlaying && player.isPlaying()) {
    isPlaying = true;
    playPause.setImages(getPauseImage());
  } else if (isPlaying && !player.isPlaying()) {
    isPlaying = false;
    playPause.setImages(getPlayImage());
    //println(length, player.position()); // 1秒以上食い違うorz
  }

  // 雑終了判定ｗ
  if (!isPlaying && length != 0 && length - 1500 <= player.position()) {
    nextTrack();
  }
}

void prevTrack() {
  move(-1);
}

void playPause() {
  if (player == null) return;

  if (isPlaying) player.pause();
  else player.play();
}

void nextTrack() {
  move(1);
}

void move(int i) {
  if (files.size() == 0) return;

  if (player != null) player.close();

  current += i;
  if (files.size() <= current) current = 0;
  if (current < 0) current = files.size() - 1;

  player = minim.loadFile(files.get(current));
  player.play(0);
  length = player.length();
}

void folderSelected(File selection) {
  if (selection == null) return;

  if (player != null) player.close();
  files.clear();
  img = null;

  for (File file : selection.listFiles()) {
    if (!file.isFile()) continue;

    String name = file.getName().toLowerCase();
    if (name.endsWith(".mp3") || name.endsWith(".wav")) {
      files.add(file.getAbsolutePath());
    }

    if (file.getName().equals("Folder.jpg")) {
      img = loadImage(file.getAbsolutePath()); // アルバムアート
    }
  }

  current = -1;
  nextTrack();
}

// 以下ボタン画像生成 まったく重要でないｗ
PGraphics[] getPrevTrackImage() {
  return new PGraphics[] { pn(color(0, 1), true), pn(color(0, 32), true), pn(color(0, 64), true), };
}
PGraphics[] getPlayImage() {
  return new PGraphics[] { py(color(0, 1)), py(color(0, 64)), py(color(0, 1)), };
}
PGraphics[] getPauseImage() {
  return new PGraphics[] { pe(color(0, 1)), pe(color(0, 64)), pe(color(0, 1)), };
}
PGraphics[] getNextTrackImage() {
  return new PGraphics[] { pn(color(0, 1), false), pn(color(0, 32), false), pn(color(0, 64), false), };
}

PGraphics py(color c) {
  PGraphics pg = createGraphics(50, 50);
  pg.beginDraw();

  pg.fill(c);
  pg.stroke(200);
  pg.circle(25, 25, 49);

  pg.noFill();
  pg.stroke(255);
  pg.strokeWeight(2);
  pg.triangle(17, 15, 17, 35, 32, 25);

  pg.endDraw();

  return pg;
}

PGraphics pe(color c) {
  PGraphics pg = createGraphics(50, 50);
  pg.beginDraw();

  pg.fill(c);
  pg.stroke(200);
  pg.circle(25, 25, 49);

  pg.noFill();
  pg.stroke(255);
  pg.strokeWeight(2);
  pg.line(21, 15, 21, 35);
  pg.line(29, 15, 29, 35);

  pg.endDraw();

  return pg;
}

PGraphics pn(color c, boolean flip) {
  PGraphics pg = createGraphics(40, 40);
  pg.beginDraw();

  if (flip) {
    pg.translate(40, 0);
    pg.scale(-1, 1);
  }

  pg.noStroke();
  pg.fill(c);
  pg.circle(20, 20, 39);

  pg.noFill();
  pg.stroke(255);
  pg.strokeWeight(2);
  pg.triangle(12, 12, 12, 28, 24, 20);
  pg.line(28, 12, 28, 28);

  pg.endDraw();

  return pg;
}

参考資料
processing GUI, controlP5
selectFolder() / Reference / Processing.org
File (Java Platform SE 8 )
[Folder.jpg AlbumArtSmall.jpg - Google 検索

---

player.length()が取れない時があるらしい（となると再生終了検知が。。。

setVolumeが効かない問題も悩ましい（setGainは扱いづらい）が、Soundはmp3開くのが激重すぎて使えなかった。

アートワークはFolder.jpgを使用（Windows限定だが^^;

あとファイルはwav・mp3・aiffで、 wmaが未対応なのが悲しいですね。。。