当たり判定がうまくいかない

Question

前提・実現したいこと

processingで的あてゲームを作っています。
当たり判定を作りたいのですがhitしたときに一度だけ実行したいのですがうまくいきません。
hitしたときにコンソール画面で複数回hitと表示されてしまいます。

発生している問題・エラーメッセージ

ArrayListクラスでボールを作っているのでbooleanで当たり判定のフラグを立ててもうまくいきません。

該当のソースコード

class Ball {
float x;
float y;
float size;
float vx;
float vy;
float red = 255;
float green = 255;
float blue = 0;
boolean hit = false;
float status = 0;

Ball(float initX, float initY, float initSize, float initVx, float initVy) {
x = initX;
y = initY;
size = initSize;
vx = initVx;
vy = initVy;
}

void show() {
fill(red, green, blue);
ellipse(x, y, size, size);
}

void update() {
x += vx;
y += vy;
}
}

class Target {
float x;
float y;
float size;
float red = 255;
float green = 0;
float blue = 0;
float alpha = 255;

Target(float initX, float initY, float initSize) {
x = initX;
y = initY;
size = initSize;
}

void show() {
fill(red,green, blue, alpha);
ellipse(x, y, size, size);
}

void update(ArrayList<Ball> balls) {
for(int i = 0; i < balls.size(); i++){
float dx = abs(balls.get(i).x - x);
float dy = abs(balls.get(i).y - y);
float r = (balls.get(i).size + size) / 2;

 if(dx * dx + dy * dy <= r * r){ 
   if(balls.get(i).hit == false){
     blue = 255;
     red = 0;
     //alpha -= 25.5;
     println("hit");
   }
   balls.get(i).hit = true;
 } else {
   balls.get(i).hit = false;
 }

}
}
}

ArrayList<Ball> balls = new ArrayList<Ball>();

Target[] targets = new Target[12];

void setup() {
size(600, 400);
frameRate(30);
noStroke();

targets[0] = new Target(500, 200, 10);
targets[1] = new Target(400+100sqrt(3)/2, 150, 10);
targets[2] = new Target(450, 200+100sqrt(3)/2, 10);
targets[3] = new Target(450, 200-100sqrt(3)/2, 10);
targets[4] = new Target(400, 100, 10);
targets[5] = new Target(350, 200-100sqrt(3)/2, 10);
targets[6] = new Target(400-100sqrt(3)/2, 150, 10);
targets[7] = new Target(300, 200, 10);
targets[8] = new Target(400+100sqrt(3)/2, 250, 10);
targets[9] = new Target(350, 200+100sqrt(3)/2, 10);
targets[10] = new Target(400-100sqrt(3)/2, 250, 10);
targets[11] = new Target(400, 300, 10);
}
void draw() {
background(255);

for(Ball ball : balls){
ball.update();
ball.show();
}
for (Target target : targets){
target.show();
target.update(balls);
}

int score = 0;
for (Target target : targets){
if(target.blue == 255){
score += 1;
}
}
fill(0);
text("Score" + score, 10, 20);
}
void mousePressed(){
float vx = mouseX - 50;
float vy = mouseY - 200;
float r = 1 / sqrt(vx * vx + vy * vy);
balls.add(new Ball(50, 200, 30, vx * r * 10, vy * r * 10));
}

Answer 1

プログラムを見て疑問に思うのは、
TargetクラスのupdateメソッドでなぜBallクラスのhitフィールドをいじっているのかということなのですが。
Targetクラスは自分がBallにあたっているかどうかを自分で管理すればよいだけなのに、そこでBallの状態をいじってしまうというのはおかしなことになる一つの要素では(他のTargetがBallのhitをいじってしまう)。つまり、hitフィールドはTargetクラスが持つのが適当では。

でもって、Targetがhitしているかどうかというのは全てのBallについての検査のorになるはず。逆に言えば、hitのクリアをしていいのは全てのBallに対して当たり判定がfalseになったときだけ、では。

つまり、

ArrayListクラスでボールを作っているので

というのは理由ではないでしょう。

変更を最小限をコンセプトにするなら、
boolean hit=false;
をTargetクラスのフィールドに追加して、Ballクラスのhitは削除し、
Target.update()は

  void update(ArrayList<Ball> balls) {
    boolean tmpHit=false;//全部のBallに対して当たりがないことを検出するための変数
    for (int i = 0; i < balls.size(); i++) {
      float dx = abs(balls.get(i).x - x);
      float dy = abs(balls.get(i).y - y); 
      float r = (balls.get(i).size + size) / 2; 

      if (dx * dx + dy * dy <= r * r) { 
        if (hit == false) {//当たっていない状態から当たったことを検出した
          blue = 255;
          red = 0;
          //alpha -= 25.5;
          println("hit"+millis());//millis()はスクロールしても新しい行が分かるようにしたいだけ
        }
        tmpHit = true;//一つでも当たりがあればtmpHitはtrueになる
        break;
      } 
    }
    hit = tmpHit;//tmpHitがfalseになるのは全てのBallに対し当たりがなかったときだけ
  }

といったところでは。

Comments

[hogehogeho]

ありがとうございました。無事解決できました。

Answer 2

ArrayListクラスでボールを作っているのでbooleanで当たり判定のフラグを立ててもうまくいきません。

変化があるのはTargetのほうですから、そっちにフラグを持たせればいいのでは？

---

• 色はcolorにまとめた
  変数は少ないに越したことはないでしょう。
  x,y・vx,vyもPVectorにしてもいいかも。
• （私には）計算が難しいのでPVectorにまかせた
  ちょっと無駄がでますが、わかりやすくはなります。
• ballsが増えっぱなしなので、いらないのを消した
  ループ中に消すには逆順で回すか、Iteratorを使用する必要があります。

ArrayList<Ball> balls = new ArrayList<Ball>();
Target[] targets = new Target[12];

void setup() {
  size(600, 400);
  frameRate(30);
  noStroke();

  float r = TWO_PI / targets.length;
  for (int i = 0; i < targets.length; i++) {
    var p = new PVector(100, 0).rotate(r * i).add(400, 200);
    targets[i] = new Target(p.x, p.y, 10);
  }
}

void draw() {
  background(255);

  for (int i = balls.size() - 1; 0 <= i; i--) {
    Ball ball = balls.get(i);
    ball.update();
    ball.show();

    float r = ball.size / 2;
    if (ball.x + r < 0 || width < ball.x + r || ball.y + r < 0 || height < ball.y + r) {
      balls.remove(i);
    }
  }

  for (Target target : targets) {
    target.update(balls);
    target.show();
  }

  int score = 0;
  for (Target target : targets) {
    if (target.hit) {
      score++;
    }
  }
  fill(0);
  text("Score " + score, 10, 20);
}

void mousePressed() {
  PVector p = new PVector(mouseX - 50, mouseY - 200).setMag(10);
  balls.add(new Ball(50, 200, 30, p.x, p.y));
}


class Ball {
  float x;
  float y;
  float size;
  float vx;
  float vy;
  color c = #FFFF00;

  Ball(float initX, float initY, float initSize, float initVx, float initVy) {
    x = initX;
    y = initY;
    size = initSize;
    vx = initVx;
    vy = initVy;
  }

  void update() {
    x += vx;
    y += vy;
  }

  void show() {
    fill(c);
    circle(x, y, size);
  }
}

class Target {
  float x;
  float y;
  float size;
  color c = #FF0000;
  boolean hit;

  Target(float initX, float initY, float initSize) {
    x = initX;
    y = initY;
    size = initSize;
  }

  void update(ArrayList<Ball> balls) {
    if (hit) return;

    for (Ball ball : balls) {
      float r = (ball.size + size) / 2;
      if (dist(x, y, ball.x, ball.y) <= r) {
        c = #0000FF;
        println("hit");
        hit = true;
        return;
      }
    }
  }

  void show() {
    fill(c);
    circle(x, y, size);
  }
}

Comments

[hogehogeho]

ありがとうございました。無事解決できました。