【型が一致しません】事前対処

Question

VBA
Excel

検討内容
ユーザーフォームにテキストボックスを２つ用意し
ユーザーがそれぞれのテキストボックス内に8桁で日付を入力します。
例）2021年10月14日　→　20211014

入力された数字を　Date型に格納したいと思っています。

できないこと

ユーザーが【20210931】（2021年9月31日）のような
存在しない日付を入力した際に、
エラー【型が一致しません】が発生します。

相談内容
存在しない日付が入力された際に
メッセージボックスでエラー報告をするのは
どのようなコードになるでしょうか？

ご教示お願い致します。

実際のコードは以下の通りです。

コード
'解析期間のスタート　エンドを取得する
    Dim START0 As String
    Dim START1 As Date
    Dim END0 As String
    Dim END1 As Date
    
    
    START0 = UserForm1.TextBox1.Text
    END0 = UserForm1.TextBox2.Text
    
    If START0 = "" Or END0 = "" Then '文字入力がない
        MsgBox "入力エラー１：解析期間を入力してください！"
        Exit Sub
    
    ElseIf Len(START0) <> 8 Or Len(END0) <> 8 Then  '８文字指定じゃない
    
        MsgBox "入力エラー２：期間は８桁指定してく下さい！"
        Exit Sub
    
    Else
        START1 = CDate(Format(START0, "####/##/##"))
        END1 = CDate(Format(END0, "####/##/##"))
    
    End If

Answer 1

IsDate関数かエラートラップですね。

エラートラップなら下記のような感じ。

    On Error Resume next
    START1 = CDate(Format(START0, "####/##/##"))
    END1 = CDate(Format(END0, "####/##/##"))
    If Err <> 0 Then
        MsgBox "入力エラー３：正しい日付を入力してください。"
        Exit Sub
    End If
    On Error Goto 0

Comments

[sazi]

END0が正しい書式だとエラーにならないのでは？

[riko]

ご回答ありがとうございます。
IsDate　を活用することでうまくいきました。
エラートラップについて初めて知りました。
大変勉強になりました。ありがとうございます。

[hatena19]

> END0が正しい書式だとエラーにならないのでは？

動作テストしましたが、大丈夫でした。
エラーが出ない場合は、Errを変更しないようです。

[sazi]

@hatena19さん
Errオブジェクトはエラーが発生した時のみ生成されるようですね。
逆に、同じスコープ内ではクリアされなければ、残っているという事を意識しておかないと駄目って事で。

Answer 2

VBA IsDate 関数

これでどうでしょう

Comments

[riko]

ご回答ありがとうございます。
IsDate　を活用することでうまくいきました。

Answer 3

回答頂いた内容より
IsDateを活用し解決

コード
'解析期間のスタート　エンドを取得する
    Dim TEX1 As String
    Dim TEX2 As String
    Dim START0 As Variant
    Dim START1 As Date
    Dim END0 As Variant
    Dim END1 As Date
       
    TEX1 = UserForm1.TextBox1.Text
    TEX2 = UserForm1.TextBox2.Text
    
    If TEX1 = "" Or TEX2 = "" Then '文字入力がない
        MsgBox "入力エラー１：解析期間を入力してください！"
        Exit Sub
    
    ElseIf Len(TEX1) <> 8 Or Len(TEX2) <> 8 Then  '８文字指定じゃない

        MsgBox "入力エラー２：期間は８桁指定してく下さい！"
        Exit Sub
    
    Else '文字列にスラッシュをはめ込む
        Dim YYYY1 As Variant
        Dim MM1 As Variant
        Dim DD1 As Variant
        Dim YYYY2 As Variant
        Dim MM2 As Variant
        Dim DD2 As Variant
        
        YYYY1 = Left(TEX1, 4)
        YYYY2 = Left(TEX2, 4)
        MM1 = Mid(TEX1, 5, 2)
        MM2 = Mid(TEX2, 5, 2)
        DD1 = Right(TEX1, 2)
        DD2 = Right(TEX2, 2)
        
        START0 = YYYY1 & "/" & MM1 & "/" & DD1
        END0 = YYYY2 & "/" & MM2 & "/" & DD2
    End If
    
    If IsDate(START0) = True And IsDate(END0) = True Then  '日付型にできる場合は実行
    
        START1 = START0
        END1 = END0
    
    Else
        MsgBox "入力エラー３：存在しない日付です"
        Exit Sub
    End If