VBA:オートフィルしていない行を削除したい

Question

前提・実現したいこと

以下のコードではSheet1に抽出したい日付K５セルとM５セルに(例:2021/1/1~2021/2/10)を書き込んで、
日程シートのK列にフィルタをかけて対象の日付のみを表示させています。

しかし、オートフィルで表示していない行はすべて削除したいのですが
どのようなコードをかけばいいでしょうか。
[補足]
オートフィルタした行に色をつけたいのですが、
その場合はどうすればいいでしょうか。

該当のソースコード

Sub Filterdata()
'データを絞る

Dim MaxRow  As Long

MaxRow = worksheets("日程").Cells(Rows.Count, 11).End(xlUp).row

worksheets("日程").Range("K1") _
            .AutoFilter Field:=11, _
            Criteria1:=">=" & worksheets("Sheet1").Range("K5"), _
            Operator:=xlAnd, _
            Criteria2:="<=" & worksheets("Sheet1").Range("M5")

End Sub

Answer 1

削除するときは後ろから削除しないとうまくいかない。（削除すことによって後の行が前に移動するため）

    Dim i As Long
    With worksheets("日程").Range("K1").CurrentRegion.EntireRow
        For i = .count To 2 Step -1
            If .Rows(i).Hidden Then .Rows(i).Delete
        Next
    End With

あるいは、Unionでまとめて一気に削除するかですね。

    Dim R As Range, delR As Range
    For Each R In Range("A1").CurrentRegion.EntireRow
        If R.Hidden Then
            If delR Is Nothing Then
                Set delR = R
            Else
                Set delR = Union(delR, R)
            End If
        End If
    Next
    If Not delR Is Nothing Then delR.Delete

---

フィルターをかけて、非表示になった行を削除、その後フィルターを解除

Sub Filterdata()

'フィルターをかける
    Dim r As Range
    Set r = Worksheets("日程").Range("K1")
    r.AutoFilter Field:=11, _
                 Criteria1:=">=" & worksheets("Sheet1").Range("K5"), _
                 Operator:=xlAnd, _
                 Criteria2:="<=" & worksheets("Sheet1").Range("M5")

'非表示行の削除
    Dim i As Long
    With r.CurrentRegion.EntireRow
        For i = .Count To 2 Step -1
            If .Rows(i).Hidden Then .Rows(i).Delete
        Next
    End With
    
'フィルター解除
    r.AutoFilter
End Sub

Comments

[pomiw0000]

回答ありがとうございます。
上のコードは別で書く感じでしょうか？それとも既存のコードに追加する感じでしょうか？

[hatena19]

どちらでもいいです。

[pomiw0000]

実行してみたのですが、消えませんでした????

[pomiw0000]

オートフィルタもついたままになっています

[hatena19]

フィルターをかけて、非表示になった行を削除、その後フィルターを解除したいということですね。
サンプルコードを追記しておきますので、参考にしてください。
こちらのサンプルでは動作確認済みです。

Answer 2

        Dim r As Range
        For Each r In Worksheets("日程").Range("K1").AutoFilter.Range.Rows
            If r.Hidden Then r.EntireRow.Delete
        Next