【VBA】コードを短縮したいです（初学者）

Question

前提・実現したいこと

VBAのコードを短縮したいです。

VBA初学者です。
問題なく動作するものの、後学のために
より効率の良い記述を教えて頂きたいです。

宜しくお願いします。

■ 処理内容

A列に文字列が入っている間、列に対して順番に
文字列を加工・日付型に変換する処理を行います。

該当のソースコード

Sub editString()

    Dim row As Integer
    row = 2
    
    '文字列を左から8文字目まで切り出して日付型に変換
    
    Do Until Cells(row, 1).Value = ""
        Cells(row, 4).Value = CDate(Left(Cells(row, 4).Value, 8))
        row = row + 1
    Loop

    row = 2

    Do Until Cells(row, 1).Value = ""
        Cells(row, 5).Value = CDate(Left(Cells(row, 5).Value, 8))
        row = row + 1
    Loop

    row = 2

    Do Until Cells(row, 1).Value = ""
        Cells(row, 8).Value = CDate(Left(Cells(row, 8).Value, 8))
        row = row + 1
    Loop

End Sub

Comments

[hex309]

例ということなのでしょうけれど、文字列の先頭から8文字を切り出して日付型になるような、8文字ってどんな文字ですか？「20210910」みたいな8文字だと、うまく行かないな、と思ったもので。
本筋とは違ってすみません。

[pinkieee]

hex309 様

ご連絡下さりありがとうございます。
「21/09/10(金) 13:00」このような文字列です。

Answer 1

下記のように一回のループに纏めるだけでかなり簡略化できると思うけど、

Sub editString()

    Dim row As Integer
    row = 2

    '文字列を左から8文字目まで切り出して日付型に変換
    Do Until Cells(row, 1).Value = ""
        Cells(row, 4).Value = CDate(Left(Cells(row, 4).Value, 8))
        Cells(row, 5).Value = CDate(Left(Cells(row, 5).Value, 8))
        Cells(row, 8).Value = CDate(Left(Cells(row, 8).Value, 8))
        row = row + 1
    Loop

End Sub

自分がするなら、

Sub editString()

    Dim rng As Range
    Set rng = Range(Cells(2,1), Cells(rows.count,1).End(xlUp))

    '文字列を左から8文字目まで切り出して日付型に変換
    Dim c As Range
    For Each c In rng.Cells
        c.Offset(,3).Value = CDate(Left(c.Offset(,3).Value, 8))
        c.Offset(,4).Value = CDate(Left(c.Offset(,4).Value, 8))
        c.Offset(,7).Value = CDate(Left(c.Offset(,7).Value, 8))
    Next

End Sub

こんなのも。

Sub editString()

    Dim rng As Range
    Set rng = Range(Cells(2, 1), Cells(Rows.Count, 1).End(xlUp))
    Set rng = Union(rng.Offset(, 3), rng.Offset(, 4), rng.Offset(, 7))

    '文字列を左から8文字目まで切り出して日付型に変換
    Dim c As Range
    For Each c In rng.Cells
        c.Value = CDate(Left(c.Value, 4))
    Next

End Sub

Comments

[pinkieee]

hatena19 様

早速のご回答ありがとうございます。

ループの作り方やOffset関数など
一層理解・興味を深めることができました。
ベストアンサーとさせて頂きます。

お忙しい中、ご丁寧な回答重ねて感謝致します。

Answer 2

最大行を取得する方法が定石としてあるので、それを使用します。
行を表す変数:rowですが、intger型（-32768～32767）で確保するよりはLong型（約10桁まで格納可能）で確保したほうが安全です。
又、変数名:rowはプロパティにrowがあるので、その名称は使わないほうが無難です。
teratailのこの掲示板ではrowの文字が青色で表示されてます。

Sub editString()
    Dim maxrow As Long
    Dim wrow As Long
    maxrow = Cells(Rows.count, 1).End(xlUp).row    '1列の最大行取得
    '文字列を左から8文字目まで切り出して日付型に変換
    For wrow = 2 To maxrow
        Cells(wrow, 4).Value = CDate(Left(Cells(wrow, 4).Value, 8))
        Cells(wrow, 5).Value = CDate(Left(Cells(wrow, 5).Value, 8))
        Cells(wrow, 8).Value = CDate(Left(Cells(wrow, 8).Value, 8))
    Next
End Sub

Comments

[pinkieee]

tatsu99 様

早速のご回答ありがとうございます。

今後はLong型で確保するようにします。
変数名:rowも確かに仰る通りリスクがありますね。
詳しい方から教えて頂くまで考えもしませんでした。
一層理解・興味を深めることができました。

お忙しい中、ご丁寧な回答重ねて感謝致します。