Dir関数でファイル名取得が出来ない

Question

本当に度々失礼いたします。

今現在　excel上のB1、B2に指定のファイルを
B3で指定されたフォルダにコピーしようとしております。

Option Explicit

'B1とB2から次年度、当年度のデータを作成する。
Sub ボタン1_Click()
    Dim strTmp, copyDest, konnnenndoFile, jinenndoFile, copyDir As String
    Dim ret As Long

    konnnenndoFile = Range("B1").Value
    jinenndoFile = Range("B2").Value
    copyDir = Range("B3").Value
    
    'B1の当年度　のデータを読込　コピーする。
    strTmp = Dir(konnnenndoFile)
    copyDest = copyDir & strTmp
    FileCopy konnnenndoFile, copyDest
End Sub

上記のソースにて
konnnenndoFile = Range("B1").Value
と入れていてそのファイルはあるのは確実なのですが
（excelのB1をクリックして開くので）
strTmp = Dir(konnnenndoFile)
にてstrTmp="" なのです……
・Dir関数の使い方が不味いのでしょうか？
・変数の指定方法が不味いのでしょうか？
・フォルダとファイル名が長すぎると不味いのでしょうか？（半角190文字です。）

グーグルさんで調べても不明だったため本当に申し訳ないのですが
何か情報をお持ちな方はコメント頂けますと嬉しく思います。

Comments

[1T2R3M4]

https://docs.microsoft.com/ja-jp/office/vba/language/reference/user-interface-help/dir-function
リファレンスはお読みになられましたか。

[D0NKAMA]

Dirの()の中はファイル名ではなくファイルのパスをいれるのですが、"B1"にはファイルのパスが入っているっということでよろしいですか？

[ma2hiro]

1T2R3M4様
リファレンス読みましたが理解できなかったのです。（現在トラブルの原因究明が出来ず）
申し訳ございません。

D0NKAMA様
はい。ファイルのフルパスが入っております。
\\192.168.1.11\gyoumu\200_事業\★事業実績データ\事業実績自動化\テストフォルダ\\211112_10月末予定●7期社完工高と利益（2期以降）%20-%20コレが元.xlsx
このようなデータがB1にははいっております。

[bebebe_]

一度コピー元のファイルと同じ場所でVBAが実行できるようにして
Debug.Print ThisWorkbook.path
なりを実行してみて表示されるとパスと一致していますか？

また今回の問題とは関係ないと思いますがその宣言だとstrTmp, copyDest, konnnenndoFile, jinenndoFileはバリアント型になっています。

[退会済みユーザー]

hatena19さんは原因の説明もしていて、既にFileSystemObjectの解説記事のリンクも貼ってるのに、後出しでソースだけ貼り付けているjinojiさんがベストアンサーって、さすがに選び方に問題がありすぎませんか。選んだ理由をお聞かせ願えますか？

[ma2hiro]

radian様
ご指摘ごもっともです……

Hatena19様大変失礼しました。
ご紹介して頂いたURLを参考にしていて
うんうん唸っていた際に
jinojiさんの直ソースを見て実装出来たので思わずBAにしてしまいました。

Answer 1

Dir関数には、パス名の長さが256バイトまでという制限がありますが、それを超えてませんか。
ファイル名が半角190文字とのことですが、提示のフルパスには全角文字も含まれています。
全角文字は2バイトになります。それで計算して超えてないでしょうか。
また、UNICODE文字を含むファイル名も扱えません。

上記の点に引っ掛かっているなら、FileSystemObjectオブジェクトを使ってコピーすることを検討してください。

Dir関数の制限について｜VBA技術解説

ファイルシステムオブジェクト（FileSystemObject）｜VBA入門

Comments

[ma2hiro]

hatena19様
コメントありがとうございます。
＞全角文字は2バイトになります。それで計算して超えてないでしょうか。
はい。私の使用しているテキストエディターでは全角は二文字としてカウントするので
それで191文字なので超えておりません……
念の為Cの直下に持ってきても動作しませんでしたが
ファイル名を短くしたらDirが上手く行きました……

211012_10月末暫予定●58期あああああああと利益（53期以降） - コレが元.xlsx
↓
211012_10月末暫予定●（53期以降）コレが元.xlsx
としたら上手く行ったのでファイル名そのものが長すぎた模様です……

Dirでのファイル名の長さの制限のドキュメントが見つけられませんでしたが
試行錯誤の結果　Dirの問題は解決しました。
Dirでのファイル名の長さの制限のドキュメントを探し中です。

FileCopyが上手くいかないです……
B3のコピー先フォルダが　私ではアクセス出来るのですが
VBAのFileCopyではアクセス出来ない模様です……

新規で質問立てるのは忍びないので
ご紹介して頂いた　https://excel-ubara.com/excelvba1/EXCELVBA419.html　を見て実装してみようと思います。

本当にありがとうございました。

Answer 2

Sub sample()
    Dim konnnenndoFile As String, jinenndoFile As String, copyDir As String

    konnnenndoFile = Range("B1").Value
    jinenndoFile = Range("B2").Value
    copyDir = Range("B3").Value & "\"

    With New FileSystemObject
        If .FileExists(konnnenndoFile) And .FileExists(jinenndoFile) And .FolderExists(copyDir) Then
            .GetFile(konnnenndoFile).Copy copyDir
            .GetFile(jinenndoFile).Copy copyDir
        End If
    End With
End Sub

Comments

[ma2hiro]

jinoji様
コメント本当にありがとうございます。
' With New FileSystemObject
ではなくて
With CreateObject("Scripting.FileSystemObject")
としたら出来ました。

[ファイルシステムオブジェクト（FileSystemObject）｜VBA入門](https://excel-ubara.com/excelvba1/EXCELVBA419.html) には
参照設定＞「ツール」→「参照設定」に、「Microsoft Scripting Runtime」にチェックを付ける
と表記してあるのですがそちらはやってなく
Microsoft　Excel　16.0　Object　Library　と
Microsoft　Office　16.0　Object　Library　にはチェックが入っているので
そこが原因だと思っております……（そこら辺の知識が疎いのですが参考文献見つからないのです）

本当にありがとうございました。