EXCELでブックからデータを抽出して別ブックの特定のセルに入力したいです。

Question

お世話になります。
EXCELでブックからデータを抽出して別ブックの特定のセルに入力したいです。
売上データというEXCELがあり、B14・F14・B15・F15に数字が入力されています。

その数字を別のEXCEL（売上表）に自動的に反映させたいのですが、

売上表は一つですが、売上データのEXCELが大量にあります。

売上データにはI8に「名前」というセルがあり、売上表にもC列に「名前」が入力されています。

この売上データの「名前」を売上表のC列と照合して、
合っていればその名前（C列の複数行）を起点に

C列の名前セルから右に2列移動、下に1行移動した所にB14

C列の名前セルから右に3列移動、下に1行移動した所にF14

C列の名前セルから右に2列移動、下に3行移動した所にB15

C列の名前セルから右に3列移動、下に3行移動した所にF15

という形で数字を反映させたいと考えております。

VBAで作ってみようと思いましたが、名前を参照する所で躓いております。

お手数ですがご教示の程お願い致します。

2021年11月17日14時2分　画像追記

Answer 1

こんな感じでどうでしょうか。（修正：セル結合がある場合にOffsetがずれる事象に対処しました。）

Sub sample()
    Dim moto As Worksheet
    Dim myName
    Set moto = Workbooks("売上データ").Worksheets(1)
    myName = moto.Range("I8").Value

    Dim saki As Worksheet
    Dim c As Range
    Dim firstAddress As String
    Set saki = Workbooks("売上表").Worksheets(1)
    With saki.Range("C:C")
        Set c = .Find(myName)
        If Not c Is Nothing Then
            firstAddress = c.Address
            Do
                c.Offset(, 2).Offset(1).Value = moto.Range("B14")
                c.Offset(, 3).Offset(1).Value = moto.Range("F14")
                c.Offset(, 2).Offset(3).Value = moto.Range("B15")
                c.Offset(, 3).Offset(3).Value = moto.Range("F15")
                Set c = .FindNext
            Loop While Not c Is Nothing
        End If
    End With
End Sub

Comments

[ko1]

ご回答ありがとうございます。

申し訳ありません。 Set moto = Workbooks("売上データ").Worksheets(1)の部分で

実行時エラー'9';
インデックスが有効ではありません。

とえらーが出てしまい名前など変えてみましたが直すことができませんでした。
お手数ではございますがご教示頂けますでしょうか。

[jinoji]

売上データと売上表のどちらについても既に開いた状態で実行してください。
また、ファイル名の部分は、実際のファイル名にあわせて、たとえばWorkbooks("○○売上データ.xlsx") のようにしてください。

[ko1]

迅速なご対応ありがとうございます。
両方のブックを開き実行できました。ありがとうございます。
ただ画像を追記させて頂きました通り、売上表に記載された時行が1～2段ずれており、
Offset(1, 2)の数字を変えて試してみましたが、思うどおりの所に入らない状況です。
何度も申し訳ありませんが、ご教示いただきますでしょうか。
よろしくお願い致します。

[jinoji]

修正してみました。もう一度お確かめください。

[ko1]

対処していただいたコードで実行できました！
何度も申し訳ありません！
ありがとうございますm(__)m