複数の画像を一括で拡大処理するバッチファイルを作成したい

Question

前提・実現したいこと

RealESRGANを用いて、複数の画像を一括で拡大処理するバッチファイルを作成したい。

▽RealESRGAN
https://github.com/xinntao/Real-ESRGAN

発生している問題・エラーメッセージ

フォルダ内の画像をforループで参照し、拡大処理を行っているが、出力されたファイルも参照されてしまい、無限ループしてしまう。
出力された画像（拡大された画像）にさらに拡大処理を行っている状況。

該当のソースコード

@echo off
setlocal enabledelayedexpansion

pushd "%~dp0"

set path="realesrgan-ncnn-vulkan.exe"
rem 出力画像名を「ファイル名_4x.png」のように設定
set suffix=_4x

for %%f in (*.jpg *.jpeg *.png) do (
    rem 拡大処理　参照元のファイルから、新たに拡大された画像を生成（出力）します
    call %path% -i %%f -o "%%~nf%suffix%".png -n realesrgan-x4plus-anime
)

popd
pause

試したこと

一応、もとあるファイル数以上のループ処理を行わないようにすることで対応しましたが、
正直もっと賢いやり方があるのでは、と思い質問させていただきました。
余分なループ処理を行わないような最適解を探しています。

@echo off
setlocal enabledelayedexpansion

pushd "%~dp0"

set path="realesrgan-ncnn-vulkan.exe"
set suffix=_4x

set /a counter=0
for %%A in (*.jpg *.jpeg *.png) do ( if exist %%A (set /a counter=counter+1) )
echo %counter%

set num=0
for %%f in (*.jpg *.jpeg *.png) do (
  if !num! lss %counter% (
    call %path% -i %%f -o "%%~nf%suffix%".png -n realesrgan-x4plus-anime
  )
  set /a num=num+1
  echo !num!
)

popd
pause

よろしくお願い致します。

補足情報（FW/ツールのバージョンなど）

▽RealESRGAN
https://github.com/xinntao/Real-ESRGAN

Answer 1

まず、「PATHを通す」とか聞いたことはないですか？環境変数PATHは特別な意味を持っているので、他の目的には使いません。このコードだと、realesrgan-ncnn-vulkan.exe以外の外部コマンドを使っていないので、動いていますが。
（realesrgan-ncnn-vulkan.exeのプログラムの中で環境変数PATHを参照している可能性もありましたが、動いているなら結果オーライですね）

案1：最初にファイル一覧を取得する
案2：ファイル名に_4xを含む場合は処理しない
案3：出力ファイルは別のフォルダーを指定してそこに出力する

案1：

for %%f in (*.jpg *.jpeg *.png) do (
を、
for /f "delims=" %%f in ('dir /b *.jpg *.jpeg *.png') do (
に。他は同じ。

案2：

@echo off
setlocal enabledelayedexpansion

pushd "%~dp0"

set prog="realesrgan-ncnn-vulkan.exe"
rem 出力画像名を「ファイル名_4x.png」のように設定
set suffix=_4x

for %%f in (*.jpg *.jpeg *.png) do (
    rem 拡大処理　参照元のファイルから、新たに拡大された画像を生成（出力）します
    set FN=%%~nf
    if not "!FN:~-3!"=="%suffix%" %prog% -i %%f -o "%%~nf%suffix%".png -n realesrgan-x4plus-anime
)
popd
pause

拡張子を除いたファイル名の末尾3文字を取り出してますが、3じゃなくて%suffix%の長さを求めるとか考えると面倒。

案3：
（略）

案1だと、再実行すると前回の処理結果のファイルも処理対象になってしまいますが、案2・案3だと再実行してもそういうことにはなりません。

案3が普通でしょうか。