VB.NETのフォーム画面上でTABキーを一度でも使うとコントロールに枠線が出てしまう

Question

前提・実現したいこと

VB.NETで簡単なウィンドウアプリケーションを作成しています。
画面上にいくつかのテキストボックスとボタンが配置されています。
テキストボックスは複数個あり、すべてのテキストボックスのValidatingイベントでテキストボックスの入力内容をチェックし、何かしらの入力がされていればボタンを有効化(Enabled=true)しています。

このボタンのプロパティは、デフォルト以外の設定は以下のようにしています。

        Me.SubmitButton.BackColor = System.Drawing.Color.LimeGreen
        Me.SubmitButton.FlatAppearance.BorderSize = 0
        Me.SubmitButton.FlatAppearance.MouseDownBackColor = System.Drawing.Color.LightGreen
        Me.SubmitButton.FlatAppearance.MouseOverBackColor = System.Drawing.Color.LimeGreen
        Me.SubmitButton.FlatStyle = System.Windows.Forms.FlatStyle.Flat
        Me.SubmitButton.Font = New System.Drawing.Font("Yu Gothic UI", 15.75!, System.Drawing.FontStyle.Bold, System.Drawing.GraphicsUnit.Point, CType(128, Byte))
        Me.SubmitButton.ForeColor = System.Drawing.SystemColors.HighlightText
        Me.SubmitButton.Location = New System.Drawing.Point(1056, 40)
        Me.SubmitButton.Margin = New System.Windows.Forms.Padding(0)
        Me.SubmitButton.Name = "SubmitButton"
        Me.SubmitButton.Size = New System.Drawing.Size(336, 64)
        Me.SubmitButton.TabIndex = 11
        Me.SubmitButton.TabStop = False
        Me.SubmitButton.Text = "検索"
        Me.SubmitButton.UseVisualStyleBackColor = False

この設定の状態で、フォーム上から、以下の挙動で操作した際に、ボタンコントロール上に枠線の表示に差が出ています。
これをなんとか表示させないようにしたいのですが、対処方法はあるでしょうか。

枠線が出ない挙動

1.テキストボックスに値を入力
2.キーボードを使わず他のテキストボックスに遷移させてから、ボタンをクリック

枠線が出る挙動

1.テキストボックスに値を入力
2.TABキーで項目を遷移させてから、ボタンをマウスクリック

一度でもTABキーを使ってコントロールを遷移してしまうと、枠線が出ない挙動と全く同じ方法で操作しても枠線が出るようになってしまいます。

Comments

[退会済みユーザー]

出なかったらキーボードフォーカスあるの判らなくなるけど、そこはいいんですか？

[nipponica]

たしかにキーボード操作をメインとするユーザー視点で見ると、ちょっと優しくないUIですね。
一旦その危惧を無視するとして、回避策を思いつくようであればご教示いただきたいです。

Answer 1

• 黒い点線のフォーカス枠だけを消す場合（外側の青いフォーカス枠は出る）

Public Class MyButton
    Inherits Button

    Protected Overrides ReadOnly Property ShowFocusCues As Boolean
        Get
            Return False
        End Get
    End Property

End Class

• 自分で描く

Public Class MyButton
    Inherits Button

    Private Shared _DicTextFormat As New Dictionary(Of ContentAlignment, TextFormatFlags) From
    {
        {ContentAlignment.TopLeft, TextFormatFlags.Left Or TextFormatFlags.Top},
        {ContentAlignment.MiddleLeft, TextFormatFlags.Left Or TextFormatFlags.VerticalCenter},
        {ContentAlignment.BottomLeft, TextFormatFlags.Left Or TextFormatFlags.Bottom},
        {ContentAlignment.TopCenter, TextFormatFlags.HorizontalCenter Or TextFormatFlags.Top},
        {ContentAlignment.MiddleCenter, TextFormatFlags.HorizontalCenter Or TextFormatFlags.VerticalCenter},
        {ContentAlignment.BottomCenter, TextFormatFlags.HorizontalCenter Or TextFormatFlags.Bottom},
        {ContentAlignment.TopRight, TextFormatFlags.Right Or TextFormatFlags.Top},
        {ContentAlignment.MiddleRight, TextFormatFlags.Right Or TextFormatFlags.VerticalCenter},
        {ContentAlignment.BottomRight, TextFormatFlags.Right Or TextFormatFlags.Bottom}
    }

    Protected Overrides Sub OnPaint(pevent As PaintEventArgs)
        'ボタン描画
        If Not Me.Enabled Then
            ButtonRenderer.DrawButton(pevent.Graphics, pevent.ClipRectangle, VisualStyles.PushButtonState.Disabled)
        ElseIf Me.Focused Then
            ButtonRenderer.DrawButton(pevent.Graphics, pevent.ClipRectangle, VisualStyles.PushButtonState.Hot)
        Else
            ButtonRenderer.DrawButton(pevent.Graphics, pevent.ClipRectangle, VisualStyles.PushButtonState.Normal)
        End If

        'ボタンテキスト描画
        TextRenderer.DrawText(pevent.Graphics, Me.Text, Me.Font, pevent.ClipRectangle, Me.ForeColor, _DicTextFormat(Me.TextAlign))
    End Sub

End Class

自分で描く場合、今回のサンプルはかなり手抜きなので、標準の外観に近づけようと思ったら、クリックやスペースキー押し続けてる時、フォーカス無しでマウスカーソル当たってる時等の処理などもあるので、もっと工夫する必要があります。標準の外観にこだわらないなら、自分で用意した画像を描いたり、思いのままです。

dobon.net - Buttonの表面を自分で描画する

Answer 2

フォーカスを持った時の表示を全くしなくてもいいのであれば

Public Class CustomButton
    Inherits Button

    Public Sub New()
        Me.SetStyle(ControlStyles.Selectable, False)
    End Sub
End Class

とButtonを継承したものを作成し、コンストラクタでフォーカスを持たないようにすればいいかと思います。

Comments

[nipponica]

シンプルで良さそうですね。
早速試させていただきます。

[退会済みユーザー]

これをした場合、キーボードでフォーカス移動出来なくなりますね。